Fix hue blending between a gray and a non-gray (#30)

Author: kimikage

docs/src/color-space-dependence.md

@@ -64,6 +64,21 @@ julia> blend(c1, blend(c2, c3))
 HSL{Float64}(240.0,1.0,0.8)
 ```
 
+In addition, in the case of blending a gray, i.e., a color with zero saturation,
+and a non-gray, the hue of the non-gray color is used.
+
+```jldoctest; setup=(using ColorTypes, ColorBlendModes;)
+julia> for w in 0.0:0.2:1.0 # gray to yellow green, not via brown
+           println(blend(HSI(12.3, 0.0, 0.5), HSI(78.9, 1.0, 0.5), opacity=w))
+       end
+HSI{Float64}(78.9,0.0,0.5)
+HSI{Float64}(78.9,0.2,0.5)
+HSI{Float64}(78.9,0.4,0.5)
+HSI{Float64}(78.9,0.6,0.5)
+HSI{Float64}(78.9,0.8,0.5)
+HSI{Float64}(78.9,1.0,0.5)
+```
+
 ## Gamma correction
 
 The [`blend`](@ref) function blends colors in a "uniform" space. Note that this

src/operations.jl

@@ -1,9 +1,9 @@
 
 mapch(f, x, y) = mapc(f, x, y)
 mapch(f, x::C, y::C) where C <: Union{HSV, HSL, HSI} =
-    C(f(Hue(x.h), Hue(y.h)), f(x.s, y.s), f(comp3(x), comp3(y)))
+    C(f(Hue(x), Hue(y)), f(x.s, y.s), f(comp3(x), comp3(y)))
 mapch(f, x::C, y::C) where C <: Union{LCHab, LCHuv} =
-    C(f(x.l, y.l), f(x.c, y.c), f(Hue(x.h), Hue(y.h)))
+    C(f(x.l, y.l), f(x.c, y.c), f(Hue(x), Hue(y)))
 
 mapca(fc, a, x::C) where C <: TransparentColorN{2} = C(fc(comp1(x)), a)
 mapca(fc, a, x::C) where C <: TransparentColorN{3} = C(fc(comp1(x)), fc(comp2(x)), a)
@@ -15,9 +15,9 @@ mapca(fc, a, x::C, y::C) where C <: TransparentColorN{3} =
 mapca(fc, a, x::C, y::C) where C <: TransparentColorN{4} =
     C(fc(comp1(x), comp1(y)), fc(comp2(x), comp2(y)), fc(comp3(x), comp3(y)), a)
 mapca(fc, a, x::C, y::C) where C <: TransparentColorN{4, <:Union{HSV, HSL, HSI}} =
-    C(fc(Hue(x.h), Hue(y.h)), fc(x.s, y.s), fc(comp3(x), comp3(y)), a)
+    C(fc(Hue(x), Hue(y)), fc(x.s, y.s), fc(comp3(x), comp3(y)), a)
 mapca(fc, a, x::C, y::C) where C <: TransparentColorN{4, <:Union{LCHab, LCHuv}} =
-    C(fc(x.l, y.l), fc(x.c, y.c), fc(Hue(x.h), Hue(y.h)))
+    C(fc(x.l, y.l), fc(x.c, y.c), fc(Hue(x), Hue(y)))
 
 # complement
 _n(v::T) where T = oneunit(T) - v
@@ -26,9 +26,11 @@ _n(v::T) where T = oneunit(T) - v
 _w(v1::T, v2::T, w) where T = convert(T, muladd(_n(w), v1, w * v2))
 
 function _w(h1::Hue{T}, h2::Hue{T}, w) where T
-    d0 = h2.angle - h1.angle
+    h1a = ifelse(h1.isgray, h2.angle, h1.angle)
+    h2a = ifelse(h2.isgray, h1.angle, h2.angle)
+    d0 = h2a - h1a
     d = ifelse(abs(d0) > T(180), d0 - copysign(T(360), d0), d0)
-    a = muladd(d, w, h1.angle)
+    a = muladd(d, w, h1a)
     convert(T, ifelse(a > T(360), a - T(360), ifelse(a < T(0), a + T(360), a)))
 end
 
@@ -45,8 +47,7 @@ _w_safe(v1::T, w1, v2::T, w2) where T = min(oneunit(T), _w(v1, w1, v2, w2))
 _w_safe(v1::T, w1, v2::T, w2) where T <: FixedPoint =
     convert(T, min(float(typemax(T)), muladd(w1, float(v1), w2 * float(v2))))
 
-_comp(op::CompositeOperation{:clear}, c1, c2) =
-    mapc(v1 -> zero(v1), c1)
+_comp(op::CompositeOperation{:clear}, c1, c2) = mapc(v1 -> zero(v1), c1)
 
 _comp(op::CompositeOperation{:copy}, c1, c2) = c2
 

src/types.jl

@@ -3,6 +3,14 @@ const TransparentColorN{N,C<:Color,T} = TransparentColor{C,T,N}
 
 struct Hue{T<:Real}
     angle::T
+    isgray::Bool
+    Hue(angle::T, isgray::Bool=false) where {T <: Real} = new{T}(angle, isgray)
+    Hue(c::C) where {T, C<:Union{HSV{T}, HSL{T}, HSI{T},
+                                 AHSV{T}, AHSL{T}, AHSI{T}, HSVA{T}, HSLA{T}, HSIA{T}}} =
+        new{T}(c.h, c.s == zero(T))
+    Hue(c::C) where {T, C<:Union{LCHab{T}, LCHuv{T},
+                                 ALCHab{T}, ALCHuv{T}, LCHabA{T}, LCHuvA{T}}} =
+        new{T}(c.h, c.c == zero(T))
 end
 
 const SeparableBlendMode = Union{

test/blend_hsx.jl

@@ -20,4 +20,8 @@
     @testset "$A over $A: $T" for T in (Float64, Float32)
         @test BlendNormal(A{T}(100,  0.75, 0, 0.6), A{T}(0, 0.5, 1, 0.6)) ≈ A{T}(200/7, 4/7, 5/7, 0.84)
     end
+
+    @testset "$C over gray $C: $T" for T in (Float64, Float32)
+        @test blend(C{T}(100, 0, 1), C{T}(200, 1, 0.5), opacity=0.5) ≈ C{T}(200, 0.5, 0.75)
+    end
 end

test/blend_lab.jl

@@ -36,3 +36,9 @@
         @test BlendNormal(A{T}(90, 80, 70, 0.6), A{T}(60, 50, -40, 0.6)) ≈ A{T}(68.57142857142857, 58.57142857142857, -8.57142857142857, 0.84)
     end
 end
+
+@testset "$C" for C in (LCHab, LCHuv)
+    @testset "$C over gray $C: $T" for T in (Float64, Float32)
+        @test blend(C{T}(40, 0, 100), C{T}(60, 100, 200), opacity=0.5) ≈ C{T}(50, 50, 200)
+    end
+end

test/runtests.jl

@@ -95,6 +95,13 @@ end
     @test ColorBlendModes._w(Hue(175.0), 0.4, Hue(185.0), 0.6) ≈ 181.0
     @test ColorBlendModes._w(Hue(230.0), 0.4, Hue(30.0), 0.6) ≈ 326.0
     @test ColorBlendModes._w(Hue(5.0), 0.4, Hue(355.0), 0.6) ≈ 359.0
+
+    @test ColorBlendModes._w(Hue(30.0, true), Hue(130.0), 0.0) ≈ 130.0
+    @test ColorBlendModes._w(Hue(30.0, true), Hue(130.0), 0.6) ≈ 130.0
+    @test ColorBlendModes._w(Hue(30.0, true), Hue(130.0), 1.0) ≈ 130.0
+    @test ColorBlendModes._w(Hue(30.0), Hue(130.0, true), 0.0) ≈ 30.0
+    @test ColorBlendModes._w(Hue(30.0), Hue(130.0, true), 0.6) ≈ 30.0
+    @test ColorBlendModes._w(Hue(30.0), Hue(130.0, true), 1.0) ≈ 30.0
 end
 
 @testset "blend: RGB" begin