build.gradle

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'osgi'
apply plugin: 'maven'
apply plugin: 'signing'

version = '1.0.17'
group = 'org.openmuc'
def projectName = 'jSML'
def projectNameLowerCase = 'jsml'

sourceCompatibility = 1.6
targetCompatibility = 1.6

repositories { mavenCentral() }

dependencies {
  testCompile group: 'junit', name: 'junit', version: '4.11'
  compile files('dependencies/rxtxcomm_api-2.2pre2-11_bundle.jar')
}

uploadArchives {
  repositories {
    mavenDeployer {
      beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

      repository(url: project.properties.sonatypeRepository) {
        authentication(userName: project.properties.sonatypeUser, password: project.properties.sonatypePass)
      }
      snapshotRepository(url: project.properties.sonatypeSnapshotRepository) {
        authentication(userName: project.properties.sonatypeUser, password: project.properties.sonatypePass)
      }

      pom.project {
	name projectName
	packaging 'jar'
	description 'jSML is a library that can be used to communicate using the Smart Message Language (SML).'
	url 'http://www.openmuc.org/'

	licenses {
	  license {
	    name 'GNU Lesser General Public License'
	    url 'http://www.gnu.org/licenses/lgpl-2.1.html'
	    distribution 'repo'
	  }
	}

	scm {
	  url 'none'
	  connection 'none'
	}

	developers {
	  developer {
	    id 'sfeuerhahn'
	    name 'Stefan Feuerhahn'
	  }
	}
      }
    }
  }
}

task sourcesJar(type: Jar, dependsOn: classes) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

artifacts {
  archives sourcesJar
  archives javadocJar
}

signing {
  if ( project.hasProperty('signing.keyId') ) {
    sign configurations.archives
  }
}

task copyLibs(type: Copy) {
  dependsOn(configurations.default.getAllArtifacts().getBuildDependencies())
  dependsOn(sourcesJar)  

  into "build/libsdeps"
  from configurations.default
  from configurations.archives.getAllArtifacts().getFiles()
}

build.dependsOn(copyLibs)

jar {
  manifest {
    version = project.version.replace('-','.');
    name = projectName
    instruction 'Export-Package', '!*.internal.*,*'
  }
}

sourceSets {
  sample
}

eclipse.pathVariables([GRADLE_USER_HOME:file(gradle.gradleUserHomeDir)])
tasks.eclipse.dependsOn(cleanEclipse)

task javadocs(type: Javadoc) {
  source sourceSets.main.allJava
  
  exclude '**/internal/**'
  
  destinationDir = new File(buildDir, 'javadoc')
  
  classpath = sourceSets.main.compileClasspath
  classpath += sourceSets.main.output
}

task (tar, type: Tar) {
  dependsOn(build)
  dependsOn(javadocs)

  compression = Compression.GZIP

  into(project.archivesBaseName) {
    from('./') {
      include 'doc/*.txt'
      include 'licenses/**'
      include 'build/libsdeps/**'
      include 'build/javadoc/**'
      include 'build.gradle'
      include 'dependencies/**'
      include 'src/**'
      exclude 'src/sample/java/*.class'
    }
  }
}