containers: Add migration module to support container upgrades

Author: ricardobranco777

tests/containers/migration.pm

@@ -0,0 +1,121 @@
+# SUSE's openQA tests
+#
+# Copyright SUSE LLC
+# SPDX-License-Identifier: FSFAP
+# Maintainer: QE-C team <[email protected]>
+
+# Summary: Validate docker and podman runtime upgrades
+# Maintainer: QE-C team <[email protected]>
+
+use Mojo::Base 'containers::basetest';
+use testapi;
+use serial_terminal qw(select_serial_terminal select_user_serial_terminal);
+use utils;
+use containers::common;
+
+my $port = 8080;
+
+sub validate {
+    my $runtime = shift;
+
+    assert_script_run "$runtime compose start";
+    assert_script_run "$runtime compose logs";
+    assert_script_run "$runtime compose ps";
+
+    assert_script_run "$runtime container ls";
+    assert_script_run "$runtime volume ls";
+    assert_script_run "$runtime image ls";
+
+    validate_script_output "curl -s http://127.0.0.1:$port", qr/Welcome to nginx/;
+
+    $port++;
+}
+
+sub setup_containers {
+    my ($runtime, $rootless) = @_;
+    my $opts = $rootless ? "--user" : "";
+
+    if ($runtime eq "docker") {
+        assert_script_run "dockerd-rootless-setuptool.sh install" if $rootless;
+        systemctl "$opts enable --now docker";
+    } else {
+        systemctl "$opts start podman.socket";
+    }
+
+    assert_script_run "curl -O " . data_url("containers/docker-compose.yml");
+    assert_script_run "curl -O " . data_url("containers/haproxy.cfg");
+    assert_script_run "sed -i 's/8080/$port/g' docker-compose.yml";
+
+    assert_script_run "$runtime compose pull", 600;
+    assert_script_run "$runtime compose up -d", 120;
+    wait_still_screen stilltime => 15, timeout => 180;
+
+    validate $runtime;
+
+    assert_script_run "$runtime compose stop", 180;
+}
+
+sub upgrade {
+    select_serial_terminal;
+
+    foreach my $repo (split /\s+/, get_var("TEST_REPOS", "")) {
+        zypper_call "addrepo -f $repo";
+    }
+
+    zypper_call "--gpg-auto-import-keys --no-gpg-checks up --details --allow-vendor-change", timeout => 600;
+}
+
+sub cleanup {
+    my ($runtime, $rootless) = @_;
+    my $opts = $rootless ? "--user" : "";
+
+    script_run "$runtime compose down";
+    script_run "$runtime rmi \$($runtime images -aq)";
+
+    if ($runtime eq "docker") {
+        script_run "dockerd-rootless-setuptool.sh uninstall" if $rootless;
+    } else {
+        systemctl "$opts stop podman.socket";
+    }
+}
+
+sub run {
+    my $self = shift;
+
+    select_serial_terminal;
+
+    my @pkgs = qw(docker docker-buildx docker-compose docker-rootless-extras podman);
+    install_packages(@pkgs);
+
+    for my $rootless (0, 1) {
+        for my $runtime ("docker", "podman") {
+            record_info "$runtime old", script_output("$runtime version", proceeed_on_failure => 1);
+            select_user_serial_terminal if $rootless;
+            setup_containers $runtime, $rootless;
+        }
+    }
+
+    assert_script_run "rpm -qa | sort > /tmp/before", timeout => 180;
+    upgrade;
+    assert_script_run "rpm -qa | sort > /tmp/after", timeout => 180;
+    record_info "rpm diff", script_output "diff /tmp/before /tmp/after || true";
+
+    $port = 8080;
+
+    for my $rootless (0, 1) {
+        my $opts = $rootless ? "--user" : "";
+        for my $runtime ("docker", "podman") {
+            select_user_serial_terminal if $rootless;
+            record_info "$runtime new", script_output("$runtime version", proceeed_on_failure => 1);
+            if ($runtime eq "docker") {
+                systemctl "$opts restart docker";
+            } else {
+                systemctl "$opts restart podman.socket";
+            }
+            validate $runtime;
+            cleanup $runtime, $rootless;
+        }
+    }
+}
+
+1;