Add editor plugin with Lua REPL

Author: gilzoide

README.md

@@ -22,6 +22,7 @@ This plugin is available in the Asset Library as [Lua GDExtension](https://godot
     + Global enums, like `OK`, `TYPE_STRING` and `SIDE_LEFT`
     + (TODO) Patch Lua `package.searchers` to accept paths relative to `res://` and `user://`
 - Create Godot scripts directly in Lua
+- Editor plugin with Lua REPL for testing out Lua snippets
 
 
 ## Calling Lua from Godot
@@ -201,7 +202,7 @@ return LuaBouncingLogo
 - [ ] Use framework in iOS (possibly a xcframework supporting the iOS simulator as well)
 - [X] Automated unit tests
 - [X] Automated build and distribution
-- [ ] Lua REPL editor plugin
+- [X] Lua REPL editor plugin
 
 
 ## Other projects for using Lua in Godot 4

addons/lua-gdextension/lua_repl.gd

@@ -0,0 +1,132 @@
+# Copyright (C) 2025 Gil Barbosa Reis.
+# 
+# Permission is hereby granted, free of charge, to any person obtaining a copy of
+# this software and associated documentation files (the “Software”), to deal in
+# the Software without restriction, including without limitation the rights to
+# use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies
+# of the Software, and to permit persons to whom the Software is furnished to do
+# so, subject to the following conditions:
+# 
+# The above copyright notice and this permission notice shall be included in all
+# copies or substantial portions of the Software.
+# 
+# THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+@tool
+extends Node
+
+@onready var _output: RichTextLabel = $Output
+@onready var _input: LineEdit = $Footer/Input
+@onready var _history_popup: PopupMenu = $Header/HistoryButton.get_popup()
+var _lua: LuaState
+var _history = PackedStringArray()
+var _current_history = 0
+
+
+func _ready():
+	_history_popup.about_to_popup.connect(_on_history_popup_about_to_popup)
+	_history_popup.id_pressed.connect(_on_history_popup_id_pressed)
+	reset()
+
+
+func reset():
+	_lua = LuaState.new()
+	_lua.open_libraries()
+	_lua.registry.print = _printn
+	_lua.do_string(r"print = function(...) debug.getregistry().print(table.concat({...}, '\t')) end")
+	
+	_history.clear()
+	_current_history = 0
+	clear()
+
+
+func do_string(text: String):
+	text = text.strip_edges()
+	if text.is_empty():
+		return
+	
+	_history.append(text)
+	_current_history = _history.size()
+	_input.clear()
+	_printn(text)
+	
+	# support for "= value" idiom from Lua 5.1 REPL
+	text.trim_prefix("=")
+	
+	var result = _lua.do_string("return " + text)
+	if result is LuaError:
+		result = _lua.do_string(text)
+	
+	if result is LuaError:
+		_print_error(result.message)
+	else:
+		_printn("Out[%d]: %s" % [_current_history, result])
+	_prompt()
+
+
+func clear():
+	_output.clear()
+	_prompt()
+
+
+func set_history(index: int):
+	if index < 0 or index >= _history.size():
+		return
+	
+	_current_history = index
+	var text = _history[index]
+	_input.text = text
+	_input.caret_column = text.length()
+
+
+func _prompt():
+	_print("\nIn [%d]: " % [_current_history + 1])
+
+
+func _print(msg: String):
+	self._output.add_text(msg)
+
+
+func _printn(msg: String):
+	_print(msg)
+	_print("\n")
+
+
+func _print_error(msg: String):
+	var color: Color = EditorInterface.get_editor_settings().get_setting("text_editor/theme/highlighting/brace_mismatch_color")
+	self._output.append_text("[color=%s]%s[/color]\n" % [color.to_html(), msg.replace("[", "[lb]")])
+
+
+func _on_history_popup_about_to_popup():
+	_history_popup.clear()
+	for line in _history:
+		_history_popup.add_item(line)
+
+
+func _on_history_popup_id_pressed(id: int):
+	set_history(id)
+
+
+func _on_input_text_submitted(new_text: String):
+	do_string(new_text)
+
+
+func _on_run_button_pressed():
+	do_string(_input.text)
+
+
+func _on_input_gui_input(event: InputEvent):
+	var key_event = event as InputEventKey
+	if not key_event or not key_event.pressed:
+		return
+	
+	if key_event.keycode == KEY_UP:
+		set_history(_current_history - 1)
+	elif key_event.keycode == KEY_DOWN:
+		set_history(_current_history + 1)

addons/lua-gdextension/lua_repl.gd.uid

@@ -0,0 +1 @@
+uid://bjod0yq2efea8

addons/lua-gdextension/lua_repl.tscn

@@ -0,0 +1,59 @@
+[gd_scene load_steps=2 format=3 uid="uid://4lq5s4lnqg8c"]
+
+[ext_resource type="Script" uid="uid://bjod0yq2efea8" path="res://addons/lua-gdextension/lua_repl.gd" id="1_gf8ka"]
+
+[node name="LuaRepl" type="VBoxContainer"]
+anchors_preset = 15
+anchor_right = 1.0
+anchor_bottom = 1.0
+grow_horizontal = 2
+grow_vertical = 2
+script = ExtResource("1_gf8ka")
+
+[node name="Header" type="HBoxContainer" parent="."]
+layout_mode = 2
+
+[node name="Title" type="Label" parent="Header"]
+layout_mode = 2
+size_flags_horizontal = 3
+text = "Lua REPL"
+
+[node name="HistoryButton" type="MenuButton" parent="Header"]
+layout_mode = 2
+text = "History"
+flat = false
+
+[node name="ResetButton" type="Button" parent="Header"]
+layout_mode = 2
+tooltip_text = "Reset the Lua environment and REPL history"
+text = "Reset"
+
+[node name="ClearButton" type="Button" parent="Header"]
+layout_mode = 2
+tooltip_text = "Clear the output text"
+text = "Clear"
+
+[node name="Output" type="RichTextLabel" parent="."]
+layout_mode = 2
+size_flags_vertical = 3
+focus_mode = 2
+scroll_following = true
+selection_enabled = true
+
+[node name="Footer" type="HBoxContainer" parent="."]
+layout_mode = 2
+
+[node name="Input" type="LineEdit" parent="Footer"]
+layout_mode = 2
+size_flags_horizontal = 3
+keep_editing_on_text_submit = true
+
+[node name="RunButton" type="Button" parent="Footer"]
+layout_mode = 2
+text = "Run"
+
+[connection signal="pressed" from="Header/ResetButton" to="." method="reset"]
+[connection signal="pressed" from="Header/ClearButton" to="." method="clear"]
+[connection signal="gui_input" from="Footer/Input" to="." method="_on_input_gui_input"]
+[connection signal="text_submitted" from="Footer/Input" to="." method="_on_input_text_submitted"]
+[connection signal="pressed" from="Footer/RunButton" to="." method="_on_run_button_pressed"]

addons/lua-gdextension/plugin.cfg

@@ -0,0 +1,7 @@
+[plugin]
+
+name="Lua GDExtension"
+description="Tools for Lua GDExtension: REPL tab"
+author="gilzoide"
+version="0.2.0"
+script="plugin.gd"

addons/lua-gdextension/plugin.gd

@@ -0,0 +1,37 @@
+# Copyright (C) 2025 Gil Barbosa Reis.
+# 
+# Permission is hereby granted, free of charge, to any person obtaining a copy of
+# this software and associated documentation files (the “Software”), to deal in
+# the Software without restriction, including without limitation the rights to
+# use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies
+# of the Software, and to permit persons to whom the Software is furnished to do
+# so, subject to the following conditions:
+# 
+# The above copyright notice and this permission notice shall be included in all
+# copies or substantial portions of the Software.
+# 
+# THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+@tool
+extends EditorPlugin
+
+
+var _lua_repl: Control
+
+
+func _enter_tree():
+	_lua_repl = preload("lua_repl.tscn").instantiate()
+	add_control_to_bottom_panel(_lua_repl, "Lua REPL")
+
+
+func _exit_tree():
+	if _lua_repl:
+		remove_control_from_bottom_panel(_lua_repl)
+		_lua_repl.queue_free()
+		_lua_repl = null

addons/lua-gdextension/plugin.gd.uid

@@ -0,0 +1 @@
+uid://cwp2hwkpbitgx

test/project.godot

@@ -15,6 +15,10 @@ run/main_scene="uid://d3pmpkdvfqjca"
 config/features=PackedStringArray("4.4", "GL Compatibility")
 config/icon="uid://cih6ia8rwpfa3"
 
+[editor_plugins]
+
+enabled=PackedStringArray("res://addons/lua-gdextension/plugin.cfg")
+
 [rendering]
 
 renderer/rendering_method="gl_compatibility"