Merge pull request #98 from urschrei/shugel/push-kvxttvnpkznr

Switch to scikit-build

Author: urschrei

.github/workflows/wheels.yml

@@ -10,7 +10,13 @@ env:
   rustlib: polylineffi
   wheelname: pypolyline
 
-on: [push, pull_request]
+on:
+  pull_request:
+  push:
+    branches:
+      - master
+    tags:
+      - 'v*'
 
 jobs:
   get_latest_lib_tag:

CMakeLists.txt

@@ -0,0 +1,75 @@
+cmake_minimum_required(VERSION 3.15...3.27)
+project(${SKBUILD_PROJECT_NAME} LANGUAGES C)
+
+# Find Python
+find_package(
+  Python
+  COMPONENTS Interpreter Development.Module NumPy
+  REQUIRED)
+
+# Get NumPy include directory
+message(STATUS "NumPy include directory: ${Python_NumPy_INCLUDE_DIRS}")
+
+# Cythonize the .pyx file to .c
+add_custom_command(
+  OUTPUT cutil.c
+  COMMENT "Cythonizing ${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline/cutil.pyx"
+  COMMAND Python::Interpreter -m cython
+          "${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline/cutil.pyx"
+          --output-file cutil.c
+          -I "${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline"
+  DEPENDS src/pypolyline/cutil.pyx src/pypolyline/pypolyline_p.pxd
+  VERBATIM)
+
+# Create the extension module
+python_add_library(cutil MODULE cutil.c WITH_SOABI)
+
+# Set include directories
+target_include_directories(cutil PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline
+  ${Python_NumPy_INCLUDE_DIRS}
+)
+
+# Link against the Rust library
+# The library is pre-built and located in src/pypolyline/
+find_library(POLYLINE_LIBRARY
+  NAMES polylineffi libpolylineffi
+  PATHS ${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline
+  NO_DEFAULT_PATH
+  REQUIRED
+)
+message(STATUS "Found Rust polyline library: ${POLYLINE_LIBRARY}")
+
+target_link_libraries(cutil PRIVATE ${POLYLINE_LIBRARY})
+
+# Set RPATH for different platforms
+if(APPLE)
+  set_target_properties(cutil PROPERTIES
+    INSTALL_RPATH "@loader_path"
+    BUILD_WITH_INSTALL_RPATH TRUE
+  )
+elseif(UNIX)
+  set_target_properties(cutil PROPERTIES
+    INSTALL_RPATH "$ORIGIN"
+    BUILD_WITH_INSTALL_RPATH TRUE
+  )
+endif()
+
+# Install the extension module
+install(TARGETS cutil DESTINATION pypolyline)
+
+# Install the shared library
+if(APPLE)
+  set(POLYLINE_LIB_NAME "libpolylineffi.dylib")
+elseif(UNIX)
+  set(POLYLINE_LIB_NAME "libpolylineffi.so")
+elseif(WIN32)
+  set(POLYLINE_LIB_NAME "polylineffi.dll")
+endif()
+
+install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline/${POLYLINE_LIB_NAME}
+        DESTINATION pypolyline)
+
+# Install header file
+install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/pypolyline/header.h
+        DESTINATION pypolyline)

README.md

@@ -3,8 +3,15 @@
 # Fast Google [Polyline](https://developers.google.com/maps/documentation/utilities/polylinealgorithm) Encoding and Decoding
 
 ## Installation
+`uv add pypolyline`  
 `pip install pypolyline`  
 
+### Installing for local development
+1. Ensure you have a copy of `libpolylineffi` and `header.h` from https://github.com/urschrei/polyline-ffi/releases, and it's in the `src/pypolyline` subdir
+2. run `uv sync --dev`
+3. run `pytest .`
+4. If you make changes, you must rebuild the extension: `uv sync --reinstall`
+
 ### Supported Python Versions
 All [_currently_ supported Python versions](https://devguide.python.org/versions/).
 

pyproject.toml

@@ -1,7 +1,8 @@
 [project]
 name = "pypolyline"
-dynamic = ["version", "readme"]
+version = "0.5.7"
 description = "Fast Google Polyline encoding and decoding using Rust FFI"
+readme = "README.md"
 requires-python = ">=3.10"
 dependencies = [
     "numpy >= 2.0.0",
@@ -29,34 +30,32 @@ classifiers = [
 Repository = "https://github.com/urschrei/pypolyline"
 Tracker = "https://github.com/urschrei/pypolyline/issues"
 
-[project.optional-dependencies]
-test = ["pytest >= 7.4.2"]
+[dependency-groups]
+dev = [
+    "pytest>=8.4.1",
+]
 
-[tool.setuptools.dynamic]
-readme = {file = "README.md", content-type = "text/markdown"}
+[tool.scikit-build]
+minimum-version = "build-system.requires"
+wheel.packages = ["src/convertbng"]
 
 [build-system]
-build-backend = "setuptools.build_meta"
 requires = [
-    "setuptools >= 45",
-    "setuptools-scm[toml] >= 6.2",
+    "scikit-build-core>=0.10",
     "numpy >= 2.0.0",
-    "cython >= 3.0.0",
-    "wheel >= 0.29.0",
+    "cython >= 3.1.0",
 ]
+build-backend = "scikit_build_core.build"
 
 [tool.pytest.ini_options]
-minversion = "6.2.2"
+minversion = "8.4.1"
 addopts = [
     "--import-mode=importlib",
 ]
 testpaths = [
     "tests",
 ]
 
-[tool.setuptools_scm]
-write_to = "src/_version.py"
-
 [tool.ruff]
 exclude = [
     ".bzr",
@@ -99,5 +98,3 @@ quote-style = "double"
 
 # Like Black, indent with spaces, rather than tabs.
 indent-style = "space"
-
-