docs: use lib.extend instead of patching nixpkgs

This speeds up evaluation and removes IFD. Additionally, this makes it
easier to maintain these library changes, as we don't have to maintain
static patches.

Signed-off-by: Sefa Eyeoglu <[email protected]>

Author: Scrumplex

docs/default.nix

@@ -4,19 +4,37 @@
   pkgs,
 }:
 let
-  pkgsDoc =
-    import
-      (pkgs.applyPatches {
-        name = "nixpkgs-nixvim-doc";
-        src = pkgs.path;
-        patches = [ ./either_recursive.patch ];
-      })
-      {
-        inherit (pkgs) system;
-        config.allowUnfree = true;
+  # Extend nixpkg's lib, so that we can handle recursive leaf types such as `either`
+  lib = pkgs.lib.extend (
+    final: prev: {
+      types = prev.types // {
+        either =
+          t1: t2:
+          (prev.types.either t1 t2)
+          // {
+            getSubOptions = prefix: (t1.getSubOptions prefix) // (t2.getSubOptions prefix);
+          };
+
+        eitherRecursive = t1: t2: (final.types.either t1 t2) // { getSubOptions = _: { }; };
+
+        oneOfRecursive =
+          ts:
+          let
+            head' =
+              if ts == [ ] then
+                throw "types.oneOfRecursive needs to get at least one type in its argument"
+              else
+                builtins.head ts;
+            tail' = builtins.tail ts;
+          in
+          builtins.foldl' final.types.eitherRecursive head' tail';
       };
+    }
+  );
 
-  inherit (pkgsDoc) lib;
+  pkgsDoc = pkgs // {
+    inherit lib;
+  };
 
   nixvimPath = toString ./..;
 

docs/either_recursive.patch

@@ -1,14 +1,18 @@
 {
   perSystem =
     {
-      pkgs,
+      pkgsUnfree,
       config,
       rawModules,
       helpers,
       ...
     }:
     {
-      packages = import ../docs { inherit rawModules pkgs helpers; };
+      packages = import ../docs {
+        inherit rawModules helpers;
+        # Building the docs evaluates each plugin's default package, some of which are unfree
+        pkgs = pkgsUnfree;
+      };
 
       # Test that all packages build fine when running `nix flake check`.
       checks = config.packages;