Pull the latest fontawesome-6 related changes

.github/workflows/cmake.yml

@@ -0,0 +1,52 @@
+name: CMake
+
+on:
+  push:
+    branches:
+      - master
+      - main
+    tags:
+      - "*"
+  pull_request:
+
+env:
+  # Customize the CMake build type here (Release, Debug, RelWithDebInfo, etc.)
+  BUILD_TYPE: Release
+
+jobs:
+  build-and-test:
+
+    name: ${{ matrix.os }}-Qt-${{ matrix.qt_version }}-shared-${{ matrix.shared }}
+    runs-on: ${{ matrix.os }}
+
+    strategy:
+      fail-fast: false
+      matrix:
+        os: [ubuntu-20.04, ubuntu-22.04, ubuntu-24.04, macos-12, macos-13, macos-14, windows-2019, windows-2022]
+        qt_version: [5.12.12, 5.15.2, 6.4.0, 6.5.0, 6.6.0, 6.7.0]
+        shared: [ON, OFF]
+        exclude:
+          - os: macos-14
+            qt_version: 5.12.12
+          - os: macos-14
+            qt_version: 5.15.2
+    steps:
+    - name: Checkout Code
+      uses: actions/checkout@v4
+      with:
+        fetch-depth: 0
+    - run: git fetch --tags --force
+
+    - name: Install Qt
+      uses: jurplel/install-qt-action@v4
+      with:
+        version: ${{ matrix.qt_version }}
+        cache: 'true'
+        cache-key-prefix: ${{ runner.os }}-Qt-Cache-${{ matrix.qt_version }}
+        dir: ${{ github.workspace }}/Qt
+
+    - name: Configure (${{ matrix.configuration }})
+      run: cmake -DCMAKE_BUILD_TYPE="${{env.BUILD_TYPE}}" -DBUILD_SHARED_LIBS=${{ matrix.shared }} -B "${{github.workspace}}/build"
+
+    - name: Build with ${{ matrix.compiler }}
+      run: cmake --build ${{github.workspace}}/build --config ${{env.BUILD_TYPE}} --target package

.gitignore

@@ -1,7 +1,8 @@
 .*
 *.pro.user
 *.pro.user*
-/*build*
+CMakeLists.txt.user
+**/build
 
 # never include pro files
 QtAwesome/fonts/pro/

CHANGES.md

@@ -0,0 +1,19 @@
+# Changes
+
+- (2025-07-15) #66, Style name parsing (stringToStyleEnum) not working properly (contribution by @samapico)
+- (2025-05-08) #65, Support for Qt 6.9. Fix the CMakelist example
+- (2025-04-07) Update to 6.7.2 (Updated OTF files)
+- (2024-11-21) Update to 6.7.1, Extra Duotone styles
+  - Expand Duotone to support Solid, Regular, Light and Thin
+  - Add Sharp Duotone styles
+  - Deprecated Duotone (without style)
+- (2024-04-23) Support for dark/light colorSchema mode, (contribution by @hanjianqiao(Lanchitour))
+- (2023-12-07) Update to 6.5.1, Sharp Thin Pro font
+- (2023-08-16) Update to 6.4.2, Fix issue missing pro icons in namedCodePoints
+- (2023-03-28) Update to 6.4.0, Sharp Light Pro font
+- (2023-02-09) Update to 6.3.0, Aliases and Sharp Regular Pro font
+  - Aliases are now included in the icon list names
+  - Support for font style "Font Awesome Sharp Regular" (Pro)
+  - Update generator to include all alias names
+  - Update free font files to latest release
+- (2013-04-19) Initial release

CMakeLists.txt

@@ -0,0 +1,143 @@
+cmake_minimum_required(VERSION 3.16)
+
+#Set The Current Version Number to use as fallback if GIT Fails.
+set(QTAWESOME_VERSION_MAJOR 6)
+set(QTAWESOME_VERSION_MINOR 5)
+set(QTAWESOME_VERSION_PATCH 1)
+set(QTAWESOME_VERSION_TWEAK 0)
+# Get the version from git if it's a git repository
+if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git)
+  find_package(Git)
+  if(GIT_FOUND)
+    execute_process(
+      COMMAND ${GIT_EXECUTABLE} describe --tags --long --match "font-awesome-*" --always
+      WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+      OUTPUT_VARIABLE GITREV
+      ERROR_QUIET
+      OUTPUT_STRIP_TRAILING_WHITESPACE)
+      string(FIND ${GITREV} "font-awesome-" isRev)
+      if(NOT ifRev EQUAL -1)
+        string(REGEX MATCH [0-9]+ MAJOR ${GITREV})
+        string(REGEX MATCH \\.[0-9]+ MINOR ${GITREV})
+        string(REPLACE "." "" MINOR "${MINOR}")
+        string(REGEX MATCH [0-9]+\- PATCH ${GITREV})
+        string(REPLACE "-" "" PATCH "${PATCH}")
+        string(REGEX MATCH \-[0-9]+\- TWEAK ${GITREV})
+        string(REPLACE "-" "" TWEAK "${TWEAK}")
+        set(QTAWESOME_VERSION_MAJOR ${MAJOR})
+        set(QTAWESOME_VERSION_MINOR ${MINOR})
+        set(QTAWESOME_VERSION_PATCH ${PATCH})
+        set(QTAWESOME_VERSION_TWEAK ${TWEAK})
+      elseif(NOT ${GITREV} STREQUAL "")
+        set(QTAWESOME_VERSION_TWEAK ${GITREV})
+      endif()
+  endif()
+endif()
+
+set(QTAWESOME_VERSION "${QTAWESOME_VERSION_MAJOR}.${QTAWESOME_VERSION_MINOR}.${QTAWESOME_VERSION_PATCH}.${QTAWESOME_VERSION_TWEAK}")
+message(STATUS "Building QTAWESOME: ${QTAWESOME_VERSION}")
+
+project(QtAwesome VERSION ${QTAWESOME_VERSION} DESCRIPTION "Add Font Awesome icons to your Qt application")
+
+find_package(QT NAMES Qt6 Qt5 REQUIRED COMPONENTS Core)
+find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Core Widgets)
+
+set(CMAKE_AUTOUIC ON)
+set(CMAKE_AUTOMOC ON)
+set(CMAKE_AUTORCC ON)
+
+set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS ON)
+
+set(QtAwesome_HEADERS
+	QtAwesome/QtAwesome.h
+	QtAwesome/QtAwesomeAnim.h
+	QtAwesome/QtAwesomeEnumGenerated.h
+	QtAwesome/QtAwesomeStringGenerated.h
+)
+
+add_library(QtAwesome
+	QtAwesome/QtAwesome.cpp
+	QtAwesome/QtAwesomeAnim.cpp
+	QtAwesome/QtAwesomeFree.qrc
+	${QtAwesome_HEADERS}
+)
+
+include(GNUInstallDirs)
+
+target_include_directories(QtAwesome
+	INTERFACE
+		$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/QtAwesome>
+		$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+)
+
+target_link_libraries(QtAwesome PUBLIC
+	Qt${QT_VERSION_MAJOR}::Widgets
+)
+
+set_target_properties(QtAwesome PROPERTIES
+	PUBLIC_HEADER "${QtAwesome_HEADERS}"
+)
+
+install(TARGETS QtAwesome EXPORT QtAwesomeConfig
+	RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+	LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/QtAwesome
+)
+
+install (FILES "${PROJECT_SOURCE_DIR}/LICENSE.md" DESTINATION ${CMAKE_INSTALL_DATADIR}/licenses/${PROJECT_NAME} RENAME LICENSE)
+
+install(EXPORT QtAwesomeConfig
+	DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/QtAwesome/
+	NAMESPACE QtAwesome::
+)
+
+export(EXPORT QtAwesomeConfig NAMESPACE QtAwesome::)
+
+## PACKAGES
+#Generic Info
+set(CPACK_PACKAGE_CONTACT "rick@blommersit.nl")
+set(CPACK_STRIP_FILES TRUE)
+set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/LICENSE.md")
+set(CPACK_PACKAGE_NAME "QtAwesome")
+set(CPACK_PACKAGE_VENDOR "gamecreature")
+set(CPACK_PACKAGE_HOMEPAGE_URL "https://github.com/gamecreature/QtAwesome")
+set(CPACK_PACKAGE_DESCRIPTION_SUMMARY ${CMAKE_PROJECT_DESCRIPTION})
+
+## SET OS NAME
+if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
+	set(OS_STRING "macos")
+elseif(CMAKE_SYSTEM_NAME MATCHES "Windows")
+	if (CMAKE_SIZEOF_VOID_P EQUAL 8)
+		set(OS_STRING "win64")
+	elseif(CMAKE_SIZEOF_VOID_P EQUAL 4)
+		set(OS_STRING "win32")
+	endif()
+elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
+	set(OS_STRING "linux_${CMAKE_SYSTEM_PROCESSOR}")
+else()
+	set(OS_STRING ${CMAKE_SYSTEM_NAME}_${CMAKE_SYSTEM_PROCESSOR})
+endif()
+
+if (NOT CPACK_PACKAGE_VERSION)
+	set(CPACK_PACKAGE_VERSION ${CMAKE_PROJECT_VERSION})
+endif()
+
+if(NOT BUILD_SHARED_LIBS)
+	set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${OS_STRING}")
+else()
+	set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-static-${OS_STRING}")
+endif()
+set(CPACK_PACKAGE_INSTALL_DIRECTORY ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
+set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY OFF)
+
+#Set base Name And Generator Based on the system
+if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
+	set(CPACK_GENERATOR "ZIP")
+elseif(CMAKE_SYSTEM_NAME MATCHES "Windows")
+	set(CPACK_GENERATOR "7Z")
+elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
+	set(CPACK_GENERATOR "TGZ")
+endif()
+
+include(CPack)

LICENSE.md

@@ -1,7 +1,7 @@
 MIT License
 ===========
 
-Copyright 2013-2022 [Reliable Bits Software by Blommers IT](https://blommersit.nl). All Rights Reserved.
+Copyright 2013-2025 [Blommers IT](https://blommersit.nl). All Rights Reserved.
 Author [Rick Blommers](mailto:rick@blommersit.nl)
 
 Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated