Refactor project

Author: Tommy-Geenexus

.editorconfig

@@ -1,9 +1,6 @@
 root = true
 
-[*.{kt,kts}]
 # noinspection EditorConfigKeyCorrectness
-ktlint_standard_package-name = disabled
-ij_kotlin_allow_trailing_comma_on_call_site = false
-ij_kotlin_allow_trailing_comma = false
-trim_trailing_whitespace = true
-insert_final_newline = true
+[*.{kt,kts}]
+ktlint_code_style = android_studio
+ktlint_function_naming_ignore_when_annotated_with=Composable

app/build.gradle

@@ -0,0 +1,115 @@
+import com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask
+import io.gitlab.arturbosch.detekt.Detekt
+import io.gitlab.arturbosch.detekt.DetektCreateBaselineTask
+
+plugins {
+    alias(libs.plugins.android.application)
+    alias(libs.plugins.compose.compiler.report.generator)
+    alias(libs.plugins.dagger.hilt.android)
+    alias(libs.plugins.detekt)
+    alias(libs.plugins.kotlin.android)
+    alias(libs.plugins.kotlin.parcelize)
+    alias(libs.plugins.kotlinter)
+    alias(libs.plugins.ksp)
+    alias(libs.plugins.room)
+    alias(libs.plugins.spotless)
+    alias(libs.plugins.versions)
+}
+
+android {
+    namespace = "io.github.tommygeenexus.usbdonglecontrol"
+    compileSdk = 34
+
+    defaultConfig {
+        applicationId = "io.github.tommygeenexus.usbdonglecontrol"
+        minSdk = 31
+        targetSdk = 34
+        versionCode = 5
+        versionName = "2.1.0"
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = true
+            isShrinkResources = true
+            proguardFiles(
+                getDefaultProguardFile("proguard-android-optimize.txt"),
+                "proguard-rules.pro"
+            )
+        }
+    }
+
+    buildFeatures {
+        compose = true
+        buildConfig = true
+    }
+
+    composeOptions {
+        kotlinCompilerExtensionVersion = "1.5.8"
+    }
+
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_17
+        targetCompatibility = JavaVersion.VERSION_17
+    }
+
+    kotlinOptions {
+        jvmTarget = "17"
+    }
+}
+
+tasks.withType<DependencyUpdatesTask>().configureEach {
+    fun isNonStable(version: String): Boolean {
+        val stableKeyword = listOf("RELEASE", "FINAL", "GA").any { version.uppercase().contains(it) }
+        val regex = "^[0-9,.v-]+(-r)?$".toRegex()
+        val isStable = stableKeyword || regex.matches(version)
+        return isStable.not()
+    }
+    rejectVersionIf {
+        isNonStable(candidate.version) && !isNonStable(currentVersion)
+    }
+}
+
+tasks.withType<Detekt>().configureEach {
+    jvmTarget = "1.8"
+}
+
+tasks.withType<DetektCreateBaselineTask>().configureEach {
+    jvmTarget = "1.8"
+}
+
+detekt {
+    baseline = file("$projectDir/config/detekt/baseline.xml")
+    config.setFrom("$projectDir/config/detekt/detekt.yml")
+    buildUponDefaultConfig = true
+}
+
+kotlin {
+    compilerOptions {
+        freeCompilerArgs.addAll(
+            "-opt-in=androidx.compose.material3.ExperimentalMaterial3Api",
+            "-opt-in=com.google.accompanist.permissions.ExperimentalPermissionsApi",
+            "-opt-in=androidx.compose.material3.windowsizeclass.ExperimentalMaterial3WindowSizeClassApi",
+        )
+    }
+}
+
+room {
+    schemaDirectory("$projectDir/schemas/")
+}
+
+spotless {
+    kotlin {
+        ratchetFrom("origin/main")
+        target("**/*.kt")
+        licenseHeaderFile(rootProject.file("spotless/copyright.txt"))
+    }
+}
+
+dependencies {
+    debugImplementation(libs.leakcanary)
+    implementation(platform(libs.compose.bom))
+    implementation(libs.bundles.implementation)
+    ksp(libs.bundles.ksp)
+    lintChecks(libs.bundles.lint.checks)
+}