window-name

#!/usr/bin/env bb
(require '[babashka.process :as p :refer [shell process destroy-tree]]
         '[clojure.java.io :as io])

(defn split [cmd]
  (str/split cmd #"\|"))

(def window-stream
  (process
   {:err :inherit
    :shutdown destroy-tree}
   (str "swaymsg -t subscribe -m \"['window']\"")))

(defn gtk-theme []
  (-> {:out :string}
      (shell "gsettings get org.gnome.desktop.interface icon-theme")
      :out
      str/split-lines
      first
      (str/replace #"'" "")))

(defn flatpak-name [class]
  (->> (shell {:out :string} "flatpak list --app")
       :out
       str/split-lines
       (some
        (fn [line]
          (let [[name id & _] (str/split line #"\t")]
            (when (= name class)
              id))))))

(defn find-icon [name]
  (when name
    (first
     (remove
      nil?
      (flatten
       (for [theme [(gtk-theme) "hicolor"]]
         (for [path ["scalable/apps" "apps/scalable"]]
           (for [file [name (str/lower-case name) (flatpak-name name)]]
             (for [root ["/usr/local/share/icons" "/usr/share/icons" "~/.icons" "~/.local/share/icons" "/var/lib/flatpak/exports/share/icons"]]
               (let [file (fs/expand-home (fs/path root theme path (str file ".svg")))]
                 (when (fs/exists? file)
                   (str file))))))))))))

(def get-icon (memoize find-icon))

(defn- get-tree []
  (as-> (str "swaymsg -t get_tree") clients
    (shell {:out :string} clients)
    (:out clients)
    (json/parse-string clients true)))

(->>
 (tree-seq map? :nodes (get-tree))
 (keep (fn [{:keys [focused name app_id window_properties]}]
         (when focused
           {:name name
            :icon (or (get-icon app_id)
                      (get-icon (:instance window_properties))
                      (get-icon (:class window_properties))
                      "")})))
 first
 json/generate-string
 println)

(with-open [rdr (io/reader (:out window-stream))]
  (binding [*in* rdr]
    (loop []
      (when-let [line (-> (read-line) (json/parse-string true))]
        (->>  {:name (get-in line [:container :name])
               :icon (or (get-icon (get-in line [:container :app_id]))
                         (get-icon (get-in line [:container :window_properties :class]))
                         (get-icon (get-in line [:container :window_properties :instance]))
                         "")}
              json/generate-string
              println)
        (recur)))))