Blinking when using overwrite_display V3

[GregPlowman]

When using overwrite_display, I observe blinking between each display.

There was no blinking in PrettyTables version 2 when using overwrite keyword.

Here's some code to test each version:

using PrettyTables

function test_overwrite_v2()
    header = (
        ["Time", "Acceleration", "Velocity", "Distance"],
        [   "s",     "[m / s²]",  "[m / s]",      "[m]"]
    )

    hl_p = Highlighter(
        (data, i, j) -> (j == 4) && (data[i, j] > 9), crayon"blue bold"
    )

    hl_v = Highlighter(
        (data, i, j) -> (j == 3) && (data[i, j] > 9), crayon"red bold"
    )

    hl_10 = Highlighter( 
        (data, i, j) -> (i == 10), crayon"fg:white bold bg:dark_gray"
    )

    for start in 0:10
        t = range(; start, length=21)
        data = hcat(t, ones(length(t)), t, 0.5.*t.^2)

        pretty_table(
            data;
            formatters    = ft_printf("%5.2f", 2:4),
            header        = header,
            header_crayon = crayon"yellow bold",
            highlighters  = (hl_10, hl_p, hl_v),
            tf            = tf_unicode_rounded,
            overwrite     = true
        )
        
        sleep(1)
    end
end

function test_overwrite_v3()
    column_labels = [
        ["Time", "Acceleration", "Velocity", "Distance"],
        [ "[s]",     "[m / s²]",  "[m / s]",      "[m]"]
    ]

    hl_p = TextHighlighter(
        (data, i, j) -> (j == 4) && (data[i, j] > 9), crayon"blue bold"
    )

    hl_v = TextHighlighter(
        (data, i, j) -> (j == 3) && (data[i, j] > 9), crayon"red bold"
    )

    hl_10 = TextHighlighter(
        (data, i, j) -> (i == 10), crayon"fg:white bold bg:dark_gray"
    )

    style = TextTableStyle(first_line_column_label = crayon"yellow bold")

    table_format = TextTableFormat(borders = text_table_borders__unicode_rounded)

    for start in 0:10
        t = range(; start, length=21)
        data = hcat(t, ones(length(t)), t, 0.5.*t.^2);
        
        pretty_table(
            data;
            column_labels     = column_labels,
            style             = style,
            highlighters      = [hl_10, hl_p, hl_v],
            table_format      = table_format_format  = TextTableFormat(borders = text_table_borders__unicode_rounded),
            overwrite_display = true
        )
        
        sleep(1)
    end
end

pkgversion(PrettyTables).major == 2 && test_overwrite_v2()
pkgversion(PrettyTables).major == 3 && test_overwrite_v3()

[ronisbr]

Hi @GregPlowman !

Which terminal are you using? I cannot reproduce the issue here.

[GregPlowman]

Which terminal are you using? I cannot reproduce the issue here.

Windows Terminal on Windows 11

[ronisbr]

Hum, I do not have any Windows system to test here :( However, I really do not know what's happening since the algorithm to clean the display is precisely the same.

[ronisbr]

Can you test with a very simple table without any decoration?

[ronisbr]

Btw, what version of Julia and PrettyTables are you using?

[GregPlowman]

Hum, I do not have any Windows system to test here :( However, I really do not know what's happening since the algorithm to clean the display is precisely the same.

Perhaps someone else using Windows could test to see if blinking is reproduced?

Can you test with a very simple table without any decoration?

I still observe blinking without decoration.
I tested with pretty_table(data; column_labels, overwrite_display=true)

Btw, what version of Julia and PrettyTables are you using?

Julia v"1.11.6"
PrettyTables v"2.4.0" - no blinking
PrettyTables v"3.0.4" - blinking

[ronisbr]

Can you please update to PrettyTables 3.0.8? I did some improvements regarding performance.

[GregPlowman]

I tested on PrettyTables 3.0.7 (latest in Registry) and still see blinking.

Here's a more minimal test example:

using Pkg

Pkg.activate(; temp=true)
#Pkg.add(name="PrettyTables", version="2")
Pkg.add(name="PrettyTables", version="3")

using PrettyTables

function test_overwrite()
    for start in 1:10
        t = range(; start, length=5)
        data = hcat(t, t.*t)
        
        if pkgversion(PrettyTables).major < 3
            pretty_table(data; overwrite=true)
        else 
            pretty_table(data; overwrite_display=true)
        end

        sleep(1)
    end
end

test_overwrite()

[ronisbr]

Can you please record a video? I need to understand in what stage it blinks because here it is instantaneous.

[ronisbr]

@GregPlowman I have one idea!

Can you please replace this code in text_backend.jl (end of file):

     if overwrite_display
        num_new_lines = max(count(==('\n'), output_str), 0)
        print(context, "\e[1F\e[2K"^num_new_lines)
    end

    print(context, output_str)

with this one:

    clean_display = ""
     if overwrite_display
        num_new_lines = max(count(==('\n'), output_str), 0)
        clean_display = "\e[1F\e[2K"^num_new_lines
    end

    print(context, clean_display * output_str)

[GregPlowman]

That works. No more blinking!
Thank you.

I actually used the code below which I thought was cleaner.

if overwrite_display
    num_new_lines = max(count(==('\n'), output_str), 0)
    print(context, "\e[1F\e[2K"^num_new_lines * output_str)
else
    print(context, output_str)
end

In any case, it seems a single print avoids blinking, whereas two separate prints cause blinking.

Would you like me to submit a PR?

[ronisbr]

Awesome!

Would you like me to submit a PR?

Please! I will appreciate.