Any interest in a D-Ring module?

[dan-p3rry]

I wrote a module to create D-rings. It's quite simple, a union of a rounded_prism() and a ycyl(). It's only interesting because the tangents are calculated so that any reasonably sized base can join to any ycyl. If you are interested, I will add some error checking and share the code.

[adrianVmariano]

Seems like there is interest. Hardest thing to figure out about this is probably how to handle the attachment settings. Do you attach to the bounding box cube? It's also not a D-ring, so maybe the name should be something else?

Any thoughts on where it belongs in the library?

[adrianVmariano]

Do you support a D-ring form where you only have a half-circle?

[dan-p3rry]

Seems like there is interest. Hardest thing to figure out about this is probably how to handle the attachment settings. Do you attach to the bounding box cube? It's also not a D-ring, so maybe the name should be something else?

My BOSL2 skills are not to the point where I use attachments, so I have no idea .... I call it a "d_shape".

Any thoughts on where it belongs in the library?

shapes3d.scad, "other round objects"

Do you support a D-ring form where you only have a half-circle?

Are you asking about the overall shape, or the through-hole? The overall shape can approach a half circle, as long as the rounded_prism() shape has a finite height. The current code for the through hole only supports a full cylinder.

[adrianVmariano]

I was asking about the hole---you know, to make it an actual D-ring.

The thinking about this is that it's a "part" rather than a "shape" so it would belong somewhere in the parts library. But I'm not sure what it would be called. (Coming up with names for things in the library is often a challenge.) What name would convey its use and function, so that somebody would find it if they needed something like this?

I encourage you to read through the attachments tutorial https://github.com/BelfrySCAD/BOSL2/wiki/Tutorial-Attachments and learn about attachments, because I think they are possibly the most important thing in the library for how they can simplify a model made from more than one object.

[dan-p3rry]

I tried to modify this code:

        union() {
            rounded_prism(rect([b_width, thickness]), 
                rect([2*tangent.x, thickness]), height=tangent.y, 
                joint_bot=roundingb, joint_sides=rounding, k_sides=0.92,
                anchor=BOTTOM);
            top_half(s=2.1*max(b_width, 2*d_rad, thickness), z=tangent.y)
                up(b_height)  
                    ycyl(r=d_rad, h=thickness, rounding=rounding);
        }

to use attachments:

        rounded_prism(rect([b_width, thickness]), 
            rect([2*tangent.x, thickness]), height=tangent.y, 
            joint_bot=roundingb, joint_sides=rounding, k_sides=0.92,
            anchor=BOTTOM)
        attach(TOP, CENTER, overlap=tangent.y - b_height)
            top_half(p=cyl(r=d_rad, h=thickness, rounding=rounding, 
                    orient=FRONT), s=2.1*max(b_width, 2*d_rad, thickness), 
                    z=tangent.y);

but it fails with an error

WARNING: variable "p" not specified as parameter in file d_shape.scad, line 48

It works without top_half(), but I tried several different things and never got it to work with top_half(). Any suggestions?

[adrianVmariano]

I can't actually run the code to see what you're doing because it's got a bunch of undefined variables.

But in your second example, you're using top_half as a module but passing it a p argument, which only exists for the function form, because the p argument replaces the child that goes to the module. So for the module it needs to be top_half(s=..., z=...) cyl(....).

There is another issue, which is that top_half is going to lose the geometry info (because we can't get geometry out of modules) so attachment won't work properly there. If you want to do that operation you'll need to attach the full cylinder and cut it off after attaching it.

Note that making your object attachable is separate from using attachments to make your object. To do that you need to decide what the correct anchors are for your object and invoke attachable() when your object makes its geometry.

[dan-p3rry]

Following code includes attachments, but attachment are only correct in Z-dimension when b_height = d_rad. The part is non-symmetric to the center of the "D" circle when b_height != d_rad and then anchors are incorrect. I don't know how to fix this. Since this part is non-symmetrical in Z, it might make more sense to anchor the part to the X-Y plane, but I couldn't figure out those anchors either.

Also, I will take a look at allowing a D-shaped hole. Are you thinking the D-shaped hole would be a semicircle? Otherwise we are adding several new variables ....

include <BOSL2/std.scad>
include <BOSL2/rounding.scad>

$fs = 0.4; 
$fa = 1;

b_width = 50;   // base width: width of the flat part of the "D"
d_rad = 25;     // D radius: radius of the round part of the "D"
b_height = 25;  // base height: distance from the flat part of "D" 
                // to center of the round part of the "D"
thickness = 12; // Y dimension of the part
rounding = 6;   // rounding of "D"
roundingb = -5; // base rounding
holeR = 0;      // hole placed in center of "D" when > 0
roundingh = 6;  // rounding of the center hole

d_shape(b_width, d_rad, b_height, thickness=thickness, 
        rounding=rounding, roundingb=roundingb, 
        holeR=holeR, roundingh=roundingh) show_anchors();

// right(80)
// d_shape(70, 25, 1, thickness=thickness, 
//         rounding=0, roundingb=0, 
//         holeR=0, roundingh=roundingh);

// right(160)
// d_shape(46, 25, 10, thickness=thickness, 
//         rounding=3, roundingb=0, 
//         holeR=0, roundingh=0);

module d_shape(b_width, d_rad, b_height, thickness, holeR=0, 
            rounding=0, roundingb=0, roundingh=0,
            anchor=BOTTOM, spin=0, orient=UP) {

    assert(sqrt((0.5*b_width)^2 + b_height^2)>d_rad, 
        "[0.5*b_width, 0] must be outside the circle of radius d_rad centered at [0, b_height]");
    // I cannot imagine anyone would ever want rounding or roundingh
    // to be < 0, but should be OK

    tangents = circle_point_tangents(r=d_rad, cp=[0, b_height], 
                pt=[0.5*b_width, 0]);
    // we want the tangent with the larger y value
    tangent = tangents[0].y > tangents[1].y
            ? tangents[0] : tangents[1];

    attachable(anchor, spin, orient, size=[max(b_width,2*d_rad), 
            thickness, b_height+d_rad]) {
        difference() {
            union() {
                top_half(s=2.1*max(b_width, 2*d_rad, thickness), 
                            z=tangent.y - b_height)
                    ycyl(r=d_rad, h=thickness, rounding=rounding);
                up(tangent.y - b_height)
                rounded_prism(rect([b_width, thickness]), 
                    rect([2*tangent.x, thickness]), height=tangent.y, 
                    joint_bot=roundingb, joint_sides=rounding, 
                    k_sides=0.92, anchor=TOP
                    );
            }
            if (holeR > 0)
                ycyl(r=holeR, h=thickness + 0.01, rounding=-roundingh);

        } // difference
        children();
    } // attachable
}

[adrianVmariano]

The way attachable works, the children need to be centered in every direction. Your asymmetric shapes where anchoring fails are not centered vertically. Basically when you give the size, it's defining a centered cuboid with that size as the anchor points. If you then make BOTTOM the default anchor, the shape will appear sitting on the XY plane.

I think the way you have it with the attachment point DOWN is the right way to do this. (Note also that if you turned it sideways the anchors would still be wrong if you didn't center it.)

Regarding a D shaped hole, only if you think it's useful and you want to do it. I toss out ideas and they aren't necessarily always good, so pushback/dialog is fine. You may want to consider talking about contributions on the developer chat (link on the github landing page).

Why would we want a D hole? Well, a D hole lets you have a wider slot in a shorter height. You could address the need for a wide slot by making the hole an ellipse, which just requires one parameter and would possibly be a trivial modification. That also avoids the problematic issue of rounding the inside corners of the D. Another wide hole option might be a rounded rectangle of some kind or the squircle.

For naming it seems like this object is like an eye bolt without the bolt. The front running name so far is connector_ring() which I'm not a big fan of, so still looking for ideas there.

[dan-p3rry]

OK, I think I'm done. Anchors are adjusted to fit the upper curve, plus custom anchors added. A D-shaped hole is supported, too.

Some ideas for future enhancement: support chamfer & for the base, teardrop mask; the D-shape could be ellipse-shaped instead of strictly circular.

[dan-p3rry]

Here's the code, including the module calls for the examples above. Let me know if you find any bugs.

include <BOSL2/std.scad>
include <BOSL2/rounding.scad>

$fs = 0.4; 
$fa = 1;

base_w = 40;   // base width: width of the flat part of the "D"
d_rad = 25;     // D radius: radius of the round part of the "D"
base_h = 25;  // base height: distance from the flat part of "D" 
                // to center of the round part of the "D"
thickness = 12; // Y dimension of the part
rounding = 0;   // rounding of "D"
roundingb = 0; // base rounding
holeR = 15;      // hole placed in center of "D" when > 0
roundingh = 2;  // rounding of the center hole

d_shape(base_w, base_h, d_rad, thickness=thickness, 
        rounding=rounding, roundingb=roundingb, 
        holeR=holeR, roundingh=roundingh, anchor=BOTTOM)
        show_anchors()
        ;

right(100)
d_shape(50, 10, 25, thickness=thickness, 
        rounding=5, roundingb=0, 
        holeR=15, holeD_Bool=true, roundingh=5);

right(200)
d_shape(50, 40, 25, thickness=thickness, 
        rounding=3, roundingb=0, 
        holeR=0, roundingh=0) show_anchors();

module d_shape(base_w, base_h, d_rad, thickness, holeR=0, holeD_Bool=false,
            rounding=0, roundingb=0, roundingh=0,
            anchor=BOTTOM, spin=0, orient=UP) {

    assert(sqrt((0.5*base_w)^2 + base_h^2)>d_rad, 
        "[0.5*base_w, 0] must be outside the circle of radius d_rad centered at [0, base_h]");
    max_holeR = holeR > 0 && roundingb < 0 ? base_h + roundingb
                                : base_h;
    if (holeR > 0 && !holeD_Bool) assert(holeR + roundingh < max_holeR, 
                "holeR + roundingh must be less than max_holeR");
    assert(roundingh >= 0, "roundingh must be greater than or equal to 0");
    // I cannot imagine anyone would ever want rounding 
    //      to be < 0, but allowed for now

    z_offset = 0.5*(base_h - d_rad);
    tangents = circle_point_tangents(r=d_rad, cp=[0, base_h], 
                pt=[0.5*base_w, 0]);
    // we want the tangent with the larger y value
    tangent = tangents[0].y > tangents[1].y
            ? tangents[0] : tangents[1];
    // anchor calcs
    angle = atan((tangent.x - 0.5*base_w)/tangent.y);
    top_x = 0.5*base_w + (base_h + d_rad)*tan(angle);
    // when d_rad > 0.5*base_w, need to move the anchor
    // use x^2 + y^2 = r^2, x = sqrt(r^2 - y^2)
    delta_y = z_offset;
    mid_x = sqrt(d_rad^2 - delta_y^2);

    anchors = [
        named_anchor("hole_ctr_front", [0, -thickness/2, z_offset], FRONT, 0),
        named_anchor("hole_ctr_back", [0, thickness/2, z_offset], BACK, 0),
        named_anchor("tangent_right", [tangent[0], 0, tangent[1] - base_h + z_offset], RIGHT, 0),
        named_anchor("tangent_left", [-tangent[0], 0, tangent[1] - base_h + z_offset], LEFT, 0),
    ];
    override = [
        for (i = [-1, 1], j=[-1:1], k=[0:1])
            if (k==0 && j!=0 && d_rad > 0.5*base_w)
                [[i, j, 0], 
                [mid_x*unit([i, 0, 0]) + 0.5*thickness*unit([0, j, 0])]]
            else if (k==0 && d_rad > 0.5*base_w) 
                [[i, 0, 0], [mid_x*unit([i, 0, 0])]]
            else if (k==1 && j==0) 
                [[i, 0, 1], [d_rad*sin(45)*unit([i, 0, 0]) 
                            + (z_offset + d_rad*sin(45))*unit([0, 0, k])]]
            else if (k==1)
                [[i, j, 1], [d_rad*sin(45)*unit([i, 0, 0]) 
                                + 0.5*thickness*unit([0, j, 0])
                                + (z_offset + d_rad*sin(45))*unit([0, 0, k])]]
    ];

    attachable(anchor, spin, orient, 
                size=[base_w, thickness, base_h + d_rad],
                size2=[2*top_x, thickness],
                anchors=anchors, override=override) {
        up(z_offset) difference() {
            union() {
                top_half(s=2.1*max(base_w, 2*d_rad, thickness), 
                            z=tangent.y - base_h)
                    ycyl(r=d_rad, h=thickness, rounding=rounding);
                up(tangent.y - base_h)
                    rounded_prism(rect([base_w, thickness]), 
                        rect([2*tangent.x, thickness]), h=tangent.y, 
                        joint_bot=roundingb, joint_sides=rounding, 
                        k_sides=0.92, k_bot=0.92, anchor=TOP);
            }
            if (holeR > 0) {
                top_half(s=2.1*max(2*holeR, thickness), 
                            z = holeD_Bool ? 0 : -holeR - roundingh - 1)
                    ycyl(r=holeR, h=thickness + 0.01, 
                            rounding=-roundingh);
                if(roundingh > 0 && holeD_Bool) {
                    rpath = path_merge_collinear( concat(
                        path2d(arc(cp=[holeR, 0], r=roundingh, start=0, angle=-90)),
                        [[holeR, -roundingh], [-holeR, -roundingh], ],
                        path2d(arc(cp=[-holeR, 0], r=roundingh, start=270, angle=-90)),
                    ));
                    for (m = [0, 1]) mirror([0, m, 0])
                        back(0.5*thickness)
                        // fwd(20)
                        // stroke(rpath);
                        xrot(90) path_sweep(
                            mask2d_roundover(r=roundingh, 
                                    anchor=RIGHT), rpath);
                }
            }   // holeR
        } // difference
        children();
    } // attachable
}

[adrianVmariano]

From your examples it's looking good.

Can you write the doc text. Just take a look at some module in the library and follow the same form. The one thing that might not be obvious is in the Arguments section, the "---" separator separates between positional arguments, listed first, and named arguments. The docs processor uses indentation to parse stuff, so pay attention to indentation. You should create enough examples to display the significantly distinct modes of operation and various features.

[dan-p3rry]

Did we get consensus on the name of the part? I saw the discussion, and I do agree that "attach" should not be part of the name. Other than that I have no strong feelings about any of the proposals.

[adrianVmariano]

Go with connector_ring for now. We can change it if some better idea comes along before we push the release. We also don't know which file it's going in. It should be categorized as a "part" but doesn't obviously fit in anywhere.

[dan-p3rry]

I should have the documentation ready later today, maybe tomorrow. How can I test it to make sure the doc looks correct in the wiki page?