How to do dict.get("key", "default") in hy?

[cloud11665]

i have a dict that may not have a key. In python i would do something like

foo = obj.get("key", "default")

i tried doing that on hy but it doesnt do anything

(serv foo ((. obj get) "key" "default"))

thanks in advance!

[cloud11665]

ok, nvm its (setv foo (obj.get "key" "default")) 😆

[allison-casey]

if the key you're trying to get is a string you can also look it up with a keyword. the second argument of a keyword lookup is the default value.

(setv foo {"a" 1 "b" 2})
(:a foo)  ; => 1
(:c foo "default")  ; => "default"

[cloud11665]

wow, that is even better! Thank you very much.

[cloud11665]

also, i dont want to start a new thread for that, but how would you go about doing something like that in hy?

pid = subprocess.check_output("ps -o 'cmd,pid' | grep '^memcached' | awk '{print $2}'", shell=True)\
		.decode()\
		.strip()

here is my try, but i think the spamming of dots is not a good way to do that

         (setv pid (. (. (.check_output subprocess
                          "ps -o 'cmd,pid' | grep '^memcached' | awk '{print $2}'"
                          :shell True)
                       decode)
                    strip)))

[cloud11665]

after reading the docs i found out about the -> macro

(setv pid (->
      (.check_output subprocess (+
                       "ps -o 'cmd,pid'"
                       "| grep '^memcached'"
                       "| awk '{print $2}'")
                     :shell True)
      .decode
      .strip))

is this the best way to do it now ?

[allison-casey]

Just about! I would probably format it something like this though

(setv pid (-> (subprocess.check-output
               "ps -o 'cmd,pid' | grep '^memcached' | awk '{print $2}'"
               :shell True)
             .decode
             .strip))

if you have a variable representing the thing you're trying to access an attribute of, you can simplify the expression to something like (subprocess.check-output ...) instead of (.check-output subprocess ...), these are identical expressions.

As an aside, its important to remember that accessing attributes looks different than calling methods an that carries over into threading macros

(setv pid (-> (subprocess.run
               "ps -o 'cmd,pid' | grep '^memcached' | awk '{print $2}'"
               :shell True
               :check True)
             (. stdout)
             .decode
             .strip))