build.gradle

def env = project.hasProperty('env') ? project.getProperty('env') : 'local'
apply from: "$rootDir/gradle/versioning.gradle"
ext.config = new ConfigSlurper(env).parse(file("$rootDir/gradle/config/buildConfig.groovy").toURL())

ext.projVersion = version

allprojects {
    apply plugin: 'idea'
    apply plugin: 'eclipse'
    group = 'com.sequenceiq'
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'checkstyle'

    sourceCompatibility = 1.7
    targetCompatibility = 1.7

    version = projVersion

    configurations {
        deployerJars
        all*.exclude group: 'org.slf4j', module: 'slf4j-log4j12'
        all*.exclude group: 'com.google.guava', module: 'guava-jdk5'
        testCompile.exclude module: 'groovy-all'
    }

    dependencies {
        deployerJars("org.springframework.build.aws:org.springframework.build.aws.maven:3.0.0.RELEASE")
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                configuration = configurations.deployerJars
                repository(url: "s3://maven.sequenceiq.com/releases") {
                    authentication(userName: "$System.env.AWS_ACCESS_KEY", passphrase: "$System.env.AWS_SECRET_ACCESS_KEY")
                }
                snapshotRepository(url: "s3://maven.sequenceiq.com/snapshots") {
                    authentication(userName: "$System.env.AWS_ACCESS_KEY", passphrase: "$System.env.AWS_SECRET_ACCESS_KEY")
                }
            }
        }
    }

    checkstyleMain {
        ignoreFailures = false
        configProperties = ['config_loc': "$projectDir/config/checkstyle"]
    }

    checkstyleTest {
        ignoreFailures = false
        configProperties = ['config_loc': "$projectDir/config/checkstyle"]
    }

    dependencies {
        checkstyle('com.puppycrawl.tools:checkstyle:5.7') {
            exclude group: 'com.google.guava'
        }
        checkstyle("com.google.guava:guava:16.0.1") { force = true }
    }

    repositories {
        mavenCentral()
        maven { url "http://maven.sequenceiq.com/snapshots" }
        maven { url "http://maven.sequenceiq.com/release" }
        maven { url "http://maven.sequenceiq.com/releases" }
    }
}