Failed to read struct data from struct File

[LukyGuyLucky]

As an exercise,I just want to learn console input/out writing/reading typed data via file.Mainly used os.write_struct[T] and os.read_struct[T].
But unfortunately I failed to read back from file created.Both address & addr (by value & by reference has been tried.Don't know whether the file created is broken,in bad format,or just failed to read.

Help would be match appreciated.

running information:

E:\Learning\vlangpack\ex\consolecn\bin
Enter a street:aaa
Enter a city:bbb
Enter a zip code:33
&Address{
    street: 'aaa'
    city: 'bbb'
    zip: 33
}-----------------------
Struct file created successfully
File opened for process---
Failed to read struct data from file

source:

module main
import os
import strconv

struct Address{
	pub:
	street string
	city string
	zip int
}
fn make_address() Address {
	print('Enter a street:')
	street:=os.get_line()
	print('Enter a city:')
	city:=os.get_line()
	print('Enter a zip code:')
	zipstr:=os.get_line()
	zip:=strconv.atoi(zipstr) or {
		println('Failed to make a number')
		return Address{}
	}
	return Address{
		street:street
		city:city
		zip:zip
	}
}
fn main() {
	path2:='address.txt'
	mut addr:=make_address()
	mut address:=&addr
	print(address)
	println('-----------------------')
	mut file1:=os.create(path2)!
	file1.write_struct[Address](addr) or {
		println('Failed to write struct data to file')
		return
	}
	file1.close()
	println('Struct file created successfully')

	file1.reopen(path2,"r") or {
		println('Failed to open file $file1')
	}
	println('File opened for process---')

	file1.read_struct[Address](mut addr) or {
		println('Failed to read struct data from file')
		return
	}
	println('adress:{$addr')
}

[gechandesu]

Print the err value:

file1.read_struct[Address](mut addr) or {
                println('Failed to read struct data from file: ${err}')
                return                                        

File opened for process---
Failed to read struct data from file: os.FileNotOpenedError: os: file not opened

os.File.reopen() does not set the internal flag File.is_open to true: https://github.com/vlang/v/blob/master/vlib/os/file.c.v#L217 this cause file not opened error.

It calls C.freopen. From man:

The freopen() function opens the file whose name is the string pointed to by path and associates the stream pointed to by stream with it. The original stream (if it exists) is closed. The mode argument is used just as in the fopen() function. The primary use of the freopen() function is to change the file associated with a standard text stream (stderr, stdin, or stdout). 

Just open new file via os.open instead of existing one and read it.

mut file2 := os.open(path2)!

file2.read_struct[Address](mut addr) or {
                println('Failed to read struct data from file: ${err} ${typeof(err).name}')
                return
        }

~ $ v run struct.v
Enter a street:aaa
Enter a city:bbb
Enter a zip code:123
&Address{
    street: 'aaa'
    city: 'bbb'
    zip: 123
}-----------------------
Struct file created successfully
adress:{Address{
    street: 'aaa'
    city: 'bbb'
    zip: 123
}

[JalonSolov]

Your final println has bad syntax for printing the addr value. Instead of

	println('adress:{$addr')

it should be

	println('adress:${addr}')

There's really no reason to take the address of addr and assign it to address, either.

Here's how I changed your example:

module main

import os
import strconv

struct Address {
pub:
        street string
        city   string
        zip    int
}

fn make_address() Address {
        print('Enter a street:')
        street := os.get_line()
        print('Enter a city:')
        city := os.get_line()
        print('Enter a zip code:')
        zipstr := os.get_line()
        zip := strconv.atoi(zipstr) or {
                println('Failed to make a number')
                return Address{}
        }
        return Address{
                street: street
                city:   city
                zip:    zip
        }
}

fn main() {
        path2 := 'address.txt'
        mut addr := make_address()
        print(addr)
        println('-----------------------')
        mut file1 := os.create(path2)!
        file1.write_struct(addr)!
        file1.close()
        println('Struct file created successfully')

        println('Clearing struct for read')
        addr = Address{}
        println(addr)

        file1 = os.open(path2)!
        println('File opened for process---')

        file1.read_struct(mut addr) or {
                println('Failed to read struct data from file')
                return
        }
        println(addr)
}

[LukyGuyLucky]

Thank you all for the help!!