Unable install in home manager with flake

[amirhossein-fzl]

These are the steps I tried to install the Android SDK:

{
  description = "NixOS configuration flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixpkgsStable.url = "github:NixOS/nixpkgs/nixos-25.05";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    android-nixpkgs = {
      url = "github:tadfisher/android-nixpkgs";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, nixpkgsStable, home-manager, android-nixpkgs, ... }@inputs: 
  let 
    system = "x86_64-linux";
    specialArgs = {
      inherit inputs;

      nixpkgsStable = import nixpkgsStable {
        system = "x86_64-linux";
        config.allowUnfree = true;
      };

      android-sdk = android-nixpkgs.sdk.${system} (sdkPkgs: with sdkPkgs; [
        cmdline-tools-latest
        platform-tools
        build-tools-36-0-0
        build-tools-35-0-0
        
        platforms-android-36
        platforms-android-35
        
        system-images-android-36-google-apis-x86-64
        system-images-android-35-google-apis-x86-64
        
        ndk-28-2-13676358
        
        emulator
      ]);

    };
  in
  {
    nixosConfigurations = {
      nixos = nixpkgs.lib.nixosSystem {
        inherit system specialArgs;
        modules = [
          ./nixos/configuration.nix
          ./modules/programs.nix
          ./modules/packages.nix

          home-manager.nixosModules.home-manager
          {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.users.amirhossein = import ./users/amirhossein;
            home-manager.extraSpecialArgs = specialArgs;
          }
        ];
      };
    };
  };
}

users/amirhossein/default.nix:

{inputs, ...}:
{
  imports = [
    ./fonts.nix
    ./home.nix
    ./packages.nix
    ./services
    inputs.android-nixpkgs.hmModule
    ./programs
  ];
}

users/amirhossein/programs/android-sdk.nix:

{config, ...}:
{
  android-sdk = {
    enable = true;
    path = "${config.home.homeDirectory}/.android/sdk";
    packages = sdk: with sdk; [
      cmdline-tools-latest
      platform-tools
      build-tools-36-0-0
      build-tools-35-0-0
      platforms-android-36
      platforms-android-35
      system-images-android-36-google-apis-x86-64
      system-images-android-35-google-apis-x86-64
      ndk-28-2-13676358
      emulator
    ];
  };
  
}

And i get this error:

error:
       … while calling the 'head' builtin
         at /nix/store/9rfm3gjhphdvi7qnzdsi7piw1gi4c8vp-source/lib/attrsets.nix:1701:13:
         1700|           if length values == 1 || pred here (elemAt values 1) (head values) then
         1701|             head values
             |             ^
         1702|           else

       … while evaluating the attribute 'value'
         at /nix/store/9rfm3gjhphdvi7qnzdsi7piw1gi4c8vp-source/lib/modules.nix:1118:7:
         1117|     // {
         1118|       value = addErrorContext "while evaluating the option `${showOption loc}':" value;
             |       ^
         1119|       inherit (res.defsFinal') highestPrio;

       … while evaluating the option `system.build.toplevel':

       … while evaluating definitions from `/nix/store/9rfm3gjhphdvi7qnzdsi7piw1gi4c8vp-source/nixos/modules/system/activation/top-level.nix':

       … while evaluating the option `warnings':

       … while evaluating definitions from `/nix/store/9rfm3gjhphdvi7qnzdsi7piw1gi4c8vp-source/nixos/modules/system/boot/systemd.nix':

       … while evaluating the option `systemd.services.home-manager-amirhossein.serviceConfig':

       … while evaluating definitions from `/nix/store/y9whb4n02wws1ficqcs9z4r77v4982di-source/nixos':

       … while evaluating the option `home-manager.users.amirhossein.home.file."/home/amirhossein/.android/sdk".source':

       … while evaluating definitions from `/nix/store/9rfm3gjhphdvi7qnzdsi7piw1gi4c8vp-source/flake.nix':

       … while evaluating the option `home-manager.users.amirhossein.android-sdk.finalPackage':

       … while evaluating definitions from `/nix/store/9rfm3gjhphdvi7qnzdsi7piw1gi4c8vp-source/flake.nix':

       (stack trace truncated; use '--show-trace' to show the full, detailed trace)

       error: attribute 'androidSdk' missing
       at /nix/store/116fjq8anzv1xh2prg3m1k3ak7r0s2ps-source/hm-module.nix:48:32:
           47|   config = mkIf (cfg.enable) {
           48|     android-sdk.finalPackage = pkgs.androidSdk cfg.packages;
             |                                ^
           49|
       Did you mean androidsdk?
Command 'nix --extra-experimental-features 'nix-command flakes' build --print-out-paths '/etc/nixos#nixosConfigurations."nixos".config.system.build.toplevel' --no-link' returned non-zero exit status 1.

[neversad-dev]

I'm experiencing the same issue. Same error when using android-nixpkgs with Home Manager via flakes:

error: attribute 'androidSdk' missing
at «github:tadfisher/android-nixpkgs/...»/hm-module.nix:48:32:
    48|     android-sdk.finalPackage = pkgs.androidSdk cfg.packages;
          |                                ^
Did you mean androidsdk?

Setup: Home Manager standalone, flake-based, importing android-nixpkgs.hmModule.

[MaikoTan]

Same issue here, and I seem to figure out a way to fix it.
By adding the overlay from android-nixpkgs directly into the flake,
the androidSdk attribute becomes available in home-manager module.
So the following is part of my modified flake.nix file.

flake.nix

{
  inputs = {
    # NixOS channels
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    android-nixpkgs = {
      url = "github:tadfisher/android-nixpkgs/stable";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { nixpkgs, ... }@inputs:
    let
+     overlays = [
+       inputs.android-nixpkgs.overlays.default
+     ];
    in
    {
      nixosConfigurations.nixos = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {
          inherit inputs;
        };
        modules = [
+         {
+           nixpkgs.overlays = overlays; # This line imports the overlay so that `androidSdk` attibute is available
+         }
          {
            nixpkgs.config.allowUnfree = true;
            nixpkgs.config.allowUnfreePredicate = _: true;
            nixpkgs.config.android_sdk.accept_license = true;
          }
          {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.extraSpecialArgs = { inherit inputs; };
            home-manager.users.maiko = import ./modules/home-manager;
          }
        ];
      };
    };
}