How do I specify the dune profile in buildOpamProject?

[MarcCoquand]

Heya!

I'm trying to understand how the syntax work if I wish to specify the profile for the nix flake. If I have the following

(env
 (dev
  (flags (:standard -w +42)))
 (release
  (ocamlopt_flags (:standard -O3))))

in my dune file, and I'd like to specify the following nix.flake to use the release profile for nix run ., how can I do so? My nix flake is:

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
    opam-nix.url = "github:tweag/opam-nix";
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.follows = "opam-nix/nixpkgs";
  };
  outputs = { self, flake-utils, opam-nix, nixpkgs }@inputs:
    let package = "ann";
    in flake-utils.lib.eachDefaultSystem (system:
      let
        goMigrate = nixpkgs.legacyPackages.${system}.go-migrate;
        pkgs = nixpkgs.legacyPackages.${system};
        on = opam-nix.lib.${system};
        devPackagesQuery = {
          # You can add "development" packages here. They will get added to the devShell automatically.
          ocaml-lsp-server = "*";
          ocamlformat = "*";
          ocamlfind = "1.9.5";
          utop = "*";
        };
        query = devPackagesQuery // {
          ## You can force versions of certain packages here, e.g:
          ## - force the ocaml compiler to be taken from opam-repository:
          ocaml-base-compiler = "*";
          ## - or force the compiler to be taken from nixpkgs and be a certain version:
          # ocaml-system = "4.14.0";
          ## - or force ocamlfind to be a certain version:
        };
        scope = on.buildOpamProject' { } ./. query;
        overlay = final: prev: {
          # You can add overrides here
          ${package} = prev.${package}.overrideAttrs (_: {
            # Prevent the ocaml dependencies from leaking into dependent environments
            doNixSupport = false;
            buildInputs = [ 
              pkgs."gmp"
              pkgs."libev"
              pkgs."openssl"
              pkgs."libargon2"
            ];
          });
        };
        scope' = scope.overrideScope' overlay;
        # The main package containing the executable
        main = scope'.${package};
        # Packages from devPackagesQuery
        devPackages = builtins.attrValues
          (pkgs.lib.getAttrs (builtins.attrNames devPackagesQuery) scope');
      in {
        legacyPackages = scope';

        packages.default = main;

        apps.ann.default = {
          type = "app";
          program = "${main}/bin/ann";
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ main ];
          buildInputs = devPackages ++ [

          ];
        };
      });
}

[balsoft]

Hi! I think you can change your overlay something like that:

        overlay = final: prev: {
          # You can add overrides here
          ${package} = prev.${package}.overrideAttrs (_: {
            # Prevent the ocaml dependencies from leaking into dependent environments
            doNixSupport = false;
            buildInputs = [ 
              pkgs."gmp"
              pkgs."libev"
              pkgs."openssl"
              pkgs."libargon2"
            ];
            DUNE_PROFILE = "release";
          });
        };

Alternatively, just modify your opam file to call dune build -p <...> , in which case the release profile will be selected by default.

[MarcCoquand]

Awesome, I'll test it out and see how it goes. Thanks!