some new words in lib/midi.dc; and a microtonal riff example

Author: akjmicro

examples/edo_riff.dc

@@ -0,0 +1,98 @@
+"midi.dc" import
+
+17 midi_edo !
+
+: generate_interval
+  / log2 midi_edo @ * round
+;
+
+9 8 generate_interval const STEP
+6 5 generate_interval const MIN3
+6 5 generate_interval const THIRD
+3 2 generate_interval const FIFTH
+9 5 generate_interval const SEV
+
+create choices 0 , STEP , THIRD , FIFTH , SEV ,
+create lengths 0.25 , 0.25 ,
+create attacks 96 , 32 , 32 , 32 , 32 ,
+create modulations FIFTH , MIN3 , FIFTH , MIN3 ,
+var stopgap
+lengths choices - const CHOICES_SIZE
+CHOICES_SIZE 2 * const MEASURE
+stopgap modulations - const MODUSIZE
+var step
+0 step !
+var modulations_pointer
+0 modulations_pointer !
+
+: _advance_step
+  step @ 1 + step !
+;
+
+: _get_modulations_pointer
+  modulations_pointer @ dup
+  MODUSIZE =
+  if
+    drop
+    0
+  endif
+  dup 1 + modulations_pointer !
+;
+
+: _add_interval
+  svpush
+  CHOICES_SIZE times
+    choices i + @
+    0 svpick +   # interval on stack is added here
+    midi_edo @ %
+    choices i + !
+  again
+  svdrop
+  # lower first note (root) an octave
+  choices @ midi_edo @ -
+  choices !
+  choices CHOICES_SIZE sortnums
+;
+
+: _do_transposition
+  step @ MEASURE %
+  0 =
+  if
+    modulations
+    _get_modulations_pointer
+    + @
+    _add_interval
+  endif
+;
+
+: _get_edo_note
+  step @
+  CHOICES_SIZE %
+  choices + @
+  step @
+  CHOICES_SIZE %
+  attacks + @
+;
+
+: _get_length
+  rand 2 * round 2 %
+  lengths + @
+;
+
+: edo_riff
+  block_sigint
+  _get_edo_note
+  # stack: ( note attack ) ( )
+  over 0 edo_degree_to_midi
+  _get_length sleep
+  0 swap 0 edo_degree_to_midi
+  0.01 sleep
+  unblock_sigint
+  _advance_step
+  _do_transposition
+  edo_riff
+;
+
+edo_riff
+
+8192 0 0xE0 send_midi_reverse

examples/midi_change_ring.dc

@@ -7,18 +7,22 @@ var fpnt
 "change_ring.txt" "r" fopen fpnt !
 
 create pentatonic 50 , 52 , 55 , 57 , 60 ,
-create lengths     2 , 1 , 2 , 2 , 1 ,
+create lengths     1 , 1 , 1 , 1 , 1 , 1 , 1 , 1 ,
+create vols       96 , 96 , 96 , 96 , 96 , 0 , 0 , 0 ,
+5 const CYCLE_SIZE
 var length_idx
-0.16 const BASE_LEN
-BASE_LEN 0.97 * const ON_LEN
-BASE_LEN ON_LEN - const OFF_LEN
+0.152 const BASE_LEN
+BASE_LEN 0.95 * const ON_LEN
+BASE_LEN 0.05 * const OFF_LEN
 6 const TRANSPOSE
 
 : length_idx++ length_idx dup @ 1 + swap ! ;
 
-: _get_on_length lengths length_idx @ 5 % + @ ON_LEN * ;
+: _get_on_length lengths length_idx @ CYCLE_SIZE % + @ ON_LEN * ;
 
-: _get_off_length lengths length_idx @ 5 % + @ OFF_LEN * ;
+: _get_off_length lengths length_idx @ CYCLE_SIZE % + @ OFF_LEN * ;
+
+: _get_vol vols length_idx @ CYCLE_SIZE % + @ ;
 
 : _get_next
     strsav lnpnt fpnt
@@ -47,7 +51,7 @@ BASE_LEN ON_LEN - const OFF_LEN
         TRANSPOSE
       +
       dup svpush
-    96
+    _get_vol
   send_midi
   ###
   _get_on_length sleep

lib/midi.dc

@@ -5,6 +5,7 @@ var mididev
 var inbuf
 var direction
 var midi_ctl_slots 128 allot
+var midi_channel_last_note 16 allot
 
 : setup_port
     "DCLANG_MIDI_PORT_DIRECTION"
@@ -85,6 +86,17 @@ setup_port
   resetout
 ;
 
+: send_midi_reverse
+  # sometimes, it's easier to have the stack be queued out such
+  # the the top-of-stack goes out first. So, in this case, one would
+  # for example put the volumn, then the note, then the status_byte
+  # on the stack in that order. Then it's a simple matter of emitting
+  # three times with zero stack-dancing or svpush or swapping involved.
+  get_mididev redirect
+  emit emit emit
+  flush resetout
+;
+
 : panic
     get_mididev
   redirect
@@ -97,3 +109,49 @@ setup_port
   next
   resetout
 ;
+
+# words for microtonal/alternate tuning musical applications
+
+: _bend_to_MSB_LSB_bytes
+  # a helper function. Given a top-of-stack 14-byte integer MIDI
+  # pitch-bend amount, replace the top-of-stack with two bytes,
+  # the top-of-stack being the LSB (least significant byte) and the next
+  # being the most significant byte
+  dup 7 >>
+  swap 0x7f and
+;
+
+
+# Set the default variable 'midi_edo' to 31. Can be changed by the user later...
+var midi_edo
+31 midi_edo !
+
+: edo_degree_to_midi
+  # input stack (rightmost is "top":
+  # ( volume, edo_degree, midi_channel )
+  #
+  # Take an input edo degree, calculate the octave fraction against the global
+  # EDO constant, which must be declared ahead-of-time, and emit midi bytes
+  # to the configured MIDI output device which will sound the correct pitch
+  # Middle-C is assumed to be "0" in all EDOs, so use negative numbers to go
+  # below middle-C.
+  svpush              # sequester the channel number away
+  midi_edo @ / 12 *   # scale to 12-EDO with fractional remainder
+  60.5 +              # shift to middle-C in MIDI, also overshoot fractional
+  dup floor swap      # part on purpose so we can fetch the floor closest
+                      # to the proper midi number; set aside by swap
+  over - 0.5 -        # grab fractional part and cancel previous 0.5 shift
+  4096 *              # scale by positive half step of bend
+  8192 +              # center zero at halfway for +/-
+  # stack now looks like:
+  # ( volume midi_note_number midi_bend ) ( midi_channel )
+  _bend_to_MSB_LSB_bytes
+  # now we have
+  # ( volume midi_note_number bend_MSB bend_LSB ) ( midi_channel )
+  # send the bend
+  0 svpick 0xE0 +
+  send_midi_reverse
+  # send the note
+  svpop 0x90 +
+  send_midi_reverse
+;