build.gradle

plugins {
    id 'java'
    id 'application'
}

version = '1.5.1'


repositories { 
    mavenCentral() 
}

targetCompatibility = "1.8"
sourceCompatibility = "1.8"

afterEvaluate {
    if(project.hasProperty("hprof")) {
        applicationDefaultJvmArgs = ["-Xrunhprof:cpu=times,depth=10", "-Xmx768m"]
    } else {
        applicationDefaultJvmArgs = ["-Xms768m", "-Xmx8g"]
    }
}

dependencies {
    compile 'commons-cli:commons-cli:1.2' 
    compile 'com.edropple.jregex:jregex:1.2_01'
    compile('com.github.samtools:htsjdk:2.8.0') {
        transitive = false
    }
    // https://mvnrepository.com/artifact/org.powermock/powermock-module-junit4
    testCompile group: 'org.powermock', name: 'powermock-api-mockito', version: '1.6.6'
    testCompile group: 'org.powermock', name: 'powermock-module-testng', version: '1.6.6'
    testCompile'org.testng:testng:6.9.13.6'
}

mainClassName = "com.astrazeneca.vardict.Main"

startScripts {
    doLast {
        unixScript.text = unixScript.text.replaceAll(/(DEFAULT_JVM_OPTS=.*)/){ all, group -> 
"""${group}

if [ -n "\$${optsEnvironmentVar}" ] ; then
    DEFAULT_JVM_OPTS=''
fi
"""
        }
    }
}

javadoc {
    options.noQualifiers 'java.lang:java.io:java.util'
    options.memberLevel=JavadocMemberLevel.PACKAGE
    exclude '**/ConcurrentHashSet*'
    exclude '**/Utils*'
    exclude '**/Tuple*'
    exclude '**/Main*'
}


test {
    // enable TestNG support (default is JUnit)
    useTestNG()
}