Adjusting overall brightness seems to be slow.

[cultur98]

Great Library which gives me all the options I was looking for!

Especially dealing with segments is very convenient.
However the setBrightness() method seems to be very slow.

At least I fail to smoothly change the brightness of the pixels
using this function. Here every 10 milliseconds.
Variable the_bright is a value I read from an ambient light sensor.

void NeoPixelArray::loop(int dim_time) {
  unsigned long the_millis = millis();
  if((the_millis - update_time) >= 10)  {
    if (dim_time == 0) {
      the_bright = bright;
      ws2812fx->setBrightness(the_bright);
    } else if(the_bright < bright) {
      the_bright++;
      ws2812fx->setBrightness(the_bright);
    } else if(the_bright > bright) {
      the_bright--;
      ws2812fx->setBrightness(the_bright);
    }
    update_time = the_millis;
  ws2812fx->service();
}

Any ideas?

[moose4lord]

Like your code, the WS2812FX service() function uses a non-blocking timer to update the LEDs, and it will only push new data out to the LEDs when the animation calls for it. For example, if you have the BLINK animation selected and the "time" parameter set to 1000, the LEDs will blink on and off once every 1000ms, and the LEDs will only be updated twice a second (once for on and once for off), regardless of how many times service() is called.

Also, the global brightness feature is inherited from the Adafruit_NeoPixel library, which accounts for brightness before storing data for the LEDs to use. The brightness isn't applied dynamically as it's pushed to the LEDs, which makes it hard to do rapid brightness changes.

There is an ugly hack to get it to work though. By creating a virtual WS2812FX strip to run the animation on, and a second physical WS2812FX strip to actually implement dynamic brightness and push that modified data out to the LEDs. Something like this:

#include <WS2812FX.h>

#define VIRTUAL_LED_PIN     2  // virtual strip GPIO (just assign to an unused GPIO)
#define PHYSICAL_LED_PIN   14  // physical strip GPIO
#define LED_COUNT 16           // number of LEDs on the strip

WS2812FX ws2812fx_v = WS2812FX(LED_COUNT, VIRTUAL_LED_PIN,  NEO_GRB + NEO_KHZ800);
WS2812FX ws2812fx_p = WS2812FX(LED_COUNT, PHYSICAL_LED_PIN, NEO_GRB + NEO_KHZ800);

unsigned long update_time = 0;
int the_bright = 0, dir = 1;

void setup() {
  Serial.begin(115200);

  // setup the virtual strip to run the animation
  ws2812fx_v.init();
  ws2812fx_v.setBrightness(255);
  ws2812fx_v.setSegment(0,  0,  LED_COUNT - 1, FX_MODE_STATIC, RED, 1000);
  ws2812fx_v.start();
  ws2812fx_v.setCustomShow([]{ });  // replace the virtual strip's show() function with a dummy function that does nothing

  ws2812fx_p.init();  // init the physical strip last
}

void loop() {
  ws2812fx_v.service();  // run the animation on the virtual strip

  if((millis() - update_time) >= (5000 / 256))  {  // brightness cycles every 5000ms
    if(the_bright >= 255) dir = -1;      // if we're at max or min brightness, change the dimming direction
    if(the_bright <= 0) dir = 1;
    the_bright += dir;                   // calc the new brightness
    Serial.printf("brightness=%d\n", the_bright);

    uint8_t *pixels_v = ws2812fx_v.getPixels();  // get pointers to the pixel data arrays
    uint8_t *pixels_p = ws2812fx_p.getPixels();

    // copy the virtual strip's data to the phystical strip, modifing the brightness 
    for (uint16_t i=0; i < ws2812fx_p.getNumBytes(); i++) {
      pixels_p[i] = pixels_v[i] * the_bright / 256;
    }

    ws2812fx_p.execShow();               // push new data to the LEDs

    update_time = millis();              // reset the brightness timer
  }
}

Ugh, I'm embarrassed to share that code. It's ugly. :)

[cultur98]

Hi!
Thanks for your response.
Demo code works fine.
I will incorporate this workaround into my program.
Working code is never really ugly!

[cultur98]

Now everything runs smoothly.
These are the parts I had to modify.

void NeoPixelArray::set_bright(u_int8_t val) {
  new_bright = val;
}
void NeoPixelArray::copy() {
    uint8_t *pixels_v = ws2812fx_v->getPixels();  // get pointers to the pixel data arrays
    uint8_t *pixels_p = ws2812fx_p->getPixels();

    // copy the virtual strip's data to the phystical strip, modifing the brightness 
    for (uint16_t i=0; i < ws2812fx_p->getNumBytes(); i++) {
      pixels_p[i] = pixels_v[i] * the_bright / 256;
    }
    ws2812fx_p->execShow();               // push new data to the LEDs
}

void NeoPixelArray::loop(int dim_time) {
  ws2812fx_v->service();
  static unsigned long update_time;
  unsigned long the_millis = millis();
  if((the_millis - update_time) >= (unsigned long)dim_time)  {
    if(the_bright < new_bright) {
      the_bright++;
    } else if(the_bright > new_bright) {
      the_bright--;
    }
    update_time = the_millis;
  }
  copy();
}

void NeoPixelArray::init(u_int16_t num, u_int8_t pin) {
  con = false;
  pixel_pin = pin;
  pixel_num = num;
  ws2812fx_v = new WS2812FX(pixel_num, VIRTUAL_LED_PIN, NEO_GRB + NEO_KHZ800);
  ws2812fx_p = new WS2812FX(pixel_num, pixel_pin, NEO_GRB + NEO_KHZ800);
  ws2812fx_v->init();
  ws2812fx_v->setBrightness(255);
  ws2812fx_v->start();
  ws2812fx_v->setCustomShow([]{ });  // replace the virtual strip's show() function with a dummy function that does nothing
  set_bright(10);
  ws2812fx_p->init();
}