chore: init repo

Author: Pierre Ugaz

README.md

@@ -0,0 +1,19 @@
+# k8s Route53 subzone
+
+Create a subzone for a kubernetes cluster from an existing hosted zone in Route53
+
+```hcl
+module "subzone" {
+  source      = "./"
+  main_domain = var.main_domain
+  zone_domain = var.resource_name
+}
+```
+
+|Variable|Description|Required|Value|
+|---|---|---|---|
+|`main_domain`|Domain to create the subzone from|X||
+|`main_private`|Wether the main domain is private or not||`false`|
+|`zone_prefixes`|Prefixes list for hosted zones to be created (e.g. `["dev", "qa"]`)|X||
+|`zone_force_destroy`|Wether the subzone should force-destroyed upon destruction removing all records or not||`true`|
+|`zone_record_ttl`|TTL for subzone NS record||`"30"`|

local.tf

@@ -0,0 +1,6 @@
+locals {
+  api_server_records = compact(var.api_server_lb)
+  hosted_zone        = format("%s.%s", var.zone_prefix, var.main_domain)
+  records            = [aws_route53_record.record, aws_route53_record.zone, aws_route53_zone.zone]
+  zone_records       = list(local.hosted_zone, format("dex.%s", local.hosted_zone))
+}

main.tf

@@ -0,0 +1,26 @@
+data aws_route53_zone main {
+  name         = var.main_domain
+  private_zone = var.main_private
+}
+
+resource aws_route53_zone zone {
+  force_destroy = var.zone_force_destroy
+  name          = local.hosted_zone
+}
+
+resource aws_route53_record zone {
+  name    = local.hosted_zone
+  records = aws_route53_zone.zone.name_servers
+  ttl     = var.record_ttl
+  type    = "NS"
+  zone_id = data.aws_route53_zone.main.zone_id
+}
+
+resource aws_route53_record record {
+  count   = length(local.zone_records)
+  name    = element(local.zone_records, count.index)
+  records = local.api_server_records
+  ttl     = var.record_ttl
+  type    = "A"
+  zone_id = aws_route53_zone.zone.zone_id
+}

output.tf

@@ -0,0 +1,6 @@
+output api_server_fqdn { value = aws_route53_record.record.0.fqdn }
+output dex_fqdn { value = aws_route53_record.record.1.fqdn }
+output name_servers { value = aws_route53_zone.zone.name_servers }
+output record { value = local.records }
+output zone_id { value = aws_route53_zone.zone.zone_id }
+output zone_record_name { value = aws_route53_record.zone.name }

vars.tf

@@ -0,0 +1,6 @@
+variable api_server_lb { default = [] }
+variable main_domain { type = string }
+variable main_private { default = false }
+variable record_ttl { default = "30" }
+variable zone_force_destroy { default = true }
+variable zone_prefix { type = string }

versions.tf

@@ -0,0 +1,8 @@
+terraform {
+  required_providers {
+    aws = {
+      source = "hashicorp/aws"
+    }
+  }
+  required_version = ">= 0.13"
+}