Property Cardinality quirk

[WolfgangFahl]

Based on the description in https://ceur-ws.org/Vol-3262/paper7.pdf i have checked the subclasses of "scientific event" with
the tool at http://wikidata.bitplan.com/

It seems to show that there are entries having multiple "country" properties as outlined by the query:

https://qlever.cs.uni-freiburg.de/wikidata/V84eip

# This query was generated by Truly Tabular
# Count all Q52260246:scientific event items
# with the given country(P17) https://www.wikidata.org/wiki/Property:P17 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?item ?itemLabel (COUNT (?value) AS ?count)
WHERE
{
  # instance of scientific event
  ?item wdt:P31+/wdt:P279* wd:Q52260246.
  ?item rdfs:label ?itemLabel.
  FILTER (LANG(?itemLabel) = "en").
  # country
  ?item wdt:P17 ?value.
} GROUP BY ?item ?itemLabel
HAVING (?count > 1)
ORDER BY DESC(?count)

When looking up the individual entries such as https://www.wikidata.org/wiki/Q57399115 the true reason for count being>1 seems to be the mulitple subclasses used not the multiple countries.

How would i have to change the query to counting the countries only?

I also think the wdt:P31+/wdt:P279* is slow and would love to find out the candidate subclasses in advanced to use a "values" clause for the subclass and instance classes instead or filtering out exotic ones such as https://www.wikidata.org/wiki/Q63980799 which seem to be irrelevant.

How could i do query and filter the subclasses in a separate step?

[WolfgangFahl]

The taxonomy for https://www.wikidata.org/wiki/Q52260246 seems to be quirky by itself.
Using the tool https://www.npmjs.com/package/wikidata-taxonomy we get:

wdtaxonomy Q52260246 -c
scientific event (Q52260246) ×14 ↑
├──sequencing (Q1764062) •20 ×1 ↑
├──academic conference (Q2020153) •31 ×8500 ↑↑
│  └──Archipel 2022 : Global systemic risks, trajectories and transdisciplinary levers for action (Q110895855) ↑
├──Lise Meitner Lectures (Q33240030) •3
├──academic workshop (Q40444998) ×4665 ↑↑
╞══Archipel 2022 : Global systemic risks, trajectories and transdisciplinary levers for action (Q110895855) ↑ …
└──hybrid scholarly conference (Q112748789) ×1 ↑

so basically only academic conference and academic workshop are interesting at this time.

[nichtich]

Best but most work would be to clean up the class hierarchy. Or stick to

{ { ?item wd:wdt:P31 wd:Q40444998 } UNION { ?item wd:wdt:P31 Q2020153 } }

and ignore the rest (less than 100 conferences you would miss by now).

[WolfgangFahl]

@nichtich Thx for the reply i agree with conferences/workshops being at the core of my work. Interesting that there seems to be no syntax element for the UNION i had hoped there would be an operator for this such as maybe “|". I already removed some IMHO invalid references. Only some scientific competitions seem to qualify as a separate specialization of "scientific event" besides conferences and workshops at this time. Wikipedia / Wikidata doesn't seem to differentiate colloquia or symposia - i also put some of these under the "conference" hat.

[tholzheim]

To select multiple objects I usually use the VALUES clause.

VALUES ?conf_type { wd:Q40444998 wd:Q2020153}
?item wdt:P31 ?conf_type.

ℹ️ UNION and VALUES result in multiple ?items if in this case both types are assigned to the item. So here you would need to aggregate the ?item set with SELECT DISTINCT as @hannahbast suggested.

[hannahbast]

@WolfgangFahl

1. Replace ?item wdt:P31+/wdt:P279* wd:Q52260246 by ?item wdt:P31/wdt:P279* wd:Q52260246. Reason: the schema of Wikdiata is such that an object of wdt:P31 is a type, which is then not again an instance of something (wdt:P31), but only a subclass of something (wdt:P279). It's also much faster that way.

2. If you want each ?item only once, replace the triple by the subquery { SELECT DISTINCT ?item WHERE { ?item wdt:P31/wdt:P279* wd:Q52260246 } }.

[tholzheim]

You can add DISTINCT to the count clause to only count the amount of different countries.

Changing (COUNT (?value) to (COUNT (DISTINCT ?value)

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?item ?itemLabel (COUNT (DISTINCT ?value) AS ?count)
WHERE 
{
  # instance of scientific event
  ?item wdt:P31+/wdt:P279* wd:Q52260246.
  ?item rdfs:label ?itemLabel.
  FILTER (LANG(?itemLabel) = "en").
  # country
  ?item wdt:P17 ?value.
} GROUP BY ?item ?itemLabel
HAVING (?count > 1)
ORDER BY DESC(?count)

Try it!