E22-900MM22S | ESP32-C6. No TX RF output when it should

[DitroniX]

Been investigating the E22-900MM22S connected to an ESP32-C6. Module OK and the MCU is OK.

• The radio initializes OK but cannot get any TX. (Monitoring on Analyzer).

• TXEN tied to DI02, just to reduce GPIO. Can see this go high when it should TX.

• RXEN left low during testing.

• NRST goes low as expected.

• BUSY goes high when expected.

• DI03 goes low when expected.

• Have tried a couple of radio.begin options (as in code), and enabled and disabled setTCXO and also put XTL before radio.begin.

• Have tried two different separate hardware configurations, hence header device 1/2, and one is a dead bugged version.

• Can see the SPI on analyzer and messages OK.

However, despite all this, no TX RF output.

Below, WIP code. Probably something minor but would appreciate any thoughts, please.

#include <Arduino.h>
#include <SPI.h>
#include <RadioLib.h>

// Pin definitions
#define SPI_MOSI_PIN 18
#define SPI_MISO_PIN 20
#define SPI_SCK_PIN 19
#define CS_PIN 14

// Device 1 #########################
// #define INT_PIN 1
// #define RESET_PIN 21
// #define BUSY_PIN 22

// #define RXEN_PIN 8
// #define TXEN_PIN 2

// Device 2 #########################
#define INT_PIN 21
#define RESET_PIN 15
#define BUSY_PIN 2

#define RXEN_PIN 1
#define TXEN_PIN 0

// Create a RadioLib SX1262 instance, setting DIO1 to -1 because it is not connected
SX1262 radio = new Module(CS_PIN, INT_PIN, RESET_PIN, BUSY_PIN);
// SX1262 radio = new Module(CS_PIN, -1, RESET_PIN, BUSY_PIN);

// save transmission states between loops
int transmissionState = RADIOLIB_ERR_NONE;

// flag to indicate transmission or reception state
bool transmitFlag = false;

// flag to indicate that a packet was sent or received
volatile bool operationDone = false;

void setup()
{
  Serial.begin(115200);

  delay(1000);

  Serial.println("\nStarting SX1262 setup...");

  // Configure TXEN and RXEN pins
  pinMode(CS_PIN, OUTPUT);
  pinMode(RESET_PIN, OUTPUT);

  // pinMode(TXEN_PIN, OUTPUT);
  // pinMode(RXEN_PIN, OUTPUT);

  // digitalWrite(TXEN_PIN, HIGH);
  // digitalWrite(RXEN_PIN, LOW);
  // delay(10);

  digitalWrite(RESET_PIN, LOW);
  delay(200);
  digitalWrite(RESET_PIN, HIGH);
  delay(200);

  SPI.begin(SPI_SCK_PIN, SPI_MISO_PIN, SPI_MOSI_PIN, CS_PIN);

  radio.XTAL = true;
  radio.setTCXO(0);  // Tried commented out too.

  // Initialize the SX1262 radio module
  // int state = radio.begin(868.0);
  int state = radio.begin();

  // int state = radio.begin(868.0, 125.0, 9, 7, RADIOLIB_SX126X_SYNC_WORD_PRIVATE, 10, 8, 1.6, false);

  // radio.setTCXO(0);

  if (state == RADIOLIB_ERR_NONE)
  {
    Serial.println("SX1262 initialized successfully.\n");
  }
  else
  {
    Serial.print("Failed to initialize SX1262. Error code: ");
    Serial.println(state);
    while (true)
      ;
  }

  // Send Test Packet - ENSURE ANTENNA is CONNNECTED FIRST!
  Serial.print(F("[SX1262] Sending first packet(s) ... "));

  transmissionState = radio.startTransmit("Hello World!");

  transmitFlag = true;

  delay(250);
  transmitFlag = false;

  Serial.println("\n\Test Complete");
}

void loop()
{
}

[jgromes]

I would start by going back to an example with minimum modifications - definitely you don't need to change pin directions, or manually reset the module, the library takes care of all of that. You are also manually initializing the SPI but not providing this instance to the Module constructor, so it is attempting to initialize it again.

Calling radio.setTCXO() prior to begin will not work, as communication with the module has not been established by that point. So if you want to change the oscillator type or reference voltage, you either have to set XTAL=true; to disable TCXO, or provide the appropriate voltage reference value to the begin method. It is fairly easy to know you have the correct setup, as with incorrect oscillator the begin method will most likely fail.

Finally - if transmission is not working, what is the return code returned by startTransmit? It would also be a lot better to use the blocking transmit instead of just a 250 ms, as the transmit method will wait for transmission completion, and then also clean up after it.

[DitroniX]

Really appreciate the feedback.

As a hardware engineer, whilst I can normally get by with code, I am unfortunately still struggling to understand your library with regards to the implementation of SPI. Obviously missing something really obvious somewhere.

FYI My original code returned 0, for startTransmit. An advantage though is that SPI was initializing (ish).

Have looked at your wiki page and trawled example code but this does not explain where to set the non-standard SPI GPIO.

The ESP32-C6 does not have a default SPI interface. For this reason, I always set the SPI GPIOs in my code and never normally have any issues.

Based on my interpretation of your wiki, I have updated the code but now it fails to initialize the SPI bus.

In addition, I now get the below error. SPI is not working at all now? Guessing but this may relate to the RADIOLIB_NC, or GPIO fourth possible pin?

Starting SX1262 setup...
[ 1007][E][esp32-hal-gpio.c:176] __digitalWrite(): IO 15 is not set as GPIO. Execute digitalMode(15, OUTPUT) first.
[ 1219][E][esp32-hal-gpio.c:176] __digitalWrite(): IO 15 is not set as GPIO. Execute digitalMode(15, OUTPUT) first.
Failed to initialize SX1262. Error code: -2

#include <RadioLib.h>

// Pin definitions
#define SPI_MOSI_PIN 18
#define SPI_MISO_PIN 20
#define SPI_SCK_PIN 19

#define cs 14
#define irq 21
#define rst 15

SPISettings spiSettings(4000000, LSBFIRST, SPI_MODE3);
SX1262 radio = new Module(cs, irq, rst, RADIOLIB_NC, SPI, spiSettings);

void setup()
{
  Serial.begin(115200);

  delay(1000);

  Serial.println("\nStarting SX1262 setup...");

  digitalWrite(rst, LOW);
  delay(200);
  digitalWrite(rst, HIGH);
  delay(200);

  SPI.begin(SPI_SCK_PIN, SPI_MISO_PIN, SPI_MOSI_PIN);
  // SPI.begin();

  radio.XTAL = true;

  int state = radio.begin(868.0);

  if (state == RADIOLIB_ERR_NONE)
  {
    Serial.println("SX1262 initialized successfully.\n");
  }
  else
  {
    Serial.print("Failed to initialize SX1262. Error code: ");
    Serial.println(state);
    while (true)
      ;
  }

  Serial.print("Sending Packet\n");

  int transmissionState = radio.startTransmit("Hello World!");

  Serial.println(transmissionState);

  Serial.println("\nTest End");
}

void loop()
{
}

[DitroniX]

PS. Not sure about the digitalMode comment as believe this is related to the Industruino environment but tried adding pinMode(rst, OUTPUT); makes no difference.

Starting SX1262 setup...
[ 1007][E][esp32-hal-gpio.c:176] __digitalWrite(): IO 15 is not set as GPIO. Execute digitalMode(15, OUTPUT) first.
[ 1219][E][esp32-hal-gpio.c:176] __digitalWrite(): IO 15 is not set as GPIO. Execute digitalMode(15, OUTPUT) first.
Failed to initialize SX1262. Error code: -2

[DitroniX]

Quick update.

Have taken example code from #1541 and tweaked to align with my setup and GPIOs.

It seems to work and the TX is sending packets. Need now to complete further tests but all good.

For other users, this is the basic code.

#include <RadioLib.h>
#include <SPI.h>

SX1262 radio = new Module(14, 21, 15, RADIOLIB_NC);

void setup()
{
  Serial.begin(115200);
  
  SPI.begin(19, 20, 18, 14);

  Serial.print(F("[SX1262] Initializing ... "));

  radio.XTAL = true;

  int state = radio.begin();
  if (state == RADIOLIB_ERR_NONE)
  {
    Serial.println(F("success!"));
  }
  else
  {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true)
    {
      delay(10);
    }
  }

  Serial.print("Sending Packet\n");

  int transmissionState = radio.startTransmit("Hello World!");

  Serial.println(transmissionState);

  Serial.println("\nTest End");

}

void loop() {}

[jgromes]

Glad you were able to resolve the issue, but I want to point out a few things in your past couple of posts, especially for people reading this later:

1. When changing the SPI configuration, you have set SPI_MODE3 in SPI settings - that is most likely the reason why SPI stopped working, since the clock polarity and phase has been inverted by this mode change, and so the data coming out of the module no longer makes sense to the MCU.
2. I would strongly recommend not leaving BUSY unconnected with RADIOLIB_NC. This pin is used by the SX1262 to signal when it is ready to accept new commands. Without it, RadioLib puts delays between SPI transactions, but it is not guaranteed to always work. The module you have does include the pin, so there's not much reason to not use it.

[DitroniX]

Thanks for the heads up.

Short of GPIOs so will have to ponder on the BUSY..

[DitroniX]

Closing comment, GPIOs resolved and thanks for your support.

https://www.kickstarter.com/projects/ditronix/espranger-lora-gnss-gyro-accelerometer-rs485-esp32-c6/posts/4533859