build.gradle

buildscript {
    repositories {
        mavenLocal()
        repositories {
            maven {
                url "https://plugins.gradle.org/m2/"
            }
        }
    }
    dependencies {
        classpath("de.undercouch:gradle-download-task:5.5.0")
        // From v6.14.0 (inc.) Java 8 support is dropped
        classpath("com.diffplug.spotless:spotless-plugin-gradle:6.13.0")
    }
}


apply plugin: "java-library"
apply plugin: "jvm-test-suite"
apply plugin: "idea"
apply plugin: "eclipse"
apply plugin: "jacoco"

defaultTasks 'clean', 'test', 'build'
description = 'Gradle configuration for Solr Lucene Analyzer Sudachi'

compileJava {
    options.encoding = 'UTF-8'
    options.compilerArgs << '-parameters' << '-Xlint:deprecation'
}

compileTestJava {
    options.encoding = 'UTF-8'
}

javadoc {
    if (JavaVersion.current().isJava8Compatible()) {
        options.addStringOption('Xdoclint:none', '-quiet')
    }
}

java {
    toolchain {
        // https://issues.apache.org/jira/browse/LUCENE-8738 Min version is JDK 11
        languageVersion = JavaLanguageVersion.of(11)
    }
}

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        url "https://maven.restlet.talend.com"
    }
}

apply from: "$rootDir/conf/gradle/dependencies.gradle"
apply from: "$rootDir/conf/gradle/tests.gradle"
apply from: "$rootDir/conf/gradle/sudachi.gradle"
apply from: "$rootDir/conf/gradle/spotless.gradle"
apply from: "$rootDir/conf/gradle/artifacts.gradle"