Добавить библиотечный шаг я запоминаю навигационную ссылку текущего окна в переменной

[asheichenko]

Хотелось бы иметь следующую функциональность
Иногда требуется повторное переоткрытие окна, например я провожу документ по статусам, создал документ в статусе "новый", записал документ и закрыл окно, затем открываю этот же документ и сохраняю его в статусе "согласован":

Предлагаю добавить библиотечные шаги:
Я запоминаю навигационную ссылку текущего окна в глобальной переменной "ИмяПеременной"
и Я запоминаю навигационную ссылку текущего окна в переменной "ИмяПеременной"

[artbear]

Хорошее предложение.

Один вопрос:
А как потом открыть эту нави-ссылку из переменной?

Получается, что нужны еще шаги

• Я открываю навигационную ссылку из переменной "ИмяПеременной"
• Я открываю навигационную ссылку из глобальной переменной "ИмяПеременной"

@asheichenko или я неправ?

[asheichenko]

Думаю да, сейчас есть только один библиотечный шаг
Дано Я открываю навигационную ссылку "e1cib/data/Справочник.Справочник1?ref=ad018df0619b11d5458a440b8c472f30"

[yadimetrio]

Я бы предложил не делать отдельные шаги для открытия сохраненной ссылки, а использовать существующий только с указанием спецсимволов в переменной "я перехожу по навигационной ссылке "$ИмяПеременной$""

[artbear]

Да, можно и так сделать.

[asheichenko]

Прошу помощи, застрял с вопросом как получить навигационную ссылку на объект. Я могу получить текущую форму как тип ТестируемаяФорма. А как для нее получить ссылку, возник ступор.

[artbear]

лучше достучаться до типа метаданного и в зависимости от этого

• либо как-то получать ссылку на ссылочный элемент из формы
• либо сразу генерить навиг.ссылку на форму - списки, отчеты, обработки и т.п.

но я сам задачей выделения навиг.ссылки в тест.АПИ не занимался :(

[yadimetrio]

Лучше действовать от ссылки, мне кажется.
Если исходить из описания задачи, то:

• Храним ссылку в контексте, в переменной "Ссылка", например.
• Дорабатываем шаг "я перехожу по навигационной ссылке ""$Ссылка$"". В этом шаге, если передана не нав. ссылка, а переменная, получить нав. ссылку по ссылке и открыть.

Минус в том что не основную форму так не откроешь. Для не основных, проще через нажатие кнопки в интерфейсе "Получить навигационную ссылку". Но вряд ли это стоит в библиотеках делать.

[asheichenko]

лучше достучаться до типа метаданного и в зависимости от этого

• либо как-то получать ссылку на ссылочный элемент из формы
• либо сразу генерить навиг.ссылку на форму - списки, отчеты, обработки и т.п.

но я сам задачей выделения навиг.ссылки в тест.АПИ не занимался :(

Ну до метаданных я смогу достучаться из заголовка тестируемой формы, а вот как потом получить ссылку открытой формы не могу понять. Методы ПолучитьНавигационнуюСсылку, работают или для объекта типа ОкноКлиентскогоПриложения или для глобального контекста ПолучитьНавигационнуюСсылку(<Объект>, <ИмяРеквизита>, <Индекс>) . Если я передаю в качестве объекта тип ТестируемаяФорма, то возвращается пустая строка.
Посмотрел даже типовые кнопки "Получить ссылку" в клиенте тестирования недоступны.

• обычный режим
  
• режим клиента тестирования
  
  Попробую продублировать вопрос на партнерскую конференцию

[artbear]

Ага, про партнерку правильная мысль.

Скинешь ссылку, я также проголосую за твой вопрос.

[asheichenko]

https://partners.v8.1c.ru/forum/t/1759315/m/1759315

[shureek]

Недавно только разбирался с этим вопросом: https://partners.v8.1c.ru/forum/topic/1759566
Сделал расширение, чтобы это получить: Помощник тестирования.zip

В доп. модуле тестирования сделал такую функцию:

Функция ПолучитьНавигационнуюСсылкуОкна()
	ГлавноеОкноТестируемого = Ванесса.ПолучитьГлавноеОкноИзТестовоеПриложение();
	ГлавноеОкноТестируемого.ВыполнитьКоманду("e1cib/command/ОбщаяКоманда.Тест_ПолучитьНавигационнуюСсылку");
	
	АктОкно = Ванесса.ПолучитьАктивноеОкноИзТестовоеПриложение();
	Сообщения = АктОкно.ПолучитьТекстыСообщенийПользователю();
	НавСсылка = Сообщения[Сообщения.ВГраница()];
	АктОкно.ЗакрытьПанельСообщенийПользователю();
	
	Возврат НавСсылка;
КонецФункции

и на сервере ещё вот такую для преобразования навигационной ссылки в обычную:

Функция НавигационнаяСсылкаВЗначение(знач Стр)
	// Стр = e1cib/data/Документ.ПриобретениеТоваровУслуг?ref=b6af00112233445511e8c88c40bab506
	Если не СтрНачинаетсяС(Стр, "e1cib/data/") тогда
		ВызватьИсключение "Неверный формат ссылки (" + Стр + ")";
	КонецЕсли;
	
	ПозВопр = СтрНайти(Стр, "?", , 12);
	ПолноеИмяМД = Сред(Стр, 12, ПозВопр - 12); // Документ.ПриобретениеТоваровУслуг
	Если Сред(Стр, ПозВопр + 1, 4) <> "ref=" тогда
		ВызватьИсключение "Неверный формат ссылки (" + Стр + ")";
	КонецЕсли;
	
	СтрИД = Сред(Стр, ПозВопр + 5); // b6af00112233445511e8c88c40bab506
	
	ПозТчк = СтрНайти(ПолноеИмяМД, ".");
	ВидМД = Лев(ПолноеИмяМД, ПозТчк - 1);  // Документ
	ИмяМД = Сред(ПолноеИмяМД, ПозТчк + 1); // ПриобретениеТоваровУслуг
	
	ТипСсылки = Тип(ВидМД + "Ссылка." + ИмяМД);
	
	Если СтрДлина(СтрИД) <> 32 тогда
		ВызватьИсключение "Неверный формат ссылки (" + Стр + ")";
	КонецЕсли;
	
	// b6af00112233445511e8c88c40bab506 -> 40bab506-c88c-11e8-b6af-001122334455
	СтрУИД = Сред(СтрИД, 25, 8) + "-" + Сред(СтрИД, 21, 4) + "-" + Сред(СтрИД, 17, 4) + "-" + Лев(СтрИД, 4) + "-" + Сред(СтрИД, 5, 12);
	
	Возврат XMLЗначение(ТипСсылки, СтрУИД);
КонецФункции