MatrixDoc_LightVerbConstructions
This document explains how to fill out the Light Verb Constructions page of the Grammar Matrix Customization questionnaire and presents background information on the light verb constructions library of the Grammar Matrix Customization System (Bender et al., 2002; Bender and Flickinger, 2005; Bender et al., 2010). General instructions on using the questionnaire can be found here.
The standard reference for the Light Verb Constructions library and its implementations is Wueger 2025. The full references and .bib entries can be found here.
You can indicate whether noun and/or verb coverbs are allowed in your language. This option is used to determine whether LVCs are possible in your language (therefore, if one of these options is not selected, this library will not function as intended). For example, Bardi allows both noun and verb coverbs (Claire Bowern. 2012. A grammar of Bardi. Berlin, Boston: De Gruyter Mouton.), so you would choose both options from the options provided below:
What possible coverbs are allowed in your language?
(selecting one or more of these options will allow you to add coverbs of that type to the lexicon)
[] Noun Coverbs
[] Verb Coverbs
If you select either of these options (or both), corresponding questions will appear that allow you to indicate if the noun/verb coverb can pick up dependents on its own. For a noun coverb, this includes determiners, modifiers, and complements. For verb coverbs, this includes a modifiers and complements. In English, noun coverbs can pick up dependents (e.g. "Jordan takes a shower" where the noun coverb "shower" has the determiner "a"), so you would choose the "yes" option for the first question shown below:
Can noun coverbs pick up dependents on their own (e.g. determiner, modifier, complement)?
() yes
() no
Can verb coverbs pick up dependents on their own (e.g. modifier, complement)?
() yes
() no
You can indicate where, with respect to the light verb, the coverb appears in your language. This can be before, after, or both before and after the light verb. For example, in Persian, the coverb must be before the light verb:
| coverb | object | light verb | ||
|---|---|---|---|---|
| Omid | dast | be | gol-hā | zan-ad |
| Omid | hand | to | flower-PL | hit-3SG |
| 'Omid touches the flowers.' |
(Danièle Godard & Pollet Samvelian. 2021. Complex predicates. Head-Driven Phrase Structure Grammar: The handbook 9. 419.)
Therefore, you would select the first option from the ones shown below:
The word order within an LVC is:
() The coverb is before the light verb
() The coverb is after the light verb
() The coverb can be before or after the light verb
You can also specify whether a coverb (or the constituent it heads) needs to be immediately adjacent to a light verb or if other elements (e.g. a subject or object) can intervene. For example, Persian does not require this (as shown in the above example), so you would select the "no" option from the ones shown below:
Does a coverb (or the constituent it heads) have to be immediately adjacent to a light verb?
() yes
() no
This library currently allows for two valence options for light verbs: the light verb can either take just the coverb and/or the coverb and one other complement as arguments. This allows for light verbs to behave intransitively or transitively. In Japanese, both valence options are possible for light verbs, so you would select both options shown below:
What possible valence options are allowed for light verbs in your language?
[] A light verb can take just a coverb as an argument (i.e. intransitive)
[] A light verb can take a coverb plus an additional complement as arguments (i.e. transitive)
This library allows for bleached/semantically empty light verbs. For example, Japanese allows for bleached light verbs, so you would select the "yes" option shown below:
Are bleached (semantically empty) verbs possible in your language?
() yes
() no
If you select "yes" for the above question, a corresponding question will appear that allows you to specify if only some or all of the light verbs are bleached in your languages. For example, since Japanese only has one light verb suru (which is bleached), you would select the "yes" option shown below (Yo Matsumoto. 1996. A syntactic account of light verb phenomena in Japanese. Journal of East Asian Linguistics 5(2). 107–149.):
Are all light verbs bleached in your language?
() yes
() no
I defined the LVC feature, which is specified on the head of the coverb and allows a coverb to indicate which light verb(s) it can combine with. For example, in the Bardi LVC liyan innyana "breathed", the lexical type that the coverb liyan "heart" inherits from specifies a value of lv-nya-tr-noun-trans for its LVC feature. This value corresponds to the transitive light verb -nya- "to catch" that can combine with noun coverbs. The values for the LVC feature are drawn from the subhierarchy shown here:
The lv-none type is used either for lexical types that are not coverbs or to prevent coverbs from being used in certain phrasal types. The lv-all type is used for lexical types that are coverbs and can be used to specify that a coverb accepts any light verb. More specific types can also be created that inherit from lv-all, which allow a coverb to combine with only some light verbs.
(For more details on the LVC feature, see section 4.2.1 of Wueger 2025.)
In my analysis, the relationship between a light verb and a coverb is that of a head and its complement (i.e. the coverb is the complement of the light verb). Since the order of the light verb and coverb does not always match the order of heads and their complements in all languages, I could not use the existing head-complement rules and added LVC-specific ones. These are head-comp-phrase-lvc (for constructions where the coverb is after the light verb) and comp-head-phrase-lvc (for constructions where the coverb is before the light verb). (An additional head-final-lvc type was also added for languages with free word order).) Both of these rules specify that the first element on the comps list of the head daughter is [lvc lv-all]. This constrains this element to be a coverb (since only coverbs will have an lvc value that is or inherits from lv-all).
head-comp-phrase-lvc := basic-head-1st-comp-phrase & head-initial &
[ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.LVC lv-all ].
head-final-lvc := head-final &
[ SYNSEM.ATTACH lmod ].
comp-head-phrase-lvc := basic-head-1st-comp-phrase & head-final-lvc &
[ HEAD-DTR.SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST.LOCAL.CAT.HEAD.LVC lv-all ].
Additionally, some languages allow any element to intervene between the light verb and coverb while other languages are more strict. For languages that don’t allow any element to intervene (including when they are part of the constituent that the coverb heads), the [ LIGHT + ] feature is required on the head daughter of head-comp-lvc and/or comp-head-lvc. This only applies to languages without auxiliaries (since this feature would prevent auxiliaries from combining with light verbs).
(For more details on LVC phrasal types, see section 4.2.2 of Wueger 2025.)
My analysis accounts for three different kinds of light verb properties: bleached vs. unbleached, intransitive vs. transitive, and those that combine with noun coverbs vs. those that combine with verb coverbs. Combinations of these three kinds of properties correspond to lexical types (Since this library doesn't currently support bleached light verbs combining with noun coverbs, there are no corresponding types). A summary of these types is shown here:
| Type name | Bleached? | Intransitive or Transitive? | Noun or Verb Coverb? |
|---|---|---|---|
| intrans-noun-lv-lex | no | intrans | noun |
| intrans-verb-lv-lex | no | intrans | verb |
| trans-noun-lv-lex | no | trans | noun |
| trans-verb-lv-lex | no | trans | verb |
| bleached-intrans-verb-lv-lex | yes | intrans | verb |
| bleached-trans-verb-lv-lex | yes | trans | verb |
To reduce redundancy, I factored out parts of the feature structures for these six types based on the three properties into other types. The full hierarchy for the LVC-related types is shown here:
The lv-lex lexical type is inherited by all unbleached light verbs. It contains features that apply to all unbleached light verbs and sets up a majority of the semantics for the construction.
lv-lex := verb-lex &
[ ARG-ST < [ LOCAL [ CAT cat-sat,
CONT.HOOK [ INDEX ref-ind & #ind1,
ICONS-KEY.IARG1 #clause ] ] ] . [ FIRST #comps &
[ LOCAL [ CAT cat-sat,
CONT.HOOK [ ICONS-KEY.IARG1 #clause,
XARG #ind1,
LTOP #ltop ] ] ] ] >,
SYNSEM [ LKEYS.KEYREL.ARG1 #ind1,
LOCAL [ CONT.HOOK [ CLAUSE-KEY #clause,
LTOP #ltop ],
CAT.VAL [ COMPS.FIRST #comps ] ] ] ].
The basic-intrans-lv-lex type makes sure that only one element is on the comps list (the coverb).
basic-intrans-lv-lex := non-mod-lex-item &
[ SYNSEM.LOCAL.CAT.VAL.COMPS.REST null ].
Complements of the light verb can, in some languages, be analyzed as the complement of the coverb. However, in my analysis, this is not possible and complements of the light verb can only be realized as such. Therefore, constraints on the object are indicated on the light verb’s lexical type. The basic-trans-lv-lex type provides information about the object in the sentence.
basic-trans-lv-lex := non-mod-lex-item & non-local-none-no-hcons & basic-icons-lex-item &
[ SYNSEM [ LOCAL [ CAT.VAL.COMPS < [ ],
[ OPT -,
LOCAL [ CAT cat-sat &
[ VAL.SPR < > ],
CONT.HOOK [ INDEX ref-ind & #ind3,
ICONS-KEY.IARG1 #clause ] ] ] >,
CONT.HOOK.CLAUSE-KEY #clause ],
LKEYS.KEYREL.ARG3 #ind3,
LIGHT + ] ].
Currently, intrans-lv-lex and trans-lv-lex do not have feature structures. They exist to coordinate with how light verbs are added to the lexical type hierarchies in the Grammar Matrix customization system. This makes sure that mophotactic types are properly added to the correct light verb-related types, if necessary.
The noun-lv-lex type is used for unbleached light verbs that combine with noun coverbs.
noun-lv-lex := lv-lex &
[ SYNSEM [ LOCAL.CAT.VAL.COMPS.FIRST #comps,
LKEYS.KEYREL.ARG2 #ind2 ],
ARG-ST.REST.FIRST #comps &
[ LOCAL [ CAT cat-sat &
[ VAL.SPR < > ],
CONT.HOOK.INDEX ref-ind & #ind2 ] ] ].
The verb-lv-lex type is used for unbleached light verbs that combine with verb coverbs.
verb-lv-lex := lv-lex &
[ SYNSEM [ LKEYS.KEYREL.ARG2 #ind2,
LOCAL.CAT.VAL.COMPS.FIRST #comps ],
ARG-ST.REST.FIRST #comps &
[ LOCAL.CONT.HOOK.INDEX event & #ind2 ] ].
The bleached-lv-lex type is inherited by all bleached light verbs. It contains features that apply to all bleached light verbs and sets up a majority of the semantics for the construction. In my analysis, bleached light verbs should not be contributing anything meaningful in the semantics, as that is the coverb’s job. Therefore, instead of identifying ARG1 of the light verb with the INDEX of the subject, bleached-lv-lex identifies the ARG1 of the coverb with the INDEX of the subject.
bleached-lv-lex := verb-lex &
[ ARG-ST < #subj &
[ LOCAL [ CAT cat-sat,
CONT.HOOK.INDEX ref-ind & #ind1 ] ] . [ FIRST #comps &
[ LOCAL [ CAT cat-sat,
CONT.HOOK #hook ],
LKEYS.KEYREL.ARG1 #ind1 ] ] >,
SYNSEM.LOCAL [ CONT.HOOK #hook,
CAT.VAL [ COMPS.FIRST #comps,
SUBJ.FIRST #subj ] ] ].
Currently, bleached-intrans-lv-lex and bleached-trans-lv-lex do not have feature structures (for the same reasons listed above for intrans-lv-lex and trans-lv-lex).
The bleached-verb-lv-lex type is used for bleached light verbs that combine with verb coverbs (as stated earlier, there is no corresponding type for noun coverbs since the library does not support bleached light verbs combining with noun coverbs).
bleached-verb-lv-lex := bleached-lv-lex &
[ SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST #comps,
ARG-ST.REST.FIRST #comps &
[ LOCAL.CONT.HOOK.INDEX event ].
There are also additional features that can be added to these types in order to constrain for certain language-dependent functionality. For lv-lex and bleached-lv-lex, they specify the head type for the subject, which is dependent on whether a language uses case-marked adpositions (e.g. +np, adp, noun). There are some languages that allow coverbs to take on dependents similar to their non-coverb counterparts and some that don’t. For the languages that don’t, this is constrained by adding [ LIGHT + ] and [ MODIFIED notmod ] to the coverb in noun-lv-lex, verb-lv-lex, and bleached-verb-lv-lex.
[ SYNSEM.LOCAL.CAT.VAL.COMPS.FIRST #comps,
ARG-ST.REST.FIRST #comps &
[ LIGHT +,
MODIFIED notmod ] ].
(For more details on light verb-related types, see section 4.2.3 of Wueger 2025. This includes explanations for each part of the feature structures.)
The noun-coverb-lex type is used for noun coverbs.
coverb-noun-lex := basic-noun-lex &
[ SYNSEM.LOCAL.CAT [ HEAD.MOD < >,
VAL [ COMPS < >,
SPR < #spr &
[ LOCAL.CAT.HEAD det ] > ] ],
ARG-ST < #spr > ].
(For more details on noun coverb types, see section 4.2.4 of Wueger 2025.)
There are two main verb coverb types, one for intransitive verb coverbs (coverb-intrans-verb-lex) and one for transitive verb coverbs (coverb-trans-verb-lex). There isn’t a relationship between the transitivity of the coverb and the light verb (i.e. a transitive light verb can combine with an intransitive coverb). No additional features are added to either type (it exists so that morphotactic types are properly added to the correct coverb-related types).
(For more details on verb coverb types, see section 4.2.5 of Wueger 2025.)
-
Future work could look into possible ways of allowing bleached light verbs to work with noun coverbs. For example, taking a noun coverb and denominalizing it so its lexical category is now a verb would allow for an event to be provided.
-
It was discovered after the implementation stage that the basic-trans-lv-lex feature structure is not completely correct. This will work for unbleached light verbs but not for bleached ones. In bleached light verbs, the INDEX of the object should be identified with the ARG2 of the coverb (this could be done by having bleached-trans-lv-lex do argument composition or by having the object directly combine with the coverb). Identifying the INDEX of the object with the ARG3 of the light verb should be moved from basic-trans-lv-lex to trans-lv-lex.
- In the current implementation noun coverbs specify that the COMPS is empty. However, this is not true for all languages, as specifying that the COMPS is empty blocks the noun from taking complements. Future work could further investigate complement-taking noun coverbs.
- Noun coverbs do not say anything about their subjects. This is to allow for the possibility of identifying the subject of the light verb with the subject of the coverb. There is an analysis of coverbs that allows it to constrain the subject. This is one avenue with which that could be possible. Fully implementing this is left to future work.
- Future work could factor out similarities between noun-lex and coverb-noun-lex into a common supertype.
- The LVC library does not support idiomatic meanings for LVCs. Future work could support a lookup table that finds the meaning of the full LVC based on the coverb and light verb combination.
- I discovered some bugs in my implementation during the testing phase. These are listed in section 5.4 of Wueger 2025 and are good candidates for future work.
Wueger, Tara. 2025. Modeling Light Verb Constructions in the LinGO Grammar Matrix. University of Washington MS Thesis. https://www.proquest.com/dissertations-theses/modeling-light-verb-constructions-lingo-grammar/docview/3230303431/se-2.
-
bibtex:
@mastersthesis{wueger2025mastersthesis,
title = {{M}odeling {L}ight {V}erb {C}onstructions in the {LinGO} {G}rammar {M}atrix},
author = {Wueger, Tara},
year = {2025},
school = {University of Washington},
type = {MS Thesis},
url = {https://www.proquest.com/dissertations-theses/modeling-light-verb-constructions-lingo-grammar/docview/3230303431/se-2},
}