Works on Acer Predator Helios Neo 16 (PHN16-71) + Package for nix!

[itm154]

Works fine on my Helios even with NixOS. For anyone who's using it here's the package, you may need to change some things. You also might want to use the acer-predator-turbo-and-rgb-keyboard-linux-module (with nix)

./packages/acer-wmi-battery/default.nix

{
  stdenv,
  lib,
  fetchFromGitHub,
  pkgs,
  kernel ? pkgs.linuxPackages_zen.kernel, # You might need to change this depending on the kernel you're using
  kmod,
}:
stdenv.mkDerivation rec {
  name = "acer-wmi-battery-${version}-${kernel.version}";
  version = "0.1.0";

  src = fetchFromGitHub {
    owner = "frederik-h";
    repo = "acer-wmi-battery";
    rev = "v${version}";
    sha256 = "0b8h4qgqdgmzmzb2hvsh4psn3d432klxdfkjsarpa89iylr4irfs";
  };

  setSourceRoot = ''export sourceRoot=$(pwd)/source'';
  nativeBuildInputs = kernel.moduleBuildDependencies;

  makeFlags =
    kernel.makeFlags
    ++ [
      "-C"
      "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
      "M=$(sourceRoot)"
    ];
  buildFlags = ["modules"];
  installFlags = ["INSTALL_MOD_PATH=${placeholder "out"}"];
  installTargets = ["modules_install"];

  meta = with lib; {
    description = "A linux kernel driver for the Acer WMI battery health control interface";
    homepage = "https://github.com/frederik-h/acer-wmi-battery";
    license = licenses.gpl2;
    maintainers = [maintainers.itm154];
    platforms = platforms.linux;
  };
}

./{your nixos/hardware config}

{
  config,
  lib,
  pkgs,
  modulesPath,
  ...
}: let
. . .
# Im using snowfall-lib here so you might need to change this to use callpackage
# acer-wmi-battery = config.boot.kernelPackages.callPackage ./acer-wmi-battery.nix {};
  acer-wmi-battery = pkgs.custom.acer-wmi-battery; 
. . .
in {
. . .
# Dont forget to include these
  boot.extraModulePackages = [acer-wmi-battery];
  boot.kernelModules = ["wmi" "acer-wmi-battery"];
. . .
}

Then you can use the commands from the instructions
echo 1 | sudo tee /sys/bus/wmi/drivers/acer-wmi-battery/health_mode etc...