settings.gradle

plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'forgegradle'

include 'runtime-environment-check'

enableFeaturePreview 'TYPESAFE_PROJECT_ACCESSORS'

// Applying plugins causes them to not have any IDE support when also applied to any build.gradle files
// The workaround for now is to use this listener here so that it can stay in settings.gradle
// See: https://youtrack.jetbrains.com/issue/IDEA-332061/Gradle-Missing-Code-Completion-Suggestions-for-Settings-Plugins-in-Groovy-DSL
gradle.beforeProject { Project project ->
    project.pluginManager.withPlugin('net.minecraftforge.gradleutils') {
        project.repositories {
            mavenCentral()
            gradlePluginPortal()
            maven project.gradleutils.forgeMaven
            //mavenLocal()
        }
    }
}

//@formatter:off
dependencyResolutionManagement.versionCatalogs.register('libs') {
    version 'gradleutils', '3.4.3'

    plugin 'licenser',       'net.minecraftforge.licenser'    version '1.2.0' // https://plugins.gradle.org/plugin/net.minecraftforge.licenser
    plugin 'gradleutils',    'net.minecraftforge.gradleutils' versionRef 'gradleutils'
    plugin 'gitversion',     'net.minecraftforge.gitversion'  version '3.1.7' // https://plugins.gradle.org/plugin/net.minecraftforge.changelog
    plugin 'changelog',      'net.minecraftforge.changelog'   version '3.2.1' // https://plugins.gradle.org/plugin/net.minecraftforge.changelog
    plugin 'plugin-publish', 'com.gradle.plugin-publish'      version '2.0.0' // https://plugins.gradle.org/plugin/com.gradle.plugin-publish
    plugin 'shadow',         'com.gradleup.shadow'            version '9.3.0' // https://plugins.gradle.org/plugin/com.gradleup.shadow

    // Static Analysis
    library 'annotations-jspecify', 'org.jspecify', 'jspecify' version '1.0.0'

    // Gradle API
    // Original: https://github.com/remal-gradle-api/packages/packages/760197?version=9.0.0
    // Mirror:   https://repos.moddinglegacy.com/#/modding-legacy/name/remal/gradle-api/gradle-api/9.0.0
    version 'gradle', '9.3.0'
    library 'gradle', 'name.remal.gradle-api', 'gradle-api'  versionRef 'gradle'

    // GradleUtils Shared Base
    library 'gradleutils-shared', 'net.minecraftforge', 'gradleutils-shared' versionRef 'gradleutils'

    // Artifact Versioning
    library 'maven-artifact', 'org.apache.maven', 'maven-artifact' version '3.9.11'

    library 'utils-data',     'net.minecraftforge', 'json-data-utils' version '0.4.1'  // https://files.minecraftforge.net/net/minecraftforge/json-data-utils/index.html
    library 'utils-os',       'net.minecraftforge', 'os-utils'        version '0.1.0'  // https://files.minecraftforge.net/net/minecraftforge/os-utils/index.html
    library 'utils-hash',     'net.minecraftforge', 'hash-utils'      version '0.1.12' // https://files.minecraftforge.net/net/minecraftforge/hash-utils/index.html
    library 'utils-download', 'net.minecraftforge', 'download-utils'  version '0.4.0'  // https://files.minecraftforge.net/net/minecraftforge/download-utils/index.html
    bundle 'utils', ['utils-data', 'utils-os', 'utils-hash', 'utils-download']
}
//@formatter:on