Lahenda regex praktikumis

Author: sim642

src/regex/brzozowski.ml

@@ -3,7 +3,13 @@ open Re
 
 (** Kas regulaaravaldis sobitub tühisõnega? *)
 let rec matches_eps (r: t): bool =
-  failwith "TODO"
+  match r with
+  | Empty -> false
+  | Eps -> true
+  | Char _ -> false
+  | Choice (l, r) -> matches_eps l || matches_eps r
+  | Concat (l, r) -> matches_eps l && matches_eps r
+  | Star _ -> true
 
 (** Regulaaravaldise tuletis antud tähe järgi.
     Antud regulaaravaldise keelest võetakse kõik sõned, mis algavad antud tähega ja eemaldatakse algusest see täht.
@@ -15,10 +21,23 @@ let rec matches_eps (r: t): bool =
 
     Vihje: matches_eps. *)
 let rec derive (r: t) (c: char): t =
-  failwith "TODO"
+  (* print_endline (show r); *)
+  match r with
+  | Empty (* -> Empty *)
+  | Eps -> Empty
+  | Char c' -> if c = c' then Eps else Empty
+  | Choice (l, r) -> Choice (derive l c, derive r c)
+  | Star r' -> Concat (derive r' c, r)
+  | Concat (l, r) ->
+    let dlr = Concat (derive l c, r) in
+    if matches_eps l then
+      Choice (dlr, derive r c)
+    else
+      dlr
 
 (** Kas regulaaravaldis sobitub antud sõnega?
     Kasutada derive ja matches_eps funktsioone.
     Vihje: String.fold_left. *)
 let matches (s: string) (r: t): bool =
-  failwith "TODO"
+  let r' = String.fold_left derive r s in
+  matches_eps r'

src/regex/simplify.ml

@@ -23,8 +23,29 @@ open Re
     Vihje: Re.equal.
     Vihje: Fixpoint. *)
 
-let rec simplify (r: t): t =
-  failwith "TODO"
+let rec simplify_step (r: t): t =
+  match r with
+  | Choice (r, r') when Re.equal r r' -> r
+  | Concat (r, Eps)
+  | Concat (Eps, r) -> r
+  | Star (Star _ as r') -> r'
+  | Concat (Star r, Star r') when Re.equal r r' -> Star r
+  | Choice (Empty, r)
+  | Choice (r, Empty) -> r
+  | Concat (Empty, r)
+  | Concat (r, Empty) -> Empty
+  | Star Empty -> Eps
+  | Star Eps -> Eps
+  | Empty
+  | Eps
+  | Char _ -> r
+  | Choice (l, r) -> Choice (simplify_step l, simplify_step r)
+  | Concat (l, r) -> Concat (simplify_step l, simplify_step r)
+  | Star r -> Star (simplify_step r)
+
+module ReFP = Fixpoint.Make (Re)
+
+let simplify = ReFP.fp simplify_step
 
 
 (** Alt-üles lahendus.
@@ -34,5 +55,26 @@ let rec simplify (r: t): t =
 
     Vihje: Re.equal. *)
 
+let rec simplify'_one (r: t): t =
+  match r with
+  | Choice (r, r') when Re.equal r r' -> r
+  | Concat (r, Eps)
+  | Concat (Eps, r) -> r
+  | Star (Star _ as r') -> r'
+  | Concat (Star r, Star r') when Re.equal r r' -> Star r
+  | Choice (Empty, r)
+  | Choice (r, Empty) -> r
+  | Concat (Empty, r)
+  | Concat (r, Empty) -> Empty
+  | Star Empty -> Eps
+  | Star Eps -> Eps
+  | _ -> r
+
 let rec simplify' (r: t): t =
-  failwith "TODO"
+  match r with
+  | Empty
+  | Eps
+  | Char _ -> r
+  | Choice (l, r) -> simplify'_one (Choice (simplify' l, simplify' r))
+  | Concat (l, r) -> simplify'_one (Concat (simplify' l, simplify' r))
+  | Star r -> simplify'_one (Star (simplify' r))