Hitting enter does not always run the command I typed even when I am not in the menu

[TommyX12]

Environment

% typeset -p1 VENDOR OSTYPE ZSH_PATCHLEVEL _autocomplete__funcfiletrace
typeset VENDOR=apple
typeset OSTYPE=darwin24.0
typeset ZSH_PATCHLEVEL=zsh-5.9-0-g73d3173
typeset -a _autocomplete__funcfiletrace=(
  /Users/tommyx/.oh-my-zsh/custom/plugins/zsh-autocomplete/zsh-autocomplete.plugin.zsh:4
  /Users/tommyx/.oh-my-zsh/oh-my-zsh.sh:175
  /Users/tommyx/.oh-my-zsh/oh-my-zsh.sh:204
  /Users/tommyx/data/tommyx-shell/tommyx-shell.sh:29
  /Users/tommyx/.zshrc:1
  zsh:0
)
% git -C ~autocomplete log --oneline -n1
762afac (grafted, HEAD -> main, tag: 24.09.04, origin/main, origin/HEAD) Add note to Readme about usage of `%`

• Operating system: macOS Sequoia 15.3.1
• Terminal emulator: iTerm2

Steps to reproduce

• In a large repository (e.g. at work), when I type something (e.g. git statu) and hit enter immediately, I expect the command to be run, but it sometimes completes/modifies the right most typed segment (e.g. replace statu with status) instead of running the command as is. This happens when I am not focusing in the autocomplete menu at all.
• This happens around 20% of the time (enough to interfere with my thoughts) and I frequently have to wait for 1 second before hitting enter just to make sure it doesn't mess with what I have already entered.
• I tried adding bindkey -M menuselect '^M' .accept-line and bindkey -M menuselect '\r' .accept-line to my config, it didn't help.

Note

• I am also using powerlevel10k which seems to have implemented deferred git status refresh (not sure if that interferes with this).

[kuro337]

@TommyX12 are you sure it is not lag too, that was also causing me issues?
Make sure to set the KEY_TIMEOUT and timeout settings for zsh.

I was able to fix this issue on MacOS Tahoe & Sonoma by making sure this is set for all modes - and I changed the menuselect binding to Shift Tab

These are my settings, a little overkill but works fine for me (I use no plugin manager like oh-my-zsh, caused too much slowness)

################### NOTE: source this before autocomplete, other plugins (included for reference)
bindkey -v
KEYTIMEOUT=1
zmodload zsh/terminfo

typeset -gA key_info
key_info=(
  'Control'         '\C-'
  'ControlLeft'     '\e[1;5D \e[5D \e\e[D \eOd'
  'ControlRight'    '\e[1;5C \e[5C \e\e[C \eOc'
  'ControlPageUp'   '\e[5;5~'
  'ControlPageDown' '\e[6;5~'
  'Tab'             "^I"
  'AltTab'          "\M-^I"
  'Meta'            '\M-'
  'Escape'          '\e'
  'Backspace'       "^?"
  'Backspace2'      "^H"
  'Delete'          "^[[3~"
  'F1'              "$terminfo[kf1]"
  'F2'              "$terminfo[kf2]"
  'F3'              "$terminfo[kf3]"
  'F4'              "$terminfo[kf4]"
  'F5'              "$terminfo[kf5]"
  'F6'              "$terminfo[kf6]"
  'F7'              "$terminfo[kf7]"
  'F8'              "$terminfo[kf8]"
  'F9'              "$terminfo[kf9]"
  'F10'             "$terminfo[kf10]"
  'F11'             "$terminfo[kf11]"
  'F12'             "$terminfo[kf12]"
  'Insert'          "$terminfo[kich1]"
  'Home'            "$terminfo[khome]"
  'PageUp'          "$terminfo[kpp]"
  'End'             "$terminfo[kend]"
  'PageDown'        "$terminfo[knp]"
  'Up'              "$terminfo[kcuu1]"
  'Left'            "$terminfo[kcub1]"
  'Down'            "$terminfo[kcud1]"
  'Right'           "$terminfo[kcuf1]"
  'BackTab'         "$terminfo[kcbt]"
  'ShiftTab'        "$terminfo[kcbt]"
)

# Set empty $key_info values to an invalid UTF-8 sequence to induce silent
# bindkey failure.
for key in "${(k)key_info[@]}"; do
  if [[ -z "$key_info[$key]" ]]; then
    key_info[$key]='�'
  fi
done

function bindkey-all {
  local keymap=''
  for keymap in $(bindkey -l); do
    [[ "$#" -eq 0 ]] && printf "#### %s\n" "${keymap}" 1>&2
    bindkey -M "${keymap}" "$@"
  done
}
######################### End of content to source FIRST ##################

# Source below AFTER sourcing zsh-autocomplete

zstyle ':autocomplete:*' min-input 2
zstyle ':autocomplete:*' delay 0.1

local _tab="$key_info[Tab]"
local _shifttab="$key_info[ShiftTab]"
local _alttab="$key_info[AltTab]"
local _esc="$key_info[Escape]"
local _ctrl="$key_info[Control]"

typeset -gA bindmap

bindmap=(
  'insert' 'viins'
  'normal' 'vicmd'
  'visual' 'visual'
  'search' 'isearch'
  'menu' 'menuselect'
  'op' 'viopp'
)

_errstr="Invalid Args:\nbindkey [mode] [func] [keys..]\ne.g keymap insert c-clear 'Tab'"
_errm="Must be insert|normal|visual|op|menu|search|main\n"

function _new_keymap {
  setopt localtraps localoptions localpatterns

  if [[ $# -lt 3 ]]; then printf "%s\n" $_errstr >&2 && return 1; fi

  if ! [[ $1 =~ ^(insert|viins|vicmd|menuselect|normal|visual|op|menu|search|main) ]]; then
    printf "Invalid Mode:%s\n%s\n" $1 $_errm >&2 && return 2
  fi
  if ! [[ -n ${widgets[$2]} ]]; then
    if ! typeset -f $2 >/dev/null; then printf "Undefined bindkey fn: $2\n" >&2 && return 2; fi
    zle -N $2
  fi

  local _mode _k
  _mode=${bindmap[$1]:-$1}

  for _k in "${@:3}"; do
    if ! bindkey -M $_mode "$_k" "$2"; then echo "Bindkey failed" >&2 && return 2; fi
  done

}

function ins_keymap {
  _new_keymap insert "$@"
}

function normal_keymap {
  _new_keymap vicmd "$@"
}

function menu_keymap {
  _new_keymap menuselect "$@"
}

function visual_keymap {
  _new_keymap visual "$@"
}

ins_keymap magic-space ' '
normal_keymap magic-space ' '

# Restore Tab as fzf-overrides. Confirm with: bindkey '^I'
normal_keymap history-beginning-search-backward 'k'
normal_keymap history-beginning-search-forward 'j'

# Go to end of line in Insert Mode
ins_keymap vi-add-eol "${_ctrl}E"

#----------------------
# COMPLETION Keymaps  #
#----------------------
# Accept Current Suggestion Word
ins_keymap menu-complete "$_tab"

# Enter Completion Menu w/ Tab
normal_keymap menu-select "$_tab"

# Accept Full Completion
ins_keymap autosuggest-accept "$_shifttab"

# Enter Completion Menu
normal_keymap menu-select "$_shifttab"

is-linux && ins_keymap down-line-or-history "$_alttab" || ins_keymap down-line-or-select "$_alttab"

# Fix Backspace for vi to also delete newlines
ins_keymap backward-delete-char "$key_info[Backspace]" "$key_info[Backspace2]"

# Space to Accept the item
menu_keymap accept-and-menu-complete ' '

# Tab, Shift Tab Changes the item in the Completion Menu
menu_keymap menu-complete "$_tab"
menu_keymap reverse-menu-complete "$_shifttab"

# q,Esc to exit menu
menu_keymap send-break "$_esc"
menu_keymap send-break 'q'

function _quote_vw {
  zle quote-region
}
visual_keymap _quote_vw "'"

function vi-clear {
  zle kill-whole-line
  zle .vi-insert
}
normal_keymap vi-clear 'q'

# Select till EOL: V
function select-to-end {
  zle set-mark-command
  CURSOR=${#BUFFER}
}
normal_keymap select-to-end 'V'

autoload -Uz edit-command-line
normal_keymap edit-command-line "${_ctrl}e"

function vi-yank-clipboard {
  zle vi-yank
  echo "$CUTBUFFER" | "${CLIPBOARD_COPY[@]}"
}
normal_keymap vi-yank-clipboard 'y'

# yank till EOL
function _viyankeol {
  zle vi-yank-eol
  echo "$CUTBUFFER" | "${CLIPBOARD_COPY[@]}"
}
normal_keymap _viyankeol 'Y'

# Paste from system clipboard
function paste-from-clipboard {
  local _clip=$("${CLIPBOARD_PASTE[@]}")
  _clip=${_clip%%[[:space:]]#}
  BUFFER="${BUFFER:0:$CURSOR}${_clip}${BUFFER:$CURSOR}"
  CURSOR=$(($CURSOR + ${#_clip}))

}
normal_keymap paste-from-clipboard 'p'

function force-steady-bar {
  echo -ne '\e[6 q'
  zle -K viins
}

function fix_cursor {
  if [[ ${KEYMAP} == vicmd ]] || [[ $1 = 'block' ]]; then
    echo -ne '\e[2 q'
  elif [[ ${KEYMAP} == main ]] || [[ ${KEYMAP} == viins ]] ||
    [[ ${KEYMAP} = '' ]] || [[ $1 = 'beam' ]]; then
    echo -ne '\e[6 q'
  fi
}

# Register functions as Widgets
zle -N fix_cursor
zle -N force-steady-bar

autoload -Uz add-zle-hook-widget
add-zle-hook-widget zle-line-init force-steady-bar
add-zle-hook-widget zle-line-finish force-steady-bar
add-zle-hook-widget zle-isearch-exit force-steady-bar
add-zle-hook-widget zle-keymap-select fix_cursor

# cleanup vars
unset -f ins_keymap normal_keymap menu_keymap
unset _esc _ctrl _tab _shifttab _alttab

# initialize cursor
echo -ne '\e[6 q'

#EOF

[marlonrichert]

I am also using powerlevel10k

Have you tried without it? Does the problem then still occur?