FOLLOW.SC

(script# FOLLOW)

(class Follow kindof Motion
	;;; This class moves its client in such a way as to try and stay within
	;;; a certain distance to another object.
	
	(properties
		who 0					;who to follow
		distance 20			;try to stay at least this close to 'who'
	)
	
	
	(method (init theObj whom dist)
		
		(if (>= argc 1)			(= client theObj)
			(if (>= argc 2)		(= who whom)
				(if (>= argc 3)	(= distance dist)
				)
			)
		)
		
		
		;If the client is too far from the object being followed, start
		;moving toward it.
		(if (> (client distanceTo: who) distance)
			(super init: client (who x?) (who y?))
;			(super doit:)
		)
	)
	
	(method (onTarget)
		(<= (client distanceTo: who) distance)
	)
	
	(method (setTarget)
		(cond
			(argc	
				(super setTarget: &rest)
			)
			((not (self onTarget:))
				(super setTarget: (who x?) (who y?))
			)
		)
	)
	
	
	(method (doit &tmp angle)
		(if (> (client distanceTo: who) distance)
			;If too far from the object being followed, move toward it.
			(super doit:)
			(if (== b-moveCnt 0)
				(super init: client (who x?) (who y?))
			)
		else
			;The client is just standing around near its destination.  Pick
			;the loop which faces in the destination's direction.
			(= xLast (client x))
			(= yLast (client y))
			(= angle (GetAngle xLast yLast (who x?) (who y?)))
			(if (client looper?)
				((client looper?) doit: client angle)
			else
				(DirLoop client angle)
			)
		)
	)
	(method (moveDone)
		;;; When done with the current leg of wandering, re-init: the motion
		;;; to continue wandering.
	;		(self init: client distance)
	)
	
)