build.gradle

plugins {
    id "java"
    id "com.github.johnrengelman.shadow" version "6.1.0"
}

group = "fr.thesmyler"
version = "1.0." + ('git rev-list --count HEAD'.execute().text.trim())

repositories {
    
    mavenCentral()
    
    maven {
        name = "JitPack"
        url = "https://jitpack.io/"
    }
    
    maven { //used for leveldb
        name = "DaPorkchop_"
        url = "https://maven.daporkchop.net/"
    }

    maven {
        name = "PaperMC"
        url = "https://papermc.io/repo/repository/maven-public/"
    }
    
}

dependencies {

    // JUnit because test are always a plus
    testImplementation 'junit:junit:4.12'
    
    // Spark to handle those fancy web requests
    implementation 'com.sparkjava:spark-core:2.9.3'
    
    // Gson and Jackson to jsonnize and dejsonnize stuff
    implementation group: 'com.google.code.gson', name: 'gson', version: '2.8.5'
    implementation "com.fasterxml.jackson.core:jackson-databind:2.11.2"

    implementation group: 'org.slf4j', name: 'slf4j-jdk14', version: '1.7.29'

    implementation 'com.github.SmylerMC:terraminusminus:master-SNAPSHOT'
    
}

// Let build task generate a shadow jar
build.dependsOn shadowJar
configurations {
    shade
    compile.extendsFrom shade
}

// Generate jar manifest with main class
jar {
    manifest {
        attributes 'Main-Class': 'fr.thesmyler.smybteapi.SmyBteApi'
    }
}

processResources {

    // Redo when version changes
    inputs.property "version", project.version
    duplicatesStrategy = DuplicatesStrategy.INCLUDE

    // Expand version token
    from(sourceSets.main.resources.srcDirs) {
        include 'fr/thesmyler/smybteapi/version.properties'
        expand 'version': project.version
    }
    
}