global_10_16_00.asa

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">

'You can add special event handlers in this file that will get run automatically when special Active Server Pages events
'occur.  To create these handlers, just create a subroutine with a name from the list below that corresponds to the event
'you want to use.  For example, to create an event handler for Session_OnStart, you would put the following code into this
'file (without the comments):
'Sub Session_OnStart
'**Put your code here **
'End Sub

'EventName            Description
'Session_OnStart      Runs the first time a user runs any page in your application
'Session_OnEnd        Runs when a user's session times out or quits your application
'Application_OnStart  Runs once when the first page of your application is run for the first time by any user
'Application_OnEnd    Runs once when the web server shuts down
    
Sub Application_OnStart
	'==Visual InterDev Generated - startspan==
	'--Project Data Connection
		Application("DataConn_ConnectionString") = "DSN=Sark;User Id=IntraProd_User;PASSWORD=intraprod;UID=IntraProd_User;APP=Microsoft (R) Developer Studio;WSID=WINBOOKXL;DATABASE=IntranetProd"
		Application("DataConn_ConnectionTimeout") = 15
		Application("DataConn_CommandTimeout") = 30
		Application("DataConn_CursorLocation") = 3
		Application("DataConn_RuntimeUserName") = "IntraProd_User"
		Application("DataConn_RuntimePassword") = "intraprod"
	'-- Project Data Environment
		'Set DE = Server.CreateObject("DERuntime.DERuntime")
		'Application("DE") = DE.Load(Server.MapPath("Global.ASA"), "_private/DataEnvironment/DataEnvironment.asa")
	'==Visual InterDev Generated - endspan==

	'---------------------------------------------------------------------------
	' The following section was moved to Session_OnStart by Nick Yates
	'	on 3-29-2000.  The 401k and weather map were not updating because
	'	this section only gets run when the server is restarted.
	'----------------------------------------------------------------------------
	'----------------------------------------------
	'  Build weather, search and stock entries on  
	'  the right margin, replacing the section     
	'  preference buttons.                         
	'----------------------------------------------


	'-----------------------------
	'  Store all web site settings  
	'-----------------------------
  
	' SET DEBUGGING STATE  
	Application("debug") = false

	' SITE INFORMATION
	Application("Web") = "intranet"
	Application("WebStart") = Now
	Application("WebMaster") = "cdolan"
	Application("DefaultBranch") = "Cincinnati"
	Application("SiteVision") = "Supporting our branch through the sharing of knowledge..."
	Application("WebRootDir") = "d:\inetpub\"

	' SHARED DIRS INFORMATION
	Application("RootFileDir") = "\\ntserver-col\sys\Users"
	Application("OfficeDir") = "c:\WebDirs\OfficeDocs"
	
	' EMAIL INFORMATION
	Application("ExchangeServer") = "EDDY"
	Set Application("RenderApplication") = nothing
	set objRenderApp = Server.CreateObject("AMHTML.Application")
	if Err = 0 then Set Application("RenderApplication") = objRenderApp

	' LINK DESCRIPTIONS
	Application("LinkDesc_Welcome")		= "Welcome to our intranet site!"
	Application("LinkDesc_Directory")	= "Sark and branch info."
	Application("LinkDesc_Events")		= "Checkout upcoming events."
	Application("LinkDesc_News")		= "Stop on over at the Web Cafe."
	Application("LinkDesc_Technology")	= "Dive in to our technologies."
	Application("LinkDesc_Training")	= "Check out Training Classes."
	Application("LinkDesc_Preferences")	= "Customize your experience."
	Application("LinkDesc_Office")		= "Office docs, benefit info, etc."
	Application("LinkDesc_Email")		= "Access your email"
	Application("LinkDesc_Projects")	= "View client summaries."
	Application("LinkDesc_Sports")		= "For the latest in SARK sporting info."	
	Application("LinkDesc_Repository")		= "Solution Services document repository."		

	' DEFAULT NAVIGATION PREFERENCES
	Application("DefaultNavWelcome")	= "*preferences*"
	Application("DefaultNavDirectory")	= "*clients*details*"
	Application("DefaultNavEmail")		= "*email*"
	Application("DefaultNavEvents")		= "*calendar*addnew*"
	Application("DefaultNavNews")		= "*classifieds*"
	Application("DefaultNavOffice")		= "*documentlist*"
	Application("DefaultNavRecruiting")	= "*"
	Application("DefaultNavProjects")	= "*clients*"
	Application("DefaultNavTechnology")	= "*usergroups*"
	Application("DefaultNavTraining")	= "*cbtcourses*"
	Application("DefaultNavSports")		= "*wellness*basketball*"
	
	' CLEAR NAVIGATION PREFERENCES
	Application("ClearNavWelcome")		= ""
	Application("ClearNavDirectory")	= ""
	Application("ClearNavEmail")		= ""
	Application("ClearNavEvents")		= ""
	Application("ClearNavNews")			= ""
	Application("ClearNavOffice")		= ""
	Application("ClearNavRecruiting")
	Application("ClearNavProjects")		= ""
	Application("ClearNavTechnology")	= ""
	Application("ClearNavTraining")		= ""
	Application("ClearNavSports")		= ""
	
	' STORE SECTION BUTTONS
	'Application("WelcomeMargin") = sectionBtns

	' SET CONCURRENT USER SETTINGS
	Application("CurrentUsers") = 0
	

	'----------------------------
	'  Create new app log entry  
	'----------------------------

	' OPEN DATABASE CONNECTION
	set DataConn = Server.CreateObject("ADODB.Connection")
	DataConn.ConnectionTimeout = Application("DataConn_ConnectionTimeout")
	DataConn.CommandTimeout = Application("DataConn_CommandTimeout")
	DataConn.Open Application("DataConn_ConnectionString"), Application("DataConn_RuntimeUserName"), Application("DataConn_RuntimePassword")
	
	' INSERT APP LOG RECORD
	if Application("ID") = "" then
		set rs = DataConn.execute("insert into LogApp (AppStart) values ('" & Now & "')")
		set rs = DataConn.execute("select max(LogApp_ID) from LogApp")
		Application("ID") = rs(0)
		rs.close
		end if

	set rs = DataConn.execute("select Branch_ID from Branch where Branch_Name = '" & Application("DefaultBranch") & "'")
	if not rs.eof then
		Application("DefaultBranchID") = rs("Branch_ID")
		rs.close
		set rs = nothing
		end if

	' CLOSE DATABASE CONNECTION
	DataConn.close
	set DataConn = nothing
	
End Sub





Sub Application_OnEnd

	'----------------------------
	'  Update new app log entry  
	'----------------------------

	' OPEN DATABASE CONNECTION
	set DataConn = Server.CreateObject("ADODB.Connection")
	DataConn.ConnectionTimeout = Application("DataConn_ConnectionTimeout")
	DataConn.CommandTimeout = Application("DataConn_CommandTimeout")
	DataConn.Open Application("DataConn_ConnectionString"), Application("DataConn_RuntimeUserName"), Application("DataConn_RuntimePassword")
	
	' UPDATE APP LOG RECORD
	set rs = DataConn.execute("update LogApp set AppEnd = '" & Now & "' where LogApp_ID = " & Application("ID"))

	' CLOSE DATABASE CONNECTION
	DataConn.close
	set DataConn = nothing
	
	' DISPOSE OF RENDERAPP OBJECT
	set objRenderApp = Application("RenderApplication")
	if not objRenderApp is nothing then
		set objRenderApp = nothing
		set Application("RenderApplication") = nothing
		end if

End Sub





Sub Session_OnStart
	'==Visual InterDev Generated - DataConnection startspan==
	'--Project Data Connection
		Session("DataConn_ConnectionString") = "DSN=Sark;UID=IntraProd_User;PWD=intraprod;APP=Microsoft (R) Developer Studio;WSID=WINBOOKXL;DATABASE=IntranetProd"
		Session("DataConn_ConnectionTimeout") = 15
		Session("DataConn_CommandTimeout") = 30
		Session("DataConn_RuntimeUserName") = "IntraProd_User"
		Session("DataConn_RuntimePassword") = "intraprod"
	'==Visual InterDev Generated - DataConnection endspan==

	Session("Surveyed")=False
	
	on error resume next

	'Moved from Application_OnStart by Nick Yates(3-29-2000)
	'----------------------------------------------
	'  Build weather, search and stock entries on  
	'  the right margin, replacing the section     
	'  preference buttons.                         
	'----------------------------------------------
	Dim NL, sectionBtns
	NL = chr(13) & chr(10)
	sectionBtns = ""
	'WEATHER
	sectionBtns = sectionBtns & "Weather<br><table border=1 cellpadding=0 cellspacing=0><tr><td>"
	sectionBtns = sectionBtns & "<a href='javascript:showWeather()' onMouseOver='statusMap()' onMouseOut='statusNone()'><img name=map src='http://maps.weather.com/images/maps/current/cur_ec_277x187.jpg' alt='Weather maps' height=65 width=100 border=0></a>"
	sectionBtns = sectionBtns & "</td></tr></table>" & NL

	'Get 401K Information
	set fso = Server.CreateObject("Scripting.FileSystemObject")
	path = "d:\inetpub\intranet\content\stock.txt"
	if fso.FileExists(path) then
		set f = fso.GetFile(path)
		set ts = fso.OpenTextFile(path)
		stock_HTML = ts.ReadAll
		stock_HTML = Replace(stock_HTML, chr(34), "")
		DateTime = f.DateLastModified
		DateTime = MonthName(Month(DateTime),true) & " " & Day(DateTime) & ", " & Year(DateTime)
		sectionBtns = sectionBtns & "<p>401K Info <font color=silver>- " & DateTime & "</font><br>" & NL
		sectionBtns = sectionBtns & "<table border=1 cellpadding=0 cellspacing=0><tr><td><table border=0 cellpadding=2 cellspacing=0 bgcolor=#d0d0d0 width=115>" & NL
		sectionBtns = sectionBtns & stock_HTML & NL & "</table></td></tr></table>" & NL
		ts.close
	end if

	'SEARCH
	sectionBtns = sectionBtns & "<form name=frmSearch method=post action='searchFrame.asp'>"
	sectionBtns = sectionBtns & "Search the Web<br><input type=text class=fldSearch name=search size=12 maxlength=100>"
	sectionBtns = sectionBtns & "<input type=submit class=button value='Go' id=submit1 name=submit1>"
	sectionBtns = sectionBtns & "</form>" & NL
	'STOCKS
	sectionBtns = sectionBtns & "<form name=frmStock method=post action='stockFrame.asp'>"
	sectionBtns = sectionBtns & "Stock Lookup<br><input type=text class=fldSearch name=stock size=12 maxlength=100>"
	sectionBtns = sectionBtns & "<input type=submit class=button value='Go' id=submit1 name=submit1>"
	sectionBtns = sectionBtns & "</form>" & NL
	'PREFERENCES
	sectionBtns = sectionBtns & "<form id=form1 name=form1><input type=button class=button value='Preferences' onClick=" &chr(34)& "window.location='../../preferences/content/default.asp'" &chr(34)& " onMouseOver=" &chr(34)& " statmsg('View and set your preferences'); return true;" & chr(34) & "onMouseOut=" & chr(34) & "statmsg('')"& chr(34) & "></form>" & NL
	'EMAIL
	sectionBtns = sectionBtns & "<form id=form1 name=form1><input type=button class=button value='Quick email' onClick=" & chr(34) & "winTech=window.open('../../email.asp?editto=yes&footer=" & Server.URLEncode("INTRANET: Quick Email") & "', 'SendEmail','height=330,width=520,toolbar=0,location=0,directories=0,status=0,menubar=0,resizable=1, scrollbar=1'); return false;" & chr(34) & " onMouseOver=" &chr(34)& " statmsg('Send quick email to another Sark'); return true;" & chr(34) & "onMouseOut=" & chr(34) & "statmsg('')"& chr(34) & "></form>" & NL
	'FEEDBACK
	sectionBtns = sectionBtns & "<form id=form1 name=form1><input type=button class=button value='Feedback' onClick='SendFeedback()' onMouseOver=" &chr(34)& " statmsg('Send feedback email to webmaster(s).'); return true;" & chr(34) & "onMouseOut=" & chr(34) & "statmsg('')"& chr(34) & " id=button1 name=button1></form>" & NL
	'IE5
	sectionBtns = sectionBtns & "<table border=1 cellpadding=0 cellspacing=0><tr><td>"
	'sectionBtns = sectionBtns & "<a href='http://www.microsoft.com/windows/ie/default.htm' target='_blank'><img src='../../lgoIE.gif' alt='IE5 Download' height=68 width=73 border=0></a>"
	sectionBtns = sectionBtns & "<a href='http://www.microsoft.com/windows/ie/default.htm' target='_blank'><img src='../../IE4get_animated.gif' alt='IE5 Download' height=31 width=81 border=0></a>"
	sectionBtns = sectionBtns & "</td></tr></table>" & NL

	'--------------------------------------
	' Store sectionBtns as session var
	'--------------------------------------
	session("WelcomeMargin") = sectionBtns
	
	'--------------------------------------
	'  Store session information for user  
	'--------------------------------------

	' STORE CURRENT SESSION START
	Session("Now") = Now

	' INIT EMAIL SESSION CACHE
	set Session("hImp") = 0                    ' NT Security impersonation
	set Session("MAPIsession") = nothing       ' MAPI session with Exchange
	
	' STORE NT AUTHENTICATION LOGIN
	NTUser = lcase(Request.ServerVariables("LOGON_USER"))
	i = instr(NTUser, "\")
	if i > 0 then NTUser = mid(NTUser, i+1)
	i = instr(NTUser, "/")
	if i > 0 then NTUser = mid(NTUser, i+1)
	if right(NTUser, 6) = "_admin" then NTUser = left(NTUser, len(NTUser)-6)
	Session("Username") = NTUser

	' GET USER BROWSER INFORMATION
	Set BrowserType = Server.CreateObject("MSWC.BrowserType")
	Session("BrowserName") = BrowserType.Browser
	Session("BrowserVersion") = BrowserType.Version
	Session("BrowserVersionMajor") = BrowserType.MajorVer
	Session("BrowserVersionMinor") = BrowserType.MinorVer
	set BrowserType = nothing

	' OPEN DATABASE CONNECTION
	set DataConn = Server.CreateObject("ADODB.Connection")
	DataConn.ConnectionTimeout = Session("DataConn_ConnectionTimeout")
	DataConn.CommandTimeout = Session("DataConn_CommandTimeout")
	DataConn.Open Session("DataConn_ConnectionString"), Session("DataConn_RuntimeUserName"), Session("DataConn_RuntimePassword")

	' GET ADDITIONAL USER INFORMATION
	Session("OfficeStaff") = false
	Session("LongName") = "[Unknown]"
	
	
	'(((((((((((((((((((((((((((((((((((((((
	'
	' Modified 02/24/2000 by GTYLER
	'
	sql =	"SELECT e.LastName, e.FirstName, e.Username, e.EmployeeID, e.VoiceMail, et.Title_Function_ID, et.Title_Level " &_
			"FROM employee e INNER JOIN Employee_Title et ON e.EmployeeTitle_ID = et.Employee_Title_ID " &_
			"WHERE e.Username = '" & ucase(NTUser) & "'"
	'sql =	"SELECT e.LastName, e.FirstName, e.Username, e.Employee_ID, e.VoiceMail, et.Title_Function_ID, et.Title_Level " &_
	'		"FROM v_employee e INNER JOIN Employee_Title et ON e.EmployeeTitle_ID = et.Employee_Title_ID " &_
	'		"WHERE e.Username = '" & ucase(NTUser) & "'"

	set rs = DataConn.execute(sql)
	If Not rs.EOF Then
		Session("Name") = rs("lastname") & ", " & rs("firstname")
		Session("LongName") = rs("firstname") & " " & rs("lastname")
		Session("FirstName") = rs("firstname")

		'(((((((((((((((((((((((((((((((((((((((
		'
		' Modified 02/24/2000 by GTYLER
		'
		Session("ID") = rs("EmployeeID")
		'Session("ID") = rs("Employee_ID")

		Session("TitleType") = rs("Title_Function_ID")
		Session("TitleLevel") = rs("Title_Level")
		if not isnull(rs("VoiceMail")) then Session("OfficeStaff") = true
		
		Session("GotID") = true
	Else
		Session("GotID") = false
	End If
	rs.close
	
	
	
	'(((((((((((((((((((((((((((((((((((((((
	'
	' Modified 08/03/2000 by SSeissiger
	'
	sql =	"SELECT EmployeeID, EmployeeTitle_ID FROM employee " &_
					"WHERE EmployeeID = " & Session("ID")
					
	set rs = DataConn.execute(sql)
	Session("titleID") = rs("EmployeeTitle_ID")
	
	If (Session("titleID") = 5 )or (Session("titleID") = 6) or (Session("titleID") = 13) Then
		Session("GotAcctMgr") = true
	Else
		Session("GotAcctMgr") = false
	End If
	rs.close
	
	'--------------------------------------------------------------------
	' Added by Dave Podnar on 8/3/2000
	' Determines if the current user is a member of Solution Services. 
	' If so, they can view the repository.
	'--------------------------------------------------------------------
	sql = "SELECT Tech_Specialists.Tech_Specialist_Type_ID, " _
			& " Employee.Username, Employee.EmployeeID " _
			& " FROM Employee, Tech_Specialists " _
			& " WHERE Employee.Username = '" & Lcase(session("Username")) & "' " _
			& " AND Employee.EmployeeID = Tech_Specialists.Employee_ID " _
			& " AND (Tech_Specialists.Tech_Specialist_Type_ID = 1 OR Tech_Specialists.Tech_Specialist_Type_ID = 2) "

	set rs = DataConn.execute(sql)

	If Not rs.eof Or Lcase(session("Username"))="dschrader" Or Lcase(session("Username"))="ggelasi" Or Lcase(Session("username")) = Lcase(Application("WebMaster")) Then
		Session("isSolutionServices")=True
	Else
		Session("isSolutionServices")=False
	End If
	
	rs.close

	'--------------------------------------------------------------------
	' Added by Dave Podnar on 8/15/2000
	' Determines if the current user has filled out the online survey.
	'--------------------------------------------------------------------
	sql = "SELECT Online_Survey.EmployeeID FROM Online_Survey " _
	& " WHERE Online_Survey.EmployeeID = " & Session("ID")
	
	set rs = DataConn.execute(sql)

	If Not rs.eof Then
		Session("Surveyed")=True
	End If
	
	rs.close
	
	' STORE HIT INFORMATION
	on error resume next
	set rs = DataConn.execute("insert into LogSession (LogApp_ID, LogSession_ID, Username, SessionStart, BrowserName, BrowserVersion) VALUES (" & Application("ID") & ", " & Session.SessionID & ",'" & ucase(Session("Username")) & "', '" & Session("Now") & "', '" & Session("BrowserName") & "','" & Session("BrowserVersion") & "')")
	set rs = DataConn.execute("update LogSession set SessionEnd = null where LogApp_ID = " & Application("ID") & " and LogSession_ID = " & Session.SessionID)
	on error goto 0
	
	' CLOSE DATABASE CONNECTION
	DataConn.close
	set DataConn = nothing


	'Get Weather Information
	set fso = Server.CreateObject("Scripting.FileSystemObject")
	path = "d:\inetpub\intranet\content\weather.txt"
	set ts = fso.OpenTextFile(path)
	session("sW_HTML") = ts.ReadAll
	session("sW_HTML") = Replace(session("sW_HTML"), chr(34), "")
	ts.close
	
	'Get CNET News
	path = "d:\inetpub\intranet\content\cnet.txt"
	set ts = fso.OpenTextFile(path)
	session("sCNet_HTML") = ts.ReadAll
	session("sCNet_HTML") = Replace(session("sCNet_HTML"), chr(34), "")
	ts.close
	
	'Get Announcements
	set fso = Server.CreateObject("Scripting.FileSystemObject")
	path = "d:\inetpub\intranet\welcome\announcements\announcements1.txt"
	set ts = fso.OpenTextFile(path)
	session("sAnnouncements") = ts.ReadAll
	ts.close
	
	'Insert another file here
	path = "d:\inetpub\intranet\welcome\announcements\announcements2.txt"
	set ts = fso.opentextfile(path)
	session("sAnnouncements") = session("sAnnouncements") & ts.ReadAll
	ts.close

	'Added on 07/11/2000 by SHSMITH
	'Insert two edit buttons for the Webmaster to update each announcement
	'If Ucase(Session("Username")) = Ucase(Application("WebMaster")) Then
	'	  session("sAnnouncements") = session("sAnnouncements") &_
	'	      "<CENTER><INPUT TYPE=button class=button NAME='EditOne' " & _
	'	          "VALUE = 'Edit One' OnClick='window.location=" & chr(34) & "update.asp?Announcement_ID=1" & chr(34)& "' >"
	'	        
    ' session("sAnnouncements") = session("sAnnouncements") &_
  	'      "<INPUT TYPE=button class=button NAME='EditTwo' " & _
	'	          "VALUE = 'Edit Two' OnClick='window.location=" & chr(34) & "update.asp?Announcement_ID=2" & chr(34) & "' ></CENTER"
	'End If
	
	'--------------------------------------
	'  Set web site user counters          
	'--------------------------------------

	' INCREMENT CONCURRENT USER COUNTER
	Application.Lock
	Application("CurrentUsers") = Application("CurrentUsers") + 1
	Application.Unlock

End Sub





Sub Session_OnEnd

	on error resume next
	
	
	'--------------------------------------
	'  Store session information for user  
	'--------------------------------------

	' OPEN DATABASE CONNECTION
	set DataConn = Server.CreateObject("ADODB.Connection")
	DataConn.ConnectionTimeout = Session("DataConn_ConnectionTimeout")
	DataConn.CommandTimeout = Session("DataConn_CommandTimeout")
	DataConn.Open Session("DataConn_ConnectionString"), Session("DataConn_RuntimeUserName"), Session("DataConn_RuntimePassword")

	' UPDATE USER SESSION INFO
	set rs = DataConn.execute("update LogSession set SessionEnd = '" &  Now  & "' where LogApp_ID = " & Application("ID") & " and LogSession_ID = " & Session.SessionID)

	' CLOSE DATABASE CONNECTION
	DataConn.close
	set DataConn = nothing

	'--------------------------------------
	'  Cleanup after email
	'--------------------------------------

	' IMPERSONATE APPROPRIATE USER'S NT SECURITY
	set objRenderApp = Application("RenderApplication")
	fRevert = false
	hImp = Session("hImp")
	if not IsEmpty(hImp) then fRevert = objRenderApp.Impersonate(hImp)

	' CLEAN OUT EMAIL FOLDER CACHE
	set Session("/Inbox") = nothing
	set Session("/") = nothing
	
	' LOGOFF MAIL & CLEANUP OBJECTS
	set objOMSession = Session("MAPIsession")
	if not objOMSession is Nothing then
		set Session("MAPIsession") = nothing
		objOMSession.Logoff
		set objOMSession = nothing
		end if

	' REVERT SECURITY TO NON-AUTHENTICATED
	if (fRevert) then objRenderApp.Impersonate(0)

	'--------------------------------------
	'  Set web site user counters          
	'--------------------------------------

	Application.Lock
	Application("CurrentUsers") = Application("CurrentUsers") - 1
	Application.Unlock

End Sub


</SCRIPT>