luaConfig question

[suasuasuasuasua]

Hi, I just learned about and had a question about how to use luaConfig in my nixvim configuration.

I see that we have pre, content, and post attributes. Could anyone give an example or "thought process" on when and how to use these options? I have just been using extraConfigLua up to this point.

Ig, which is preferred? And is this lua code lazily loaded if we have lz-n enabled?

[khaneliman]

The idea with luaConfig is to allow per plugin custom lua injection into the final generated lua. The pre, content, and post allow you to choose where to insert your custom lua code relative to the normal lua code provided by nixvim. Sometimes you want to inject configuration before the plugin gets intiialized and sometimes you have things you want to run right after.

Example from my config:

    jdtls = {
      enable = true;

      lazyLoad.settings.ft = "java";

      luaConfig.pre =
        let
          java-debug = "${pkgs.vscode-extensions.vscjava.vscode-java-debug}/share/vscode/extensions/vscjava.vscode-java-debug/server";
          java-test = "${pkgs.vscode-extensions.vscjava.vscode-java-test}/share/vscode/extensions/vscjava.vscode-java-test/server";
        in
        # Lua
        ''
          local jdtls = require("jdtls")
          local jdtls_dap = require("jdtls.dap")
          local jdtls_setup = require("jdtls.setup")

          _M.jdtls = {}
          _M.jdtls.bundles = {}

          local java_debug_bundle = vim.split(vim.fn.glob("${java-debug}" .. "/*.jar"), "\n")
          local java_test_bundle = vim.split(vim.fn.glob("${java-test}" .. "/*.jar", true), "\n")

          -- add jars to the bundle list if there are any
          if java_debug_bundle[1] ~= "" then
              vim.list_extend(_M.jdtls.bundles, java_debug_bundle)
          end

          if java_test_bundle[1] ~= "" then
              vim.list_extend(_M.jdtls.bundles, java_test_bundle)
          end
        '';

Custom unmanaged telescope extension loading with telescope

{
  config,
  lib,
  pkgs,
  ...
}:
{
  extraPlugins = [
    pkgs.vimPlugins.vs-tasks-nvim
  ];

  plugins.telescope = {
    luaConfig.post = ''
      require("vstask").setup()
      require("telescope").load_extension("vstask")
    '';
  };

  keymaps = lib.mkIf (config.plugins.telescope.enable && (!config.plugins.overseer.enable)) [
    {
      mode = "n";
      key = "<leader>RT";
      action = "<cmd>Telescope vstask tasks<CR>";
      options = {
        desc = "Find tasks";
      };
    }
  ];
}

[suasuasuasuasua]

Ohh okay, that makes more sense to me, thank you for the real examples!

Dumb question, but how do you know if the lua config goes before or after? I see you do local jdtls = require("jdtls") in the luaConfig.pre, but I thought pre means jdtls isn't initialized yet. And when you say initialized, do you mean the setup function is called?

[khaneliman]

Yeah, sorry. The main luaConfig.content is where we call setup for most plugins.

[suasuasuasuasua]

Oh okay gotcha. So if a plugin doesn't have a setting option you need, you add it there in the luaConfig.content like this:

{
  plugins.X = {
    settings = { foo = "bar"; };
    luaConfig.content = ''
      require("X").setup({
        xd = "blah"
      })
    '';
  };
}

Is the config from settings merged with the luaConfig.content and passed to the setup function?

[khaneliman]

No, settings are freeform and support any configuration you want to pass in. If a plugin has luaConfig available it is setup with our modern freeform settings options.

luaConfig is technically just a lib.types.lines collection that you are adding additional lines to the generated final output.

[suasuasuasuasua]

Oh okay, that's really helpful to know. I think I get it now. Thank you for the help!