google_memorystore_instance dependency on "region" from provider level instead of "location" at resources level

[damontfgz]

Community Note

• Please vote on this issue by adding a 👍 reaction to the original issue to help the community and maintainers prioritize this request.
• Please do not leave +1 or me too comments, they generate extra noise for issue followers and do not help prioritize the request.
• If you are interested in working on this issue or have submitted a pull request, please leave a comment.
• If an issue is assigned to a user, that user is claiming responsibility for the issue.
• Customers working with a Google Technical Account Manager or Customer Engineer can ask them to reach out internally to expedite investigation and resolution of this issue.

Terraform Version & Provider Version(s)

• provider registry.terraform.io/hashicorp/google v6.43.0

Affected Resource(s)

google_memorystore_instance

Terraform Configuration

Debug Output

Planning failed. Terraform encountered an error while generating this plan.
╷
│ Error: Cannot determine region: set in this resource, or set provider-level 'region' or 'zone'.

Expected Behavior

the memorystore should be able to recognize the region through the location field

• https://registry.terraform.io/providers/hashicorp/google/latest/docs/resources/memorystore_instance#location-1

However, the latest provider release 6.43.0 seems to be introducing a dependency on region at provider level, instead of honoring the location provided at resource level for google_memorystore_instance

Actual Behavior

Planning failed. Terraform encountered an error while generating this plan.
╷
│ Error: Cannot determine region: set in this resource, or set provider-level 'region' or 'zone'.

Steps to reproduce

The failure is gone if I do either change below

• limiting the provider version to 6.42.0
• providing region field at provider block

Important Factoids

No response

References

No response

b/431079161

[ggtisc]

Hi @damontfgz I used this terraform example but everything works as expected without errors (link here). If you are still having issues please share with us your full code without locals, variables or modules to see what is happening.

Used code:

provider "google" {
  region                = "us-central1"
}

terraform {
  required_providers {
    google = {
      source  = "hashicorp/google"
      version = "6.43.0"
    }
  }
}

data "google_project" "project_23543" {}

resource "google_compute_network" "vpc_23543" {
  name                    = "vpc-23543"
  auto_create_subnetworks = false
}

resource "google_compute_subnetwork" "subnet_23543" {
  name          = "subnet-23543"
  ip_cidr_range = "10.0.0.248/29"
  region        = "us-central1"
  network       = google_compute_network.vpc_23543.id
}

resource "google_network_connectivity_service_connection_policy" "conectivity_connection_policy_23543" {
  name          = "conectivity-connection-policy-23543"
  location      = "us-central1"
  service_class = "gcp-memorystore"
  description   = "something"
  network       = google_compute_network.vpc_23543.id

  psc_config {
    subnetworks = [google_compute_subnetwork.subnet_23543.id]
  }
}

resource "google_memorystore_instance" "memorystore_instance_23543" {
  instance_id                 = "memorystore-instance-23543"
  shard_count                 = 1
  location                    = "us-central1"
  deletion_protection_enabled = false

  desired_auto_created_endpoints {
    network    = google_compute_network.vpc_23543.id
    project_id = data.google_project.project_23543.project_id
  }
  
  maintenance_policy {
    weekly_maintenance_window {
      day = "MONDAY"
      start_time {
        hours = 1
        minutes = 0
        seconds = 0
        nanos = 0
      }
    }
  }

  depends_on = [
    google_network_connectivity_service_connection_policy.conectivity_connection_policy_23543
  ]
}

[damontfgz]

@ggtisc thanks for checking in this issue, regarding the example you share above, I believe google_memorystore_instance should be relying on the location field provided, instead of the region at the provider level? And this has been the behavior until the latest release 6.43.0

If region is removed, the reported failure will likely show up

provider "google" {
  region                = "us-central1"
}

[ggtisc]

I tried again this time without using the region at provider level but again everything works good. I suggest you to clean up your environment, and do basic troubleshooting like restart your environment, execute a terraform init -upgrade command etc.

[damontfgz]

@ggtisc I think the issue is likely due to weather transit encryption is enabled or not. In the example you shared above, that is disabled by default. I am able to replicate the failure with above example plus

• removing region field at provider level
• setting transit_encryption_mode =SERVER_AUTHENTICATION for google_memorystore_instance

[ggtisc]

Hi again @damontfgz for this reason we need the full code as the above examples, but for now I'm going to make a new try with this code configuration. Some issues were closed daily because user's doesn't provide enough and complete information

Update:

After a new with the changes everything worked again as expected without issues or errors. If you have a different code configuration we are going to need your full code without using locals, variables or modules and the terraform version you are using, not the Google provider version.

[damontfgz]

Hi @ggtisc please find the code I used below

cat main.tf

provider "google" {
}

terraform {
  required_providers {
    google = {
      source  = "hashicorp/google"
      version = "6.43.0"
    }
  }
}

data "google_project" "project_23543" {}

resource "google_compute_network" "vpc_23543" {
  name                    = "vpc-23543"
  auto_create_subnetworks = false
}

resource "google_compute_subnetwork" "subnet_23543" {
  name          = "subnet-23543"
  ip_cidr_range = "10.0.0.248/29"
  region        = "us-central1"
  network       = google_compute_network.vpc_23543.id
}

resource "google_network_connectivity_service_connection_policy" "conectivity_connection_policy_23543" {
  name          = "conectivity-connection-policy-23543"
  location      = "us-central1"
  service_class = "gcp-memorystore"
  description   = "something"
  network       = google_compute_network.vpc_23543.id

  psc_config {
    subnetworks = [google_compute_subnetwork.subnet_23543.id]
  }
}

resource "google_memorystore_instance" "memorystore_instance_23543" {
  instance_id                 = "memorystore-instance-23543"
  shard_count                 = 1
  location                    = "us-central1"
  engine_version              = "VALKEY_8_0"
  transit_encryption_mode     = "SERVER_AUTHENTICATION"

  deletion_protection_enabled = false

  desired_auto_created_endpoints {
    network    = google_compute_network.vpc_23543.id
    project_id = data.google_project.project_23543.project_id
  }

  maintenance_policy {
    weekly_maintenance_window {
      day = "MONDAY"
      start_time {
        hours = 1
        minutes = 0
        seconds = 0
        nanos = 0
      }
    }
  }

  depends_on = [
    google_network_connectivity_service_connection_policy.conectivity_connection_policy_23543
  ]
}

The output I am getting

google_memorystore_instance.memorystore_instance_23543: Still creating... [10m40s elapsed]
google_memorystore_instance.memorystore_instance_23543: Still creating... [10m50s elapsed]
google_memorystore_instance.memorystore_instance_23543: Still creating... [11m0s elapsed]
google_memorystore_instance.memorystore_instance_23543: Still creating... [11m10s elapsed]
╷
│ Error: Cannot determine region: set in this resource, or set provider-level 'region' or 'zone'.
│
│   with google_memorystore_instance.memorystore_instance_23543,
│   on main.tf line 39, in resource "google_memorystore_instance" "memorystore_instance_23543":
│   39: resource "google_memorystore_instance" "memorystore_instance_23543" {
│
╵

Will try to run again after updating the terraform to latest version, but below is my current terraform configuration

terraform --version
Terraform v1.9.8
on darwin_arm64
+ provider registry.terraform.io/hashicorp/google v6.43.0

Your version of Terraform is out of date! The latest version
is 1.12.2. You can update by downloading from https://www.terraform.io/downloads.html