Initial Commit

Author: Doug

GCOrganizer.au3

@@ -0,0 +1,63 @@
+#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
+#AutoIt3Wrapper_UseX64=y
+#AutoIt3Wrapper_Change2CUI=y
+#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
+#include <File.au3>
+#include <String.au3>
+#include <WinAPI.au3>
+
+Local $nBytes = 6 ; IDs are only 6 characters
+Global $path = @ScriptDir & "\games\" ; Match layout of USB Loader GX
+Global $version = "1.0.0"
+
+ConsoleWrite(@CRLF & "=== Gamecube Organizer v" & $version & " ===" & @CRLF)
+ConsoleWrite(@CRLF & "Gathering file list..." & @CRLF)
+
+$files = _FileListToArray($path, "*.iso", 1, False) ; Only ISO's. Multiple filers would require  _FileListToArrayRec()
+
+If Not IsArray($files) Then
+	ConsoleWrite("Oops! Something went wrong." & @CRLF & "No files could be found in: " & $path & @CRLF & "Exiting Program." & @CRLF)
+	Exit
+EndIf
+If $files[0] <= 0 Then
+	ConsoleWrite("Oops! The directory is empty." & @CRLF & "No files could be found in: " & $path & @CRLF & "Exiting Program. " & @CRLF)
+	Exit
+EndIf
+
+ConsoleWrite(UBound($files)-1 & " files found!" & @CRLF)
+ConsoleWrite("Starting loop..." & @CRLF)
+Sleep(1500)
+
+For $i = 1 To $files[0] ; Loop every ISO found
+	If StringInStr($files[$i], "[") > 0 And StringInStr($files[$i], "]") > 0 Then ; Filename has the ID in title, dont need to HEX reader
+		$dirName = StringReplace($files[$i], ".iso", "")
+		DirCreate($path & $dirName)
+		FileMove($path & $files[$i], $path & $dirName & "\game.iso")
+		checkSuccess($i, $files[0], $dirName)
+	Else ; Need to read ID from first 6 HEX
+		$tBuffer = DllStructCreate("byte[6]") ; Create our buffer
+		$file = _WinAPI_CreateFile($path & $files[$i], 2, 2) ; Open the file as read only
+		_WinAPI_SetFilePointer($file, 0, 0) ; Start at the beggining
+		_WinAPI_ReadFile($file, $tBuffer, 6, $nBytes) ; Read the next 6 bytes
+		_WinAPI_CloseHandle($file)
+		$sText = BinaryToString(DllStructGetData($tBuffer, 1)) ; Convert the binary to a readable string
+		; Need to validate the ID: 6 Characters, No Spaces, AlphaNumeric, No empty 6th character
+		If StringLen($sText) = 6 and StringInStr($sText, " ") = 0 and StringIsAlNum($sText) and StringIsXDigit(StringRight($sText, 1)) Then
+			$dirName = StringReplace($files[$i], ".iso", "") & " [" & $sText & "]"
+			DirCreate($path & $dirName)
+			FileMove($path & $files[$i], $path & $dirName & "\game.iso")
+			checkSuccess($i, $files[0], $dirName)
+		Else
+			ConsoleWrite($i & "/" & $files[0] & ": Failed To Read (" & $files[$i] & ")" & @CRLF)
+		EndIf
+		$tBuffer = Null ; Clear buffer to avoid memory leak
+	EndIf
+Next
+
+Func checkSuccess($currentRow, $maxRows, $directoryName)
+	If FileExists($path & $directoryName & "\game.iso") Then
+		ConsoleWrite($currentRow & "/" & $maxRows & ": Success! (" & $directoryName & ")" & @CRLF)
+	Else
+		ConsoleWrite($currentRow & "/" & $maxRows & ": Failed To Copy (" & $directoryName & ")" & @CRLF)
+	EndIf
+EndFunc   ;==>checkSuccess

LICENSE.md

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2018 hotdog
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

README.md

@@ -0,0 +1,25 @@
+# Gamecube ISO Organizer
+
+I made this after I realized that a specific directory layout was required for USB Loader GX to recognize my Gamecube back ups.
+It will cycle through all available game ISO's, read their unique ID, create the directory and rename/move the ISO.
+
+## Getting Started
+
+Create a 'games' folder in the same location of this binary. Drop all of your .iso files into 'games' and then run the CUI binary.
+
+### Prerequisites
+
+I never tried this on ISO's that have been shrunk, but as long as it keeps the first 6 bytes of data in the file, they will work.
+
+### Installing
+
+Download the latest release binary or compile using SciTE w/ AutoIT.
+
+## Built With
+
+* [SciTE](https://www.autoitscript.com/site/autoit-script-editor/downloads/) - Customised version of SciTE with lots of additional coding tools for AutoIt
+* [AutoIT 3.3.14.2](https://www.autoitscript.com/) - Runtime & Build tools
+
+## License
+
+This project is licensed under the MIT License - see the [LICENSE.md](LICENSE.md) file for details