Unresolved reference: buildKonfig

[ishuuwag]

Describe the bug
Unresolved reference: buildKonfig in the compose multiplatform project

To Reproduce

import org.jetbrains.compose.desktop.application.dsl.TargetFormat
import org.jetbrains.kotlin.gradle.ExperimentalKotlinGradlePluginApi
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import com.codingfeline.buildkonfig.compiler.FieldSpec.Type.*


plugins {
    alias(libs.plugins.kotlinMultiplatform)
    alias(libs.plugins.androidApplication)
    alias(libs.plugins.composeMultiplatform)
    alias(libs.plugins.composeCompiler)
    alias(libs.plugins.openApiGenerator)
    alias(libs.plugins.kotlinxSerialization)
    alias(libs.plugins.buildKonfig)
}

buildKonfig  {
    packageName = "na.com.finestbidders"
    defaultConfigs {
        buildConfigField(STRING, "API_URL", "https://api.example.com")
        buildConfigField(BOOLEAN, "DEBUG", "true")
    }
}

kotlin {
    androidTarget {
        @OptIn(ExperimentalKotlinGradlePluginApi::class)
        compilerOptions {
            jvmTarget.set(JvmTarget.JVM_11)
        }
    }

    listOf(
        iosX64(),
        iosArm64(),
        iosSimulatorArm64()
    ).forEach { iosTarget ->
        iosTarget.binaries.framework {
            baseName = "ComposeApp"
            isStatic = true
        }
    }

    sourceSets {

        androidMain.dependencies {
            implementation(compose.preview)
            implementation(libs.androidx.activity.compose)
            implementation(libs.ktor.client.android)
        }

        iosMain.dependencies {
            implementation(libs.ktor.client.darwin)
        }
        commonMain.dependencies {
            implementation(compose.runtime)
            implementation(compose.foundation)
            implementation(compose.material3)
            implementation(compose.ui)
            implementation(compose.components.resources)
            implementation(compose.components.uiToolingPreview)
            implementation(libs.androidx.lifecycle.viewmodel)
            implementation(libs.androidx.lifecycle.runtimeCompose)
            implementation(libs.multiplatform.settings)
            implementation(libs.ktor.client.core)
            implementation(libs.kotlinx.datetime)
            implementation(libs.ktor.serialization.kotlinx.json)
            implementation(libs.ktor.client.content.negotiation)

        }
        commonMain{
            kotlin.srcDir("${layout.buildDirectory.get()}/generate-resources/main/src")
        }
        commonTest.dependencies {
            implementation(libs.kotlin.test)
        }
    }
}

android {
    namespace = "na.com.finestbidders"
    compileSdk = libs.versions.android.compileSdk.get().toInt()

    defaultConfig {
        applicationId = "na.com.finestbidders"
        minSdk = libs.versions.android.minSdk.get().toInt()
        targetSdk = libs.versions.android.targetSdk.get().toInt()
        versionCode = 1
        versionName = "1.0"
    }
    packaging {
        resources {
            excludes += "/META-INF/{AL2.0,LGPL2.1}"
        }
    }
    buildTypes {
        getByName("release") {
            isMinifyEnabled = false
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }
}

dependencies {
    debugImplementation(compose.uiTooling)
}

openApiGenerate {
    skipValidateSpec.set(true)
    generateApiTests.set(false)
    generateModelTests.set(false)
    packageName.set("na.com.finestbidders")
    inputSpec.set("$rootDir/openapi.yml")
    generatorName.set("kotlin")
    library.set("multiplatform")
    configOptions.set(
        mapOf(
            "serializationLibrary" to "kotlinx_serialization",
            "dateLibrary" to "kotlinx-datetime"
        )
    )
    //outputDir.set("$rootDir/composeApp/src/commonMain/kotlin/na/com/finestbidders/api")
}

Expected behavior
The buildKonfig block to be recognised by gradle

Screenshots

Desktop (please complete the following information):

• OS: macOS sequoia 15.5
• BuildKonfig Version: v0.17.1
• Kotlin Version: 2.1.21
• Gradle Version: v8.9

Additional context
Add any other context about the problem here.

[RyuNen344]

Could you show me project root 'build.gradle' if exists?

[ishuuwag]

Could you show me project root 'build.gradle' if exists?

plugins {
    // this is necessary to avoid the plugins to be loaded multiple times
    // in each subproject's classloader
    alias(libs.plugins.androidApplication) apply false
    alias(libs.plugins.androidLibrary) apply false
    alias(libs.plugins.composeMultiplatform) apply false
    alias(libs.plugins.composeCompiler) apply false
    alias(libs.plugins.kotlinMultiplatform) apply false
    alias(libs.plugins.openApiGenerator) apply false
    alias(libs.plugins.kotlinxSerialization) apply false
    alias(libs.plugins.buildKonfig) apply false
}

[mianaliasjad]

any update on this?

[XuanNie-LF]

@mianaliasjad update your version to buildKonfig = "0.34.0".

and try this:
#note this in lowercase

buildkonfig {

defaultConfigs {
    buildConfigField(FieldSpec.Type.STRING, "test", "testvalue")
}

defaultConfigs("production") {
    buildConfigField(FieldSpec.Type.STRING, "test", "testvalue")
}

}

[XuanNie-LF]

This works for me.