wunderlib.gradle

buildscript {
    dependencies {}

    repositories {
        gradlePluginPortal()
    }
}
sourceCompatibility = JavaVersion.VERSION_21
targetCompatibility = JavaVersion.VERSION_21

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    maven { url "https://maven.fabricmc.net/" }
    maven { url 'https://jitpack.io' }
}

loom {
}

print("wunderlib.gradle")

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings loom.officialMojangMappings()
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
}

sourceSets {
    main {
        java {
            srcDirs += ['src/client/java', 'src/datagen/java']
        }
    }
}


processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    it.options.release = 21
}

java {
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}


javadoc {
    options {
        source = "21"
        encoding = "UTF-8"
        charSet = "UTF-8"
        memberLevel = JavadocMemberLevel.PROTECTED
        links("https://docs.oracle.com/en/java/javase/17/docs/api/")
        // Disable the crazy super-strict doclint tool in Java 8
        addStringOption("Xdoclint:none", "-quiet")
        addStringOption("noqualifier", "net.minecraft.*:com.mojang.*:net.fabricmc.*")
        addBooleanOption("-allow-script-in-comments", true)
        tags(
                'apiNote:a:API Note:',
                'implSpec:a:Implementation Requirements:',
                'implNote:a:Implementation Note:'
        )
    }


    allprojects.each {
        source(it.sourceSets.main.allJava)
    }

    classpath = files(sourceSets.main.compileClasspath, sourceSets.main.runtimeClasspath)
    include("**/api/**")
    include("de/ambertation/**")
    failOnError true
}

configurations {
    dev {
        canBeResolved = false
        canBeConsumed = true
    }
}

task javadocJar(type: Jar, dependsOn: [javadoc]) {
    archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    dev jar
    archives sourcesJar
    archives javadocJar
}