Lilygo T3_V1.6.1 Pinout

[fhendrikx]

Hi,

I am trying to run a simple program that sends some AFSK tones on a LilyGO Lora32 T3_V1.6.1 (SX1278 / 433).

The program is defined below:

#include <RadioLib.h>

#define RADIOLIB_DEBUG_BASIC (1)
//#define RADIOLIB_DEBUG_SPI (1)

#define LORA_SCK 5
#define LORA_MISO 19
#define LORA_MOSI 27
#define LORA_CS 18
#define LORA_DIO0 26
#define LORA_DIO1 33
#define LORA_DIO2 32
#define LORA_RST 23
#define FREQ 433

SX1278 radio = new Module(LORA_CS, LORA_DIO0, LORA_RST, LORA_DIO1);
AFSKClient audio(&radio, LORA_DIO2);

void setup() {
    Serial.begin(115200);
    delay(1000);
    Serial.println("setup()");

    //spi.begin();

    int state = radio.beginFSK(FREQ, 1.2, 6);

    if (state == RADIOLIB_ERR_NONE)
    {
        Serial.println("Radio: init success");
        audio.begin();
    }
    else
    {
        Serial.print("Radio: init failed code=");
        Serial.println(state);

        while(1);
    }
}

void loop()
{
  Serial.println("loop()");

  audio.tone(400);
  delay(500);
  audio.tone(0);

  delay(1000);
}

Sadly, it returns -2 (unable to init radio).

The Troubleshooting guide suggests this is because of either:

A. Incorrect SPI interface
B. Bad pinout
C. Bad/unreliable connections

I've followed the pinout described in the documentation, so I don't believe that B is the issue. I think that also covers the SPI configuration in A.

Therefore, I have some questions:

1. Do I need any connections? I read somewhere that there may need to be a GPIO connection for the audio class?
2. How do I get debug working? (the Arduino env complains about the macro being redefined).

Thanks in advance,
Ferry

[jgromes]

First of all, to enable the debug, you have to edit the BuildOptUser.h file or declare the macro in your build system with a -D argument to you compiler. Putting the macro in your user script will not work.

As to why are you seeing the -2, my first guess would be incorret SPI interface, as currently it will use the default SPI - you can select a diffent one as described on this wiki page.

The additional GPIO will be needed, yes - but only for AFSK tones, it is not necessary to get the radio module itself up and running.

[fhendrikx]

As to why are you seeing the -2, my first guess would be incorret SPI interface, as currently it will use the default SPI - you can select a diffent one as described on this wiki page.

Yes, I had seen that, but wasn't sure what I would need to make it work. I have dug up the correct information and am providing it below for anyone else that ever needs it:

// SPI (LoRa)
#define LORA_CLK  5
#define LORA_MISO 19
#define LORA_MOSI 27

#define LORA_CS   18
#define LORA_RST  23
#define LORA_DIO0 26
#define LORA_DIO1 33
#define LORA_DIO2 32

SPIClass spi(VSPI);
SPISettings spiSettings(2000000, MSBFIRST, SPI_MODE0);

SX1278 radio = new Module(LORA_CS, LORA_DIO0, LORA_RST, LORA_DIO1, spi, spiSettings);
AFSKClient audio(&radio, LORA_DIO2);

void setup() {
    spi.begin(LORA_CLK, LORA_MISO, LORA_MOSI);

@jgromes Thank you for taking the time to answer my questions.