-
Notifications
You must be signed in to change notification settings - Fork 11
/
characters.xsl
1340 lines (1236 loc) · 40 KB
/
characters.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0"?>
<!--
$Id: characters.xsl,v 1.71 2015/07/05 15:41:38 dcarlis Exp $
mml6.xsl David Carlisle
Generate bycodes.html, byalpha.html and the alphabetic glyph tables
originally for MathML chapter 6.
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0"
xmlns:d="data:,dpc"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="d xs">
<xsl:import href="xmlspec.xsl"/>
<xsl:param name="none" select="false()"/>
<xsl:output encoding="US-ASCII"
include-content-type="no"
omit-xml-declaration="yes"/>
<xsl:param name="cssbase" select="'//www.w3.org/StyleSheets/TR/'"/>
<xsl:param name="baseuri" select="'//www.w3.org/2003/entities/'"/>
<xsl:param name="resultbase" select="'2007doc/'"/>
<xsl:param name="editors-copy" select="''"/>
<xsl:param name="script" select="'no'"/>
<xsl:param name="longtitle" select="'yes'"/>
<xsl:variable name="css" as="element()*">
<style type="text/css">
.base {background-color: #EEEEEE;}
.kwlabel {font-weight:normal}
</style>
<link rel="stylesheet" type="text/css" href="{$cssbase}W3C-{
if($editors-copy) then 'ED' else upper-case(/spec/@w3c-doctype)}.css"/>
</xsl:variable>
<xsl:template name="css">
<xsl:copy-of select="$css"/>
</xsl:template>
<xsl:param name="glyphs" select="'http://www.w3.org/2003/entities/glyphs'"/>
<xsl:strip-space elements="group"/>
<xsl:variable name="u" select="doc('unicode.xml')"/>
<xsl:variable name="blocks" select="$u/unicode/unicodeblocks/block"/>
<xsl:variable name="hex" select="('0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F')"/>
<xsl:key name="set" match="entity" use="@set"/>
<xsl:key name="id" match="character" use="@id"/>
<xsl:key name="mathvariant" match="character[surrogate]" use="surrogate/@mathvariant"/>
<xsl:template match="/">
<xsl:result-document
method="html"
encoding="US-ASCII"
include-content-type="no"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="index.html">
<xsl:apply-templates/>
</xsl:result-document>
<xsl:apply-templates select="$u/unicode/entitygroups/group[@name='2007']/set"/>
<xsl:apply-templates select="$u/unicode/charlist"/>
</xsl:template>
<xsl:variable name="blockstarts" select="('000','001','002','003','004',
'006',
'020','021','022','023','024','025','026','027','029','02A','02B',
'0FB','0FE',
'1D4','1D5','1D6','1D7','1EE',
'1F7','1F8')"/>
<xsl:template match="charlist">
<xsl:for-each select="../mathvariants/mathvariant">
<xsl:call-template name="letter-like">
<xsl:with-param name="mathvariant" select="@name"/>
<xsl:with-param name="title" select="@description"/>
</xsl:call-template>
</xsl:for-each>
<xsl:for-each select="$blockstarts">
<xsl:call-template name="code-chart">
<xsl:with-param name="range" select="."/>
</xsl:call-template>
</xsl:for-each>
<xsl:call-template name="bycodes"/>
<xsl:call-template name="byalpha"/>
</xsl:template>
<xsl:template match="group[@name='predefined']"/>
<xsl:template match="group">
<xsl:result-document method="html"
include-content-type="no"
encoding="US-ASCII"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="{$resultbase}overview-{@name}.html">
<html>
<head>
<meta http-equiv="Content-type" content="text/html;charset=UTF-8"/>
<title><xsl:value-of select="@name"/></title>
</head>
<body>
<h1><xsl:value-of select="@name"/></h1>
<p>
<a href="../index.html">Overview</a>
</p>
<table>
<tr>
<td> </td>
<td> </td>
<td> </td>
<td> <a href="../{@name}/{@name}map.xsl">XSLT 2 character map</a> </td>
</tr>
<xsl:for-each select="set">
<xsl:variable name="f">
<xsl:apply-templates select="." mode="name"/>
</xsl:variable>
<xsl:if test="string($f)">
<tr>
<th><xsl:value-of select="$f"/></th>
<td> <a href="{$f}.html">HTML Description</a> </td>
<td> <a href="{$baseuri}{../@name}/{$f}.ent">Entity Declarations</a> </td>
<td> <a href="{$baseuri}{../@name}/{$f}map.xsl">XSLT 2 character map</a> </td>
</tr>
</xsl:if>
</xsl:for-each>
</table>
</body>
</html>
</xsl:result-document>
<xsl:apply-templates select="set[not(../@name='mathml') or starts-with(@name,'m')]"/>
</xsl:template>
<xsl:template match="set" mode="name">
<xsl:choose>
<xsl:when test="../@name='mathml' and not(starts-with(@name,'m'))"/>
<xsl:when test="starts-with(@name,'957')"><xsl:value-of select="substring(@name,11)"/></xsl:when>
<xsl:when test="starts-with(@name,'88')"><xsl:value-of select="substring-after(@name,'-')"/></xsl:when>
<!--<xsl:when test="starts-with(@name,'html')"><xsl:value-of select="substring-after(@name,'-')"/></xsl:when>-->
<xsl:otherwise><xsl:value-of select="@name"/></xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:variable name="sets" select="$u/unicode/entitygroups/group[@name='2007']/set"/>
<xsl:template match="set"/>
<xsl:template match="group[@name='2007']/set">
<xsl:variable name="set" select="@name"/>
<xsl:variable name="f">
<xsl:apply-templates select="." mode="name"/>
</xsl:variable>
<xsl:variable name="t"
select="upper-case($f)"/>
<xsl:result-document method="html"
include-content-type="no"
encoding="US-ASCII"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="{$resultbase}{$f}.html">
<html>
<head>
<title><xsl:value-of select="$t"/></title>
<style type="text/css">
.ignore {background-color: #AAAAAA;}
.base {background-color: #CCCCCC;}
</style>
<xsl:copy-of select="$css"/>
</head>
<body>
<h1><xsl:value-of select="$t"/></h1>
<p>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#sets">Sets of names</a>
<xsl:variable name="p">
<xsl:apply-templates select="preceding-sibling::set[1]" mode="name"/>
</xsl:variable>
<xsl:variable name="n">
<xsl:apply-templates select="following-sibling::set[1]" mode="name"/>
</xsl:variable>
<xsl:if test="string($p)">
<br/>Previous: <a href="{$p}.html">
<xsl:value-of select="$p"/></a>
</xsl:if>
<xsl:if test="string($n)">
<br/>Next: <a href="{$n}.html">
<xsl:value-of select="$n"/></a>
</xsl:if>
</p>
<p>
<a href="{$baseuri}{../@name}/{$f}.ent">Entity Declarations</a><br/>
<a href="{$baseuri}{../@name}/{$f}map.xsl">XSLT 2 character map</a>
</p>
<table border="1">
<tr>
<th>Name</th>
<th>Unicode</th>
<th>Glyph</th>
<th>Unicode Name</th>
<th>Description</th>
<th>Aliases</th>
</tr>
<xsl:for-each select="key('set',$set)">
<xsl:sort lang="en" select="@id"/>
<tr>
<xsl:if test="../description/@unicode='provisional'">
<xsl:attribute name="class">provisional</xsl:attribute>
<xsl:message><xsl:value-of select="concat('Provisional: ',$set,': ',@id)"/></xsl:message>
</xsl:if>
<xsl:if test="@optional and @default='IGNORE'">
<xsl:attribute name="class">ignore</xsl:attribute>
</xsl:if>
<td>
<xsl:value-of select="@id"/>
</td>
<td>
<xsl:value-of select="d:uplus(../@id)"/>
</td>
<td>
<img height="32"
width="32"
src="{$glyphs}/{substring(../@id,2,3)}/{translate(../@id,'x','')}.png"
alt="{../@id}"
>
<xsl:if test="../@image='none'"><xsl:attribute
name="src"><xsl:value-of select="$glyphs"/>/none.png</xsl:attribute></xsl:if>
</img>
</td>
<td>
<xsl:value-of select="../description"/>
</td>
<td>
<xsl:value-of select="desc"/>
<xsl:if test="not(desc)"> </xsl:if>
</td>
<td>
<xsl:variable name="aliases" select="distinct-values((../entity[@set=$sets/@name])/@id)[not (. = current()/@id)]"/>
<xsl:if test="@id='AMP'">
</xsl:if>
<xsl:choose>
<xsl:when test="exists($aliases)">
<xsl:value-of select="$aliases" separator=", "/>
</xsl:when>
<xsl:otherwise> </xsl:otherwise>
</xsl:choose>
</td>
</tr>
</xsl:for-each>
</table>
<p>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#sets">Sets of names</a>
<xsl:variable name="p">
<xsl:apply-templates select="preceding-sibling::set[1]" mode="name"/>
</xsl:variable>
<xsl:variable name="n">
<xsl:apply-templates select="following-sibling::set[1]" mode="name"/>
</xsl:variable>
<xsl:if test="string($p)">
<br/>Previous: <a href="{$p}.html">
<xsl:value-of select="$p"/></a>
</xsl:if>
<xsl:if test="string($n)">
<br/>Next: <a href="{$n}.html">
<xsl:value-of select="$n"/></a>
</xsl:if>
</p>
</body>
</html>
</xsl:result-document>
</xsl:template>
<!-- -->
<!-- -->
<xsl:template name="code-chart">
<xsl:param name="range"/>
<xsl:result-document method="html"
include-content-type="no"
encoding="US-ASCII"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="{$resultbase}{$range}.html">
<html>
<head>
<title>Unicode Characters:
<xsl:value-of select="concat($range,'00 to ',$range,'FF')"/>
</title>
<style type="text/css">
.unassigned { background-color: #FF9999 }
.nonxml { background-color: #FF7799 }
.reserved { background-color: #FF6E0E }
.undescribed { background-color: #FFFF99 }
.proposed { background-color: #FF99FF }
span.stix {
font-size: 125%;
font-family: STIXGeneral, STIXGeneral-Italic, STIXGeneral-Bold, STIXGeneral-BoldItalic, STIXSize1Symbols;
background-color: #FFFFDD;
}
<!--
span.cambria {
font-family: Cambria;
background-color: #FFFFEE;
}
-->
<xsl:if test="$script='yes'">
table#info {
text-align:left;
display:none;
font-size: 70%;
background-color:#AAFFAA;
position:absolute;
z-index: 1;
}
</xsl:if>
</style>
<xsl:copy-of select="$css"/>
<xsl:if test="$script='yes'">
<script>
function showinfo (here,hex,ent) {
var tab=here.getElementsByTagName('table');
if (tab.length==1) {
here.style.backgroundColor='white';
here.removeChild(tab[0]);
} else {
var info = document.getElementById('info');
info.style.zIndex=info.style.zIndex+1;
var newinfo=info.cloneNode(true);
newinfo.style.display="table";
here.style.backgroundColor='#AAFFAA';
tr=newinfo.getElementsByTagName('tr');
tr[0].childNodes[0].innerHTML=here.getAttribute('title');
tr[1].childNodes[0].innerHTML= '&amp;#x' + hex + ';';
tr[2].childNodes[0].innerHTML=ent.replace(/([a-zA-Z0-9]+)/g,'&amp;$1;');
here.appendChild(newinfo);
}
}
</script>
</xsl:if>
</head>
<body>
<h1>Unicode Characters:
<xsl:value-of select="concat($range,'00 to ',$range,'FF')"/>
</h1>
<xsl:if test="$script='yes'">
<table id="info">
<tr><td><span id="info-uname">AAAA</span></td></tr>
<tr><td><span id="info-ucode"></span></td></tr>
<tr><td><span id="info-entities"></span></td></tr>
</table>
</xsl:if>
<p>
<xsl:variable name="p" select="position()"/>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#blocks">Unicode Character Ranges</a><br/>
<xsl:if test="$p!=1">
<a href="{$blockstarts[$p - 1]}.html">Previous: <xsl:value-of
select="$blockstarts[$p - 1]"/>00 to <xsl:value-of
select="$blockstarts[$p - 1]"/>FF</a><br/>
</xsl:if>
<xsl:if test="$p!=last()">
<a href="{$blockstarts[$p+1]}.html">Next: <xsl:value-of
select="$blockstarts[$p+1]"/>00 to <xsl:value-of
select="$blockstarts[$p+1]"/>FF</a><br/>
</xsl:if>
</p>
<xsl:variable name="table">
<table border="1">
<tr>
<th> </th>
<xsl:for-each select="$hex">
<xsl:variable name="r" select="."/>
<xsl:variable name="b" select="$blocks[@start=concat($range,$r,'0')]"/>
<xsl:variable name="e" select="d:hexfromstring(concat($range,'FF'))"/>
<xsl:choose>
<xsl:when test="$b">
<xsl:variable name="c" select="$b/((1+min(($e,d:hexfromstring(@end))) - d:hexfromstring(@start))idiv 16)"/>
<xsl:choose>
<xsl:when test="$c=1">
<th width="32"><a href="http://www.unicode.org/charts/PDF/U{$b/replace(@start,'^0','')}.pdf"><xsl:value-of select="replace($b/@name,'(([a-zA-Z][A-Za-z])|-)','​$1')"/></a></th>
</xsl:when>
<xsl:when test="$range='1EE'">
<th width="{$c * 32}" colspan="{$c}"><a href="http://std.dkuug.dk/JTC1/SC2/WG2/docs/n3799.pdf"><xsl:value-of select="$b/@name"/></a></th>
</xsl:when>
<xsl:otherwise>
<th width="{$c * 32}" colspan="{$c}"><a href="http://www.unicode.org/charts/PDF/U{$b/replace(@start,'^0','')}.pdf"><xsl:value-of select="$b/@name"/></a></th>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:when test="position()=1 and not($b)">
<xsl:variable name="b" select="$blocks[@end>concat($range,$r,'0')][1]"/>
<xsl:variable name="c" select="$b/((1+min(($e,d:hexfromstring(@end))) - d:hexfromstring(concat($range,$r,'0')))idiv 16)"/>
<xsl:choose>
<xsl:when test="$c=1">
<th width="32"><a href=" http://www.unicode.org/charts/PDF/U{$b/replace(@start,'^0','')}.pdf"><xsl:value-of select="replace($b/@name,'(([a-zA-Z][a-zA-Z])|-)','​$1')"/></a></th>
</xsl:when>
<xsl:otherwise>
<th width="{$c * 32}" colspan="{$c}"><a href="http://www.unicode.org/charts/PDF/U{$b/replace(@start,'^0','')}.pdf"><xsl:value-of select="$b/@name"/></a></th>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
</xsl:choose>
</xsl:for-each>
<th> </th>
</tr>
<tr>
<th> </th>
<xsl:for-each select="$hex">
<th><xsl:value-of select="$range"/><xsl:value-of select="."/></th>
</xsl:for-each>
<th> </th>
</tr>
<xsl:for-each select="$hex">
<xsl:call-template name="table-row">
<xsl:with-param name="range" select="$range"/>
<xsl:with-param name="row" select="."/>
</xsl:call-template>
</xsl:for-each>
<tr>
<th> </th>
<xsl:for-each select="$hex">
<th><xsl:value-of select="$range"/><xsl:value-of select="."/></th>
</xsl:for-each>
<th> </th>
</tr>
</table>
</xsl:variable>
<xsl:copy-of select="$table"/>
<h2 id="key">Key</h2>
<table border="1">
<tr><th>Cell Style</th><th>Status</th></tr>
<tr><td>   </td><td>Unicode Character (Unicode <xsl:value-of select="$u/unicode/@unicode"/>)</td></tr>
<xsl:if test="$table//td/@class='proposed'">
<tr><td class="proposed">   </td><td><a href="http://unicode.org/alloc/Pipeline.html">Proposed Unicode Character</a></td></tr>
</xsl:if>
<xsl:if test="$table//td/@class='unassigned'">
<tr><td class="unassigned"> </td><td>Unicode or XML Non-Character</td></tr>
</xsl:if>
<xsl:if test="$table//td/@class='nonxml'">
<tr><td class="unassigned"> </td><td>Codepoint not allowed as XML 1.0 character data</td></tr>
</xsl:if>
<xsl:if test="$table//td/@class='reserved'">
<tr><td class="reserved"> </td><td>Reserved (unassigned) codepoint</td></tr>
</xsl:if>
<xsl:if test="$table//td/@class='undescribed'">
<tr><td class="undescribed"> </td><td>Codepoint allowed as XML 1.0 character data; no Unicode character defined</td></tr>
</xsl:if>
<!--<tr><td><img src="{$glyphs}/none.png" alt="none"/></td><td>Character for which an image is not currently available</td></tr>-->
<tr><td><span class="stix"> X </span></td><td>Character styled with the <a href="http://www.stixfonts.org">STIX Fonts</a></td></tr>
</table>
<p>Table headings link to the (PDF) Code charts at the <a href="http://www.unicode.org">Unicode site</a>.</p>
<!--
<p>Images link to the listing <a href="bycodes.html">listing of all characters assigned an entity name</a> whenever such an entity is defined.</p>
-->
<p>
<xsl:variable name="p" select="position()"/>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#blocks">Unicode Character Ranges</a><br/>
<xsl:if test="$p!=1">
<a href="{$blockstarts[$p - 1]}.html">Previous: <xsl:value-of
select="$blockstarts[$p - 1]"/>00 to <xsl:value-of
select="$blockstarts[$p - 1]"/>FF</a><br/>
</xsl:if>
<xsl:if test="$p!=last()">
<a href="{$blockstarts[$p+1]}.html">Next: <xsl:value-of
select="$blockstarts[$p+1]"/>00 to <xsl:value-of
select="$blockstarts[$p+1]"/>FF</a><br/>
</xsl:if>
</p>
</body>
</html>
</xsl:result-document>
</xsl:template>
<xsl:template name="table-row">
<xsl:param name="range"/>
<xsl:param name="row"/>
<tr>
<th><xsl:value-of select="$row"/></th>
<xsl:for-each select="$hex">
<xsl:call-template name="table-cell">
<xsl:with-param name="range" select="$range"/>
<xsl:with-param name="h" select="concat(.,$row)"/>
</xsl:call-template>
</xsl:for-each>
<th><xsl:value-of select="$row"/></th>
</tr>
</xsl:template>
<xsl:template name="table-cell">
<xsl:param name="range"/>
<xsl:param name="h"/>
<td width="40" align="center">
<xsl:variable name="x" select="key('id',concat('U',$range,$h),$u)"/>
<xsl:variable name="c" select=
"codepoints-to-string(d:hexfromstring(concat($range,$h))
[(. gt 32
and
. lt 128)
or
. gt 160]
)"/>
<xsl:choose>
<xsl:when test="not($x)">
<xsl:attribute name="class">undescribed</xsl:attribute>
<xsl:text> </xsl:text>
</xsl:when>
<xsl:when test="$x/description/@unicode='unassigned' and $x/bmp">
<xsl:attribute name="class">reserved</xsl:attribute>
<xsl:text> </xsl:text>
</xsl:when>
<xsl:when test="$x/description/@unicode='unassigned'">
<xsl:attribute name="class">unassigned</xsl:attribute>
<xsl:text> </xsl:text>
</xsl:when>
<xsl:when test="$range='000' and (matches($h,'^[01]') and not($h=('09','0A','0D')))">
<xsl:attribute name="class">nonxml</xsl:attribute>
<xsl:text> </xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:attribute name="title" select="$x/description"/>
<xsl:if test="$x/description/@unicode='proposed'">
<xsl:attribute name="class">proposed</xsl:attribute>
<xsl:message>proposed: <xsl:value-of select="concat($range,$h),$x/description"/></xsl:message>
</xsl:if>
<xsl:variable name="img">
<img height="32" width="32" src="{$glyphs}/{$range}/U{$range}{$h}.png"
alt="{$x/description}">
<xsl:if test="not($none) and ($x/@image='none')">
<xsl:message select="concat('$$$$: ', 'U', $range, $h, ' ', $x/description)"/>
<xsl:attribute name="src"><xsl:value-of select="$glyphs"/>/none.png</xsl:attribute>
</xsl:if>
</img>
</xsl:variable>
<xsl:choose>
<xsl:when test="$script='yes'">
<xsl:attribute name="onclick" select="concat('showinfo(this,''',replace(concat($range,$h),'^0+',''),''',''',
string-join(
distinct-values($x/entity[@set=$u/unicode/entitygroups/group[@name='2007']/set/@name]/@id),
' ')
,''');')"/>
<xsl:copy-of select="$img"/>
</xsl:when>
<xsl:when test="$longtitle='yes'">
<xsl:attribute name="title" select="concat(
$x/description,
' &',
string-join((
replace(concat($range,$h),'^0+','#x'),
distinct-values($x/entity[@set=$u/unicode/entitygroups/group[@name='2007']/set/@name]/@id)),'; &'),
';')"/>
<xsl:copy-of select="$img"/>
</xsl:when>
<xsl:when test="$x/entity[@set=$u/unicode/entitygroups/group[@name='2007']/set/@name]">
<a href="bycodes.html#{$x/@id}">
<xsl:copy-of select="$img"/>
</a>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$img"/>
</xsl:otherwise>
</xsl:choose>
<br/>
<span class="stix"> <xsl:value-of select="$c"/> </span>
</xsl:otherwise>
</xsl:choose>
</td>
</xsl:template>
<xsl:template match="phrase[@role='unicode' and not(node())]">
<xsl:value-of select="$u/unicode/@unicode"/>
</xsl:template>
<!-- -->
<xsl:template name="bycodes">
<xsl:result-document method="html"
include-content-type="no"
encoding="US-ASCII"
indent="no"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="{$resultbase}bycodes.html">
<html>
<head>
<title>
Characters Ordered by Unicode
</title>
<xsl:text> </xsl:text>
<style type="text/css">.error { color: red }</style>
<xsl:text> </xsl:text>
<xsl:copy-of select="$css"/>
</head>
<xsl:text> </xsl:text>
<body>
<h1>Characters Ordered by Unicode</h1>
<xsl:text> </xsl:text>
<p>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#sets">Sets of names</a><br/>
<a href="byalpha.html">Characters ordered by Entity Name</a><br/>
</p>
<p>The line for each character (or character sequence) in the table below lists in order:<br
/>Unicode value,<br/>
Unicode formal name (or in the case of a sequence of characters, the formal name of the first, followed by a descritption of the variant or combination),<br/>
a list of all entity names assigned to this character or sequence.</p>
<pre>
<xsl:text> </xsl:text>
<xsl:for-each select="character[entity/@set=/unicode/entitygroups/group[@name='2007']/set/@name]">
<xsl:sort lang="en" select="@id"/>
<a name="{@id}"/>
<xsl:choose>
<xsl:when test="@image='none'">
<xsl:value-of select="@id"/>
<xsl:message>missing image: <xsl:value-of select="@id"/></xsl:message>
</xsl:when>
<xsl:otherwise>
<a href="{$glyphs}/{substring(@id,2,3)}/{translate(@id,'x','')}.png">
<xsl:value-of select="d:uplus(@id)"/>
</a>
</xsl:otherwise>
</xsl:choose>
<xsl:text>, </xsl:text>
<xsl:value-of select="description"/>
<xsl:value-of select="substring(
' ',
string-length(description))"/>
<xsl:text>, </xsl:text>
<xsl:for-each-group select="entity[@set=/unicode/entitygroups/group[@name='2007']/set/@name]/@id" group-by=".">
<xsl:value-of select="."/>
<xsl:if test="position() < last()">, </xsl:if>
</xsl:for-each-group>
<xsl:text> </xsl:text>
</xsl:for-each>
</pre>
</body>
</html>
</xsl:result-document>
</xsl:template>
<xsl:template name="byalpha">
<xsl:result-document method="html"
encoding="US-ASCII"
include-content-type="no"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="{$resultbase}byalpha.html">
<html>
<head>
<title>Characters Ordered by Entity Name</title>
<style type="text/css">.error { color: red }</style>
<xsl:copy-of select="$css"/>
</head>
<body>
<h1>Characters Ordered by Entity Name</h1>
<p>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#sets">Sets of names</a><br/>
<a href="bycodes.html">Characters ordered by codes</a><br/>
</p>
<p>The line for each entity in the table below lists in order:<br
/>entity name,<br/>entity set,<br/>entity description,<br/>Unicode value,<br
/> Unicode formal name (or in the case of a sequence of characters, the formal name of the first, followed by a descritption of the variant or combination).</p>
<pre>
<xsl:for-each-group
select="character/entity[@set=/unicode/entitygroups/group[@name='2007']/set/@name]"
group-by="@id">
<xsl:sort lang="en" select="@id"/>
<xsl:value-of select="@id"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="substring(' ',string-length(@id))"/>
<xsl:text>, </xsl:text>
<xsl:variable name="s" select="string-join(current-group()/replace(@set,'9573-[0-9]*-',''),' ')"/>
<xsl:value-of select="$s"/>
<xsl:value-of select="substring(' ',string-length($s))"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="normalize-space(.)"/>
<xsl:value-of select="substring(' ',1+string-length(normalize-space(.)))"/>
<xsl:text>, </xsl:text>
<!-- new bit -->
<xsl:choose>
<xsl:when test="@image='none'">
<xsl:value-of select="../@id"/>
<xsl:message>missing image: <xsl:value-of select="../@id"/></xsl:message>
</xsl:when>
<xsl:otherwise>
<a href="{$glyphs}/{substring(../@id,2,3)}/{translate(../@id,'x','')}.png">
<xsl:value-of select="d:uplus(../@id)"/>
</a>
</xsl:otherwise>
</xsl:choose>
<!-- end new bit -->
<xsl:text> , </xsl:text>
<xsl:value-of select="normalize-space(../description)"/>
<xsl:text>, </xsl:text>
<xsl:text> </xsl:text>
</xsl:for-each-group>
</pre>
</body>
</html>
</xsl:result-document>
</xsl:template>
<xsl:function name="d:hexfromstring">
<xsl:param name="x"/>
<xsl:sequence select="(
d:hex(
for $i in string-to-codepoints(upper-case($x))
return if ($i > 64) then $i - 55 else $i - 48))"/>
</xsl:function>
<xsl:function name="d:hex">
<xsl:param name="x"/>
<xsl:sequence
select="if (empty($x)) then 0 else ($x[last()] + 16* d:hex($x[position()!=last()]))"/>
</xsl:function>
<xsl:template match="div1[@id='sets']">
<div id="setsdiv">
<xsl:apply-templates select="*"/>
<ul>
<xsl:for-each select="$u/unicode/entitygroups/group[@name='2007']/set">
<li>
<a href="2007doc/{replace(@name,'^[0-9][0-9\-]*','')}.html">
<xsl:apply-templates select="." mode="name"/>
</a>
<xsl:choose>
<xsl:when test="not(@name=../../group[@name=('html5','mathml')]/set/@name)">
<span>
<xsl:attribute name="style" select="'background-color: #FFCCCC'"/>
<xsl:text>  </xsl:text>
<xsl:value-of select="replace(@fpi,'.*ENTITIES ([^/]*)//.*','$1')"/>
<xsl:text>  (not in MathML3 / HTML5)</xsl:text>
</span>
</xsl:when>
<xsl:otherwise>
<xsl:text>  </xsl:text>
<xsl:value-of select="replace(@fpi,'.*ENTITIES ([^/]*)//.*','$1')"/>
</xsl:otherwise>
</xsl:choose>
</li>
</xsl:for-each>
</ul>
<p>In addition to the stylesheets and entity files corresponding
to each individual entity set, a <a
href="http://www.w3.org/2003/entities/2007/entitynamesmap.xsl">combined
stylesheet</a> is provided, as well as a combined entity set,
in two formats, as for the HTML MathML set described above.</p>
<ul>
<li><a href="http://www.w3.org/2003/entities/2007/w3centities.ent">w3centities</a> W3C entities collection; referencing all entity sets listed above</li>
<li><a
href="http://www.w3.org/2003/entities/2007/w3centities-f.ent">w3centities-f</a> the same set of entity definitions, expanded into a single file, with duplicates removed</li>
</ul>
</div>
</xsl:template>
<!--
<xsl:template match="div1[@id='blocks']">
<div id="sets">
<dl>
<xsl:apply-templates select="*"/>
<xsl:for-each-group select="$blocks[substring(@start,1,3)=$blockstarts]" group-by="substring(@start,1,3)">
<xsl:for-each select="current-group()">
<dt><xsl:value-of select="@name"/></dt>
</xsl:for-each>
<dd><a href="{current-grouping-key()}.html"><xsl:value-of select="current-grouping-key()"/></a></dd>
</xsl:for-each-group>
</dl>
</div>
</xsl:template>
-->
<xsl:template match="div1[@id='blocks']">
<div id="blocksdiv">
<xsl:apply-templates select="*"/>
<ul>
<xsl:for-each-group select="$blocks[substring(@start,1,3)=$blockstarts]" group-by="substring(@start,1,3)">
<xsl:variable name="s" select="d:hexfromstring(substring(@start,1,3))"/>
<xsl:variable name="e" select="d:hexfromstring(substring(@end,1,3))"/>
<xsl:for-each select="$s to $e">
<li>
<xsl:variable name="p" select="string-join(for $x in (. idiv 256, (. mod 256) idiv 16, . mod 16)
return $hex[$x+1],'')"/>
<span>
<xsl:value-of select="$p"/>
</span>
<xsl:text> </xsl:text>
<a href="2007doc/{$p}.html">
<xsl:value-of select="current-group()/@name" separator=", "/>
<xsl:if test="position()!=1"> (continued)</xsl:if>
</a>
</li>
</xsl:for-each>
</xsl:for-each-group>
</ul>
</div>
</xsl:template>
<xsl:template match="div1[@id='alphabets']">
<div id="alphabetsdiv">
<xsl:apply-templates select="*"/>
<ul>
<xsl:for-each select="$u/unicode/mathvariants/mathvariant">
<li>
<a href="2007doc/{@name}.html"><xsl:value-of select="@description"/></a>
</li>
</xsl:for-each>
</ul>
</div>
</xsl:template>
<xsl:template match="graphic[@role='glyph']">
<img height="32" width="32" style="position: relative; top: 10px;"
src="{$glyphs}/{substring(@source,2,3)}/{@source}.png"
alt="{key('id',@source,$u)/description}">
</img>
</xsl:template>
<xsl:variable name="negations" select="('U00338','U020D2','U020E5')"/>
<xsl:template match="p[@id='cancellations']">
<xsl:variable name="section" select="."/>
<ul>
<xsl:for-each select="key('id',$negations,$u)">
<xsl:call-template name="compose-table">
<xsl:with-param name="section" select="$section"/>
</xsl:call-template>
</xsl:for-each>
</ul>
</xsl:template>
<xsl:template match="p[@id='variants']">
<xsl:variable name="section" select="."/>
<ul>
<xsl:for-each select="key('id','U0FE00',$u)">
<xsl:call-template name="compose-table">
<xsl:with-param name="section" select="$section"/>
</xsl:call-template>
</xsl:for-each>
</ul>
</xsl:template>
<xsl:template name="compose-table">
<xsl:param name="section"/>
<xsl:param name="char" select="translate(@id,'U','-')"/>
<xsl:variable name="c" select="."/>
<li><a href="2007doc/{@id}.html"><xsl:value-of select="lower-case($c/description)"/></a></li>
<xsl:result-document method="html"
include-content-type="no"
encoding="US-ASCII"
doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
doctype-system="http://www.w3.org/TR/html4/loose.dtd"
href="{$resultbase}{$c/@id}.html">
<html>
<head>
<title>
<xsl:value-of select="$c/description"/>
</title>
<style type="text/css">
.ignore {background-color: #AAAAAA;}
.base {background-color: #CCCCCC;}
</style>
<xsl:copy-of select="$css"/>
</head>
<body>
<h1><a name="canc.{$c/@id}" id="canc.{$c/@id}"/><xsl:value-of select="lower-case($c/description)"/></h1>
<p>
<a href="../index.html">Overview</a><br/>
<a href="../index.html#{$section/../@id}"><xsl:apply-templates select="$section/../head/text()"/></a><br/>
<xsl:variable name="p" select="position()"/>
<xsl:if test="$p!=1">
Previous: <a href="{$negations[$p - 1]}.html">
<xsl:value-of select="key('id',$negations[$p - 1],$u)/lower-case(description)"/>
</a><br/>
</xsl:if>
<xsl:if test="$p!=last()">
Next: <a href="{$negations[$p + 1]}.html">
<xsl:value-of select="key('id',$negations[$p + 1],$u)/lower-case(description)"/>
</a><br/>
</xsl:if>
</p>
<table border="1">
<tr>
<th> </th>
<th>Unicode</th>
<th>Glyph</th>
<th>Unicode Name</th>
<th>Entity Names</th>
</tr>
<tr>
<td> </td>
<td>
<xsl:value-of select="d:uplus($c/@id)"/>
</td>
<td>
<img height="32"
width="32"
src="{$glyphs}/{substring($c/@id,2,3)}/{$c/@id}.png"
alt="{$c/@id}"
>
<xsl:if test="$c/@image='none'"><xsl:attribute
name="src"><xsl:value-of select="$glyphs"/>/none.png</xsl:attribute></xsl:if>
</img>
</td>
<td>
<xsl:value-of select="$c/description"/>
</td>
<td> </td>
</tr>
<xsl:variable name="cz" select="concat($char,'z')"/>
<xsl:for-each select="$u/unicode/charlist/character[contains(concat(@id,'z'),$cz)]">
<xsl:sort select="@id"/>
<xsl:variable name="id" select="@id"/>
<xsl:variable name="base" select="key('id',concat(substring-before($id,$char),substring-after($id,$char)),$u)"/>
<tr class="base">
<xsl:if test="not($base)">
<xsl:attribute name="class">provisional</xsl:attribute>
<xsl:message>no base: <xsl:value-of select="@id"/></xsl:message>
</xsl:if>
<th>Base</th>
<td>
<xsl:value-of select="d:uplus($base/@id)"/>
</td>
<td>
<img height="32"
width="32"
src="{$glyphs}/{substring($base/@id,2,3)}/{translate($base/@id,'x','')}.png"
alt="{$base/@id}"
>
<xsl:if test="$base/@image='none'"><xsl:attribute
name="src"><xsl:value-of select="$glyphs"/>/none.png</xsl:attribute></xsl:if>
</img>
</td>
<td>
<xsl:value-of select="$base/description"/>
</td>
<td>
<xsl:variable name="x" select="$base/entity[@set=/unicode/entitygroups/group[@name='2007']/set/@name]/@id"/>
<xsl:choose>
<xsl:when test="not($x)"> </xsl:when>
<xsl:otherwise>
<xsl:for-each select="distinct-values($x)">
<xsl:value-of select="."/>
<xsl:if test="position() < last()">, </xsl:if>
</xsl:for-each>
</xsl:otherwise>
</xsl:choose>
</td>
</tr>
<tr class="combine">
<xsl:if test="not(description/@unicode='combination' or description/@unicode='3.2')">
<xsl:attribute name="class">provisional</xsl:attribute>
<xsl:message><xsl:value-of select="@id"/></xsl:message>
</xsl:if>
<th>Variant</th>
<td>
<xsl:value-of select="d:uplus($id)"/>
</td>
<td>