file.append, file.append_bits

Author: lpil

src/gleam/erlang/file.gleam

@@ -310,6 +310,57 @@ external fn do_write_bits(
 ) -> Result(Nil, Reason) =
   "gleam_erlang_ffi" "write_file"
 
+/// Append the given String contents to a file of the given name.
+///
+/// Returns a Result with Nil if the operation was successful or a Reason
+/// otherwise.
+///
+/// ## Examples
+///
+///    > append("Hello, World!", "file.txt")
+///    Ok(Nil)
+///
+///    > append(to: "file.txt", contents: "Hello, World!")
+///    Ok(Nil)
+///
+///    > append("Hello, World!", "does_not_exist/file.txt")
+///    Error(Enoent)
+///
+pub fn append(contents contents: String, to path: String) -> Result(Nil, Reason) {
+  contents
+  |> bit_string.from_string
+  |> do_append_bits(path)
+}
+
+/// Append the given BitString contents to a file of the given name.
+///
+/// Returns a Result with Nil if the operation was successful or a Reason
+/// otherwise.
+///
+/// ## Examples
+///
+///    > append_bits(<<71,73,70,56,57,97,1,0,1,0,0,0,0,59>>, "cat.gif")
+///    Ok(Nil)
+///
+///    > append_bits(to: "cat.gif", contents: <<71,73,70,56,57,97,1,0,1,0,0,0,0,59>>)
+///    Ok(Nil)
+///
+///    > append_bits(<<71,73,70,56,57,97,1,0,1,0,0,0,0,59>>, "does_not_exist/cat.gif")
+///    Error(Enoent)
+///
+pub fn append_bits(
+  contents contents: BitString,
+  to path: String,
+) -> Result(Nil, Reason) {
+  do_append_bits(contents, path)
+}
+
+external fn do_append_bits(
+  contents: BitString,
+  path: String,
+) -> Result(Nil, Reason) =
+  "gleam_erlang_ffi" "append_file"
+
 /// Delete the given file.
 ///
 /// Returns a Result with Nil if the operation was successful or a Reason

src/gleam_erlang_ffi.erl

@@ -2,9 +2,9 @@
 -export([
     atom_from_dynamic/1, rescue/1, atom_from_string/1, get_line/1,
     ensure_all_started/1, sleep/1, os_family/0, sleep_forever/0, read_file/1,
-    write_file/2, delete_file/1, get_all_env/0, get_env/1, set_env/2,
-    unset_env/1, delete_directory/1, recursive_delete/1, list_directory/1,
-    demonitor/1, make_directory/1, new_selector/0, link/1,
+    append_file/2, write_file/2, delete_file/1, get_all_env/0, get_env/1,
+    set_env/2, unset_env/1, delete_directory/1, recursive_delete/1,
+    list_directory/1, demonitor/1, make_directory/1, new_selector/0, link/1,
     insert_selector_handler/3, select/1, select/2, trap_exits/1, map_selector/2,
     merge_selector/2, flush_messages/0
 ]).
@@ -85,6 +85,9 @@ read_file(Filename) ->
 write_file(Contents, Filename) ->
     posix_result(file:write_file(Filename, Contents)).
 
+append_file(Contents, Filename) ->
+    posix_result(file:write_file(Filename, Contents, [append])).
+
 delete_file(Filename) ->
     posix_result(file:delete(Filename)).
 

test/gleam/erlang/file_test.gleam

@@ -85,11 +85,51 @@ fn tmp_path(filename: String) {
 fn make_tmp_directory() {
   delete_tmp_directory()
   assert Ok(Nil) = file.make_directory(tmp_directory)
+  Nil
 }
 
 fn delete_tmp_directory() {
   assert Ok(Nil) = case file.recursive_delete(tmp_directory) {
     Error(file.Enoent) -> Ok(Nil)
     other -> other
   }
+  Nil
+}
+
+pub fn append_test() {
+  make_tmp_directory()
+  let path = tmp_path("success.txt")
+  assert Error(file.Enoent) = file.read(path)
+
+  assert Ok(Nil) = file.append("one", path)
+  assert Ok("one") = file.read(path)
+
+  assert Ok(Nil) = file.append("two", path)
+  assert Ok("onetwo") = file.read(path)
+
+  assert Ok(Nil) = file.append("three", path)
+  assert Ok("onetwothree") = file.read(path)
+
+  assert Ok(Nil) = file.delete(path)
+  assert Error(file.Enoent) = file.read(path)
+  delete_tmp_directory()
+}
+
+pub fn append_bits_test() {
+  make_tmp_directory()
+  let path = tmp_path("cat.jpeg")
+  assert Error(file.Enoent) = file.read_bits(path)
+
+  assert Ok(Nil) = file.append_bits(<<1>>, path)
+  assert Ok(<<1>>) = file.read_bits(path)
+
+  assert Ok(Nil) = file.append_bits(<<2>>, path)
+  assert Ok(<<1, 2>>) = file.read_bits(path)
+
+  assert Ok(Nil) = file.append_bits(<<3>>, path)
+  assert Ok(<<1, 2, 3>>) = file.read_bits(path)
+
+  assert Ok(Nil) = file.delete(path)
+  assert Error(file.Enoent) = file.read_bits(path)
+  delete_tmp_directory()
 }