BREAKING_CHANGE: cmake install now works, combined target name changed from all to ut

Author: dk949

CMakeLists.txt

@@ -1,22 +1,30 @@
 cmake_minimum_required(VERSION 3.21)
-project(libut LANGUAGES CXX)
+project(
+    libut
+    VERSION 0.1.0
+    DESCRIPTION "Various useful bits of C++"
+    HOMEPAGE_URL "https://github.com/dk949/libut"
+    LANGUAGES CXX
+)
+include(cmake/install.cmake)
 include(cmake/targets.cmake)
 
 file(GLOB includes "${CMAKE_CURRENT_SOURCE_DIR}/include/*")
 
-add_library(all INTERFACE)
+add_library(ut INTERFACE)
 foreach (include ${includes})
     add_subdirectory("${include}")
     cmake_path(GET include FILENAME module_name)
-    target_link_libraries(all INTERFACE "${module_name}")
+    target_link_libraries(ut INTERFACE "${module_name}")
     list(APPEND LIBUT_TARGET_LIST "${module_name}")
 endforeach ()
-list(APPEND LIBUT_TARGET_LIST all)
+list(APPEND LIBUT_TARGET_LIST ut)
 set(LIBUT_TARGET_LIST
     "${LIBUT_TARGET_LIST}"
     CACHE INTERNAL "" FORCE
 )
-message(STATUS "libut: adding UT::all")
+message(STATUS "libut: adding UT::ut")
+libut_install()
 
 if (PROJECT_IS_TOP_LEVEL)
     option(ENABLE_TESTING "Should tests be enabled?" ON)

README.md

@@ -2,7 +2,7 @@
 
 [![CMake build and test](https://github.com/dk949/libut/actions/workflows/cmake-multi-platform.yml/badge.svg)](https://github.com/dk949/libut/actions/workflows/cmake-multi-platform.yml)
 
-    Various useful bits of c++
+    Various useful bits of C++
 
 This is header only C++ library for doing useful things. Such as printing human
 readable type names, converting `string_view`s to numbers. See the [Currently
@@ -67,7 +67,7 @@ target_link_libraries(MY_TARGET UT::target_name)
 
 <!-- AUTOGEN_END -->
 
-A special target `UT::all` is also available, combining all of the above.
+A special target `UT::ut` is also available, combining all of the above.
 
 ## Testing
 

cmake/UTConfig.cmake.in

@@ -0,0 +1,4 @@
+@PACKAGE_INIT@
+
+# Let the config file find the targets file installed by install(EXPORT)
+include("${CMAKE_CURRENT_LIST_DIR}/UTTargets.cmake")

cmake/install.cmake

@@ -0,0 +1,34 @@
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+function (libut_install)
+    install(
+        TARGETS ${LIBUT_TARGET_LIST}
+        EXPORT UTTargets
+        FILE_SET HEADERS
+        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+    )
+
+    install(
+        EXPORT UTTargets
+        NAMESPACE UT::
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/ut
+    )
+
+    configure_package_config_file(
+        "${CMAKE_CURRENT_LIST_DIR}/cmake/UTConfig.cmake.in" "${CMAKE_CURRENT_BINARY_DIR}/UTConfig.cmake"
+        INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/ut"
+        NO_CHECK_REQUIRED_COMPONENTS_MACRO
+    )
+
+    write_basic_package_version_file(
+        "${CMAKE_CURRENT_BINARY_DIR}/UTConfigVersion.cmake"
+        VERSION ${PROJECT_VERSION}
+        COMPATIBILITY AnyNewerVersion
+    )
+
+    install(FILES "${CMAKE_CURRENT_BINARY_DIR}/UTConfig.cmake"
+                  "${CMAKE_CURRENT_BINARY_DIR}/UTConfigVersion.cmake"
+            DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/ut
+    )
+endfunction ()

tests/CMakeLists.txt

@@ -54,7 +54,7 @@ check_source_compiles(
 endblock()
 
 function (setup_target target)
-    target_link_libraries(${target} PRIVATE UT::all)
+    target_link_libraries(${target} PRIVATE ut)
     set_target_warnings(${target})
     target_link_libraries(${target} PRIVATE Catch2::Catch2WithMain)
     target_precompile_headers(${target} PRIVATE <catch.hpp>)