audio: rework modules, forward pipewire socket to gui-vm

- introduced 'server' and 'client' configs
- audio-vm is now the 'server', in charge of all audio hw
- all other systems are now 'clients'
- 'clients' can optionally enable pw socket forwarding
- removed all audio-related configs from gui-vm/cosmic
- removed ghaf-audio namespace
- removed ghaf audio control tool, replaced by pavucontrol
- re-enabled all sound-related settings in cosmic DE

Signed-off-by: Kajus Naujokaitis <[email protected]>

Author: kajusnau

modules/common/services/audio.nix

@@ -0,0 +1,93 @@
+# SPDX-FileCopyrightText: 2026 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+let
+  useGivc = config.ghaf.givc.enable;
+  cfg = config.ghaf.services.audio;
+  host = "audio-vm";
+  port =
+    if cfg.client.pipewireControl.enable then
+      cfg.server.pulseaudioTcpControlPort
+    else
+      cfg.server.pulseaudioTcpPort;
+  address = "tcp:${host}:${toString port}";
+
+in
+{
+  options.ghaf.services.audio = {
+    client = {
+      remotePulseServerAddress = lib.mkOption {
+        type = lib.types.str;
+        default = address;
+        defaultText = address;
+        description = ''
+          Address of the remote PulseAudio server to connect to.
+
+          This should point to the main Ghaf audio server.
+        '';
+      };
+      pipewireControl = {
+        enable = lib.mkEnableOption ''
+          PipeWire control forwarding to gui-vm client.
+
+          This allows gui-vm to control audio settings via PipeWire.
+          Requires givc to be enabled on both client and server.
+
+          To use it, set the `PIPEWIRE_RUNTIME_DIR` environment variable to /tmp.
+          `PIPEWIRE_RUNTIME_DIR` can be set for the entire session but is not recommended,
+          as it may interfere with local PipeWire instances.
+        '';
+        socket = lib.mkOption {
+          type = lib.types.str;
+          readOnly = true;
+          default = "/tmp/pipewire-0";
+          description = ''
+            Path where the PipeWire socket is available for control operations.
+          '';
+        };
+      };
+    };
+  };
+  config = lib.mkIf (cfg.enable && (cfg.role == "client")) (
+    lib.mkMerge [
+      {
+        environment = {
+          systemPackages = [ pkgs.pulseaudio ];
+          sessionVariables = {
+            PULSE_SERVER = "${cfg.client.remotePulseServerAddress}";
+          };
+          variables = {
+            PULSE_SERVER = "${cfg.client.remotePulseServerAddress}";
+          };
+        };
+      }
+      # givc socket proxy is declared in modules/givc/guivm.nix
+      (lib.mkIf (cfg.client.pipewireControl.enable && useGivc) {
+        assertions = [
+          {
+            assertion = config.system.name == "gui-vm";
+            message = "PipeWire control forwarding can only be enabled on gui-vm.";
+          }
+          {
+            assertion = useGivc;
+            message = "GIVC must be enabled on audio clients when enabling Ghaf audio server control forwarding.";
+          }
+        ];
+
+        environment = {
+          systemPackages = with pkgs; [
+            pipewire
+            # `pwwvucontrol` is a good Rust-based alternative for pure PipeWire
+            # but it lacks some features and polish compared to `pavucontrol`
+            pavucontrol
+          ];
+        };
+      })
+    ]
+  );
+}

modules/common/services/audio/client.nix

@@ -0,0 +1,28 @@
+# SPDX-FileCopyrightText: 2022-2026 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  lib,
+  ...
+}:
+{
+  imports = [
+    ./server.nix
+    ./client.nix
+  ];
+
+  options.ghaf.services.audio = {
+    enable = lib.mkEnableOption "Enable Ghaf audio services";
+    role = lib.mkOption {
+      type = lib.types.enum [
+        "server"
+        "client"
+      ];
+      default = "client";
+      description = ''
+        The role of this VM in the Ghaf audio topology.
+        - "server" controls audio hardware and runs the main audio server
+        - "client" connects to the audio server to play/record (and optionally control) audio
+      '';
+    };
+  };
+}