build.gradle

buildscript {
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.2.2'
    }
}

apply plugin: 'com.android.application'

android {
    defaultConfig {
        versionCode 1
        versionName "1.0"

        minSdkVersion 16
        targetSdkVersion 30

        externalNativeBuild {
            cmake {
                arguments '-DANDROID_STL=c++_shared'
            }
        }
    }

    packagingOptions {
        doNotStrip '*/*/*.so'
    }

    compileSdkVersion 30
    buildToolsVersion "30.0.3"
    ndkVersion "23.1.7779620"

    //lintOptions {
    //    abortOnError false
    //}

    buildFeatures {
        prefab true
    }

    dependencies {
        implementation("com.android.ndk.thirdparty:openssl:1.1.1l-SNAPSHOT")
        implementation("org.resiprocate:resiprocate:1.13.0-SNAPSHOT")
    }

    signingConfigs {
        release {
            storeFile file(System.getenv('HOME') + '/.keystore')
            storePassword 'unset'
            keyAlias System.getenv('SIGNING_KEY')
            keyPassword 'unset'
        }
    }

    buildTypes {
        release {
            signingConfig signingConfigs.release
        }
    }

    externalNativeBuild {
        cmake {
            version '3.18.1'
            path 'jni/CMakeLists.txt'
        }
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
            jni.srcDirs = ['jni']
            jniLibs.srcDir 'libs'
        }
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven {
            url "${rootProject.buildDir}/../../ndkports/build/repository"
        }
    }
}